lib/Moose/Meta/Method/Destructor.pm

   1
   2 package Moose::Meta::Method::Destructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken';
   8
   9 our $VERSION   = '0.75_01';
  10 $VERSION = eval $VERSION;
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Generated';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (ref $options{options} eq 'HASH')
  21         || $class->throw_error("You must pass a hash of options", data => $options{options});
  22
  23     ($options{package_name} && $options{name})
  24         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  25
  26     my $self = bless {
  27         # from our superclass
  28         'body'                 => undef,
  29         'package_name'         => $options{package_name},
  30         'name'                 => $options{name},
  31         # ...
  32         'options'              => $options{options},
  33         'associated_metaclass' => $options{metaclass},
  34     } => $class;
  35
  36     # we don't want this creating
  37     # a cycle in the code, if not
  38     # needed
  39     weaken($self->{'associated_metaclass'});
  40
  41     $self->_initialize_body;
  42
  43     return $self;
  44 }
  45
  46 ## accessors
  47
  48 sub options              { (shift)->{'options'}              }
  49
  50 ## method
  51
  52 sub is_needed {
  53     my $self      = shift;
  54     my $metaclass = shift;
  55
  56     ( blessed $metaclass && $metaclass->isa('Class::MOP::Class') )
  57         || $self->throw_error(
  58         "The is_needed method expected a metaclass object as its arugment");
  59
  60     return $metaclass->find_method_by_name('DEMOLISH');
  61 }
  62
  63 sub initialize_body {
  64     Carp::cluck('The initialize_body method has been made private.'
  65         . " The public version is deprecated and will be removed in a future release.\n");
  66     shift->_initialize_body;
  67 }
  68
  69 sub _initialize_body {
  70     my $self = shift;
  71     # TODO:
  72     # the %options should also include a both
  73     # a call 'initializer' and call 'SUPER::'
  74     # options, which should cover approx 90%
  75     # of the possible use cases (even if it
  76     # requires some adaption on the part of
  77     # the author, after all, nothing is free)
  78
  79     my @DEMOLISH_methods = $self->associated_metaclass->find_all_methods_by_name('DEMOLISH');
  80
  81     return unless @DEMOLISH_methods;
  82
  83     my $source = 'sub {';
  84
  85     my @DEMOLISH_calls;
  86     foreach my $method (@DEMOLISH_methods) {
  87         push @DEMOLISH_calls => '$_[0]->' . $method->{class} . '::DEMOLISH()';
  88     }
  89
  90     $source .= join ";\n" => @DEMOLISH_calls;
  91
  92     $source .= ";\n" . '}';
  93     warn $source if $self->options->{debug};
  94
  95     my $code = $self->_compile_code(
  96         environment => {},
  97         code => $source,
  98     ) or $self->throw_error("Could not eval the destructor :\n\n$source\n\nbecause :\n\n$@", error => $@, data => $source);
  99
 100     $self->{'body'} = $code;
 101 }
 102
 103
 104 1;
 105
 106 __END__
 107
 108 =pod
 109
 110 =head1 NAME
 111
 112 Moose::Meta::Method::Destructor - Method Meta Object for destructors
 113
 114 =head1 DESCRIPTION
 115
 116 This class is a subclass of L<Class::MOP::Class::Generated> that
 117 provides Moose-specific functionality for inlining destructors.
 118
 119 To understand this class, you should read the the
 120 L<Class::MOP::Class::Generated> documentation as well.
 121
 122 =head1 INHERITANCE
 123
 124 C<Moose::Meta::Method::Destructor> is a subclass of
 125 L<Moose::Meta::Method> I<and> L<Class::MOP::Method::Generated>.
 126
 127 =head1 METHODS
 128
 129 =over 4
 130
 131 =item B<< Moose::Meta;:Method::Destructor->new(%options) >>
 132
 133 This constructs a new object. It accepts the following options:
 134
 135 =over 8
 136
 137 =item * package_name
 138
 139 The package for the class in which the destructor is being
 140 inlined. This option is required.
 141
 142 =item * name
 143
 144 The name of the destructor method. This option is required.
 145
 146 =item * metaclass
 147
 148 The metaclass for the class this destructor belongs to. This is
 149 optional, as it can be set later by calling C<<
 150 $metamethod->attach_to_class >>.
 151
 152 =back
 153
 154 =item B<< Moose::Meta;:Method::Destructor->is_needed($metaclass) >>
 155
 156 Given a L<Moose::Meta::Class> object, this method returns a boolean
 157 indicating whether the class needs a destructor. If the class or any
 158 of its parents defines a C<DEMOLISH> method, it needs a destructor.
 159
 160 =back
 161
 162 =head1 AUTHORS
 163
 164 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 165
 166 =head1 COPYRIGHT AND LICENSE
 167
 168 Copyright 2006-2009 by Infinity Interactive, Inc.
 169
 170 L<http://www.iinteractive.com>
 171
 172 This library is free software; you can redistribute it and/or modify
 173 it under the same terms as Perl itself.
 174
 175 =cut
 176