lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken', 'looks_like_number', 'refaddr';
   8
   9 our $VERSION   = '0.93';
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Moose::Meta::Method',
  13          'Class::MOP::Method::Constructor';
  14
  15 sub new {
  16     my $class   = shift;
  17     my %options = @_;
  18
  19     my $meta = $options{metaclass};
  20
  21     (ref $options{options} eq 'HASH')
  22         || $class->throw_error("You must pass a hash of options", data => $options{options});
  23
  24     ($options{package_name} && $options{name})
  25         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  26
  27     my $self = bless {
  28         'body'          => undef,
  29         'package_name'  => $options{package_name},
  30         'name'          => $options{name},
  31         'options'       => $options{options},
  32         'associated_metaclass' => $meta,
  33         '_expected_method_class' => $options{_expected_method_class} || 'Moose::Object',
  34     } => $class;
  35
  36     # we don't want this creating
  37     # a cycle in the code, if not
  38     # needed
  39     weaken($self->{'associated_metaclass'});
  40
  41     $self->_initialize_body;
  42
  43     return $self;
  44 }
  45
  46 ## method
  47
  48 sub _initialize_body {
  49     my $self = shift;
  50     # TODO:
  51     # the %options should also include a both
  52     # a call 'initializer' and call 'SUPER::'
  53     # options, which should cover approx 90%
  54     # of the possible use cases (even if it
  55     # requires some adaption on the part of
  56     # the author, after all, nothing is free)
  57     my $source = 'sub {';
  58     $source .= "\n" . 'my $_instance = shift;';
  59
  60     $source .= "\n" . 'my $class = Scalar::Util::blessed($_instance) || $_instance;';
  61
  62     $source .= "\n" . 'return $class->Moose::Object::new(@_)';
  63     $source .= "\n    if \$class ne '" . $self->associated_metaclass->name
  64             .  "';\n";
  65
  66     $source .= $self->_generate_params('$params', '$class');
  67     $source .= $self->_generate_instance('$instance', '$class');
  68     $source .= $self->_generate_slot_initializers;
  69
  70     $source .= $self->_generate_triggers();
  71     $source .= ";\n" . $self->_generate_BUILDALL();
  72
  73     $source .= ";\nreturn \$instance";
  74     $source .= ";\n" . '}';
  75     warn $source if $self->options->{debug};
  76
  77     # We need to check if the attribute ->can('type_constraint')
  78     # since we may be trying to immutabilize a Moose meta class,
  79     # which in turn has attributes which are Class::MOP::Attribute
  80     # objects, rather than Moose::Meta::Attribute. And
  81     # Class::MOP::Attribute attributes have no type constraints.
  82     # However we need to make sure we leave an undef value there
  83     # because the inlined code is using the index of the attributes
  84     # to determine where to find the type constraint
  85
  86     my $attrs = $self->_attributes;
  87
  88     my @type_constraints = map {
  89         $_->can('type_constraint') ? $_->type_constraint : undef
  90     } @$attrs;
  91
  92     my @type_constraint_bodies = map {
  93         defined $_ ? $_->_compiled_type_constraint : undef;
  94     } @type_constraints;
  95
  96     my ( $code, $e ) = $self->_compile_code(
  97         code => $source,
  98         environment => {
  99             '$meta'  => \$self,
 100             '$attrs' => \$attrs,
 101             '@type_constraints' => \@type_constraints,
 102             '@type_constraint_bodies' => \@type_constraint_bodies,
 103         },
 104     );
 105
 106     $self->throw_error(
 107         "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$e",
 108         error => $e, data => $source )
 109         if $e;
 110
 111     $self->{'body'} = $code;
 112 }
 113
 114 sub _generate_params {
 115     my ( $self, $var, $class_var ) = @_;
 116     "my $var = " . $self->_generate_BUILDARGS( $class_var, '@_' ) . ";\n";
 117 }
 118
 119 sub _generate_instance {
 120     my ( $self, $var, $class_var ) = @_;
 121     "my $var = "
 122         . $self->_meta_instance->inline_create_instance($class_var) . ";\n";
 123 }
 124
 125 sub _generate_slot_initializers {
 126     my ($self) = @_;
 127     return (join ";\n" => map {
 128         $self->_generate_slot_initializer($_)
 129     } 0 .. (@{$self->_attributes} - 1)) . ";\n";
 130 }
 131
 132 sub _generate_BUILDARGS {
 133     my ( $self, $class, $args ) = @_;
 134
 135     my $buildargs = $self->associated_metaclass->find_method_by_name("BUILDARGS");
 136
 137     if ( $args eq '@_' and ( !$buildargs or $buildargs->body == \&Moose::Object::BUILDARGS ) ) {
 138         return join("\n",
 139             'do {',
 140             $self->_inline_throw_error('"Single parameters to new() must be a HASH ref"', 'data => $_[0]'),
 141             '    if scalar @_ == 1 && !( defined $_[0] && ref $_[0] eq q{HASH} );',
 142             '(scalar @_ == 1) ? {%{$_[0]}} : {@_};',
 143             '}',
 144         );
 145     } else {
 146         return $class . "->BUILDARGS($args)";
 147     }
 148 }
 149
 150 sub _generate_BUILDALL {
 151     my $self = shift;
 152     my @BUILD_calls;
 153     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 154         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD($params)';
 155     }
 156     return join ";\n" => @BUILD_calls;
 157 }
 158
 159 sub _generate_triggers {
 160     my $self = shift;
 161     my @trigger_calls;
 162     foreach my $i ( 0 .. $#{ $self->_attributes } ) {
 163         my $attr = $self->_attributes->[$i];
 164
 165         next unless $attr->can('has_trigger') && $attr->has_trigger;
 166
 167         my $init_arg = $attr->init_arg;
 168
 169         next unless defined $init_arg;
 170
 171         push @trigger_calls => '(exists $params->{\''
 172             . $init_arg
 173             . '\'}) && do {'
 174             . "\n    "
 175             . '$attrs->['
 176             . $i
 177             . ']->trigger->('
 178             . '$instance, '
 179             . $self->_meta_instance->inline_get_slot_value(
 180                   '$instance',
 181                   $attr->name,
 182               )
 183             . ', '
 184             . ');' . "\n}";
 185     }
 186
 187     return join ";\n" => @trigger_calls;
 188 }
 189
 190 sub _generate_slot_initializer {
 191     my $self  = shift;
 192     my $index = shift;
 193
 194     my $attr = $self->_attributes->[$index];
 195
 196     my @source = ('## ' . $attr->name);
 197
 198     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 199
 200     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 201         push @source => ('(exists $params->{\'' . $attr->init_arg . '\'}) ' .
 202                         '|| ' . $self->_inline_throw_error('"Attribute (' . $attr->name . ') is required"') .';');
 203     }
 204
 205     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 206
 207         if ( defined( my $init_arg = $attr->init_arg ) ) {
 208             push @source => 'if (exists $params->{\'' . $init_arg . '\'}) {';
 209             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 210             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 211                 if $is_moose;
 212             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 213             push @source => "} else {";
 214         }
 215             my $default;
 216             if ( $attr->has_default ) {
 217                 $default = $self->_generate_default_value($attr, $index);
 218             }
 219             else {
 220                my $builder = $attr->builder;
 221                $default = '$instance->' . $builder;
 222             }
 223
 224             push @source => '{'; # wrap this to avoid my $val overwrite warnings
 225             push @source => ('my $val = ' . $default . ';');
 226             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 227                 if $is_moose;
 228             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 229             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 230
 231         push @source => "}" if defined $attr->init_arg;
 232     }
 233     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 234         push @source => '(exists $params->{\'' . $init_arg . '\'}) && do {';
 235
 236             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 237             if ($is_moose && $attr->has_type_constraint) {
 238                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 239                     push @source => $self->_generate_type_coercion(
 240                         $attr,
 241                         '$type_constraints[' . $index . ']',
 242                         '$val',
 243                         '$val'
 244                     );
 245                 }
 246                 push @source => $self->_generate_type_constraint_check(
 247                     $attr,
 248                     '$type_constraint_bodies[' . $index . ']',
 249                     '$type_constraints[' . $index . ']',
 250                     '$val'
 251                 );
 252             }
 253             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 254
 255         push @source => "}";
 256     }
 257
 258     return join "\n" => @source;
 259 }
 260
 261 sub _generate_slot_assignment {
 262     my ($self, $attr, $value, $index) = @_;
 263
 264     my $source;
 265
 266     if ($attr->has_initializer) {
 267         $source = (
 268             '$attrs->[' . $index . ']->set_initial_value($instance, ' . $value . ');'
 269         );
 270     }
 271     else {
 272         $source = (
 273             $self->_meta_instance->inline_set_slot_value(
 274                 '$instance',
 275                 $attr->name,
 276                 $value
 277             ) . ';'
 278         );
 279     }
 280
 281     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 282
 283     if ($is_moose && $attr->is_weak_ref) {
 284         $source .= (
 285             "\n" .
 286             $self->_meta_instance->inline_weaken_slot_value(
 287                 '$instance',
 288                 $attr->name
 289             ) .
 290             ' if ref ' . $value . ';'
 291         );
 292     }
 293
 294     return $source;
 295 }
 296
 297 sub _generate_type_constraint_and_coercion {
 298     my ($self, $attr, $index) = @_;
 299
 300     return unless $attr->has_type_constraint;
 301
 302     my @source;
 303     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 304         push @source => $self->_generate_type_coercion(
 305             $attr,
 306             '$type_constraints[' . $index . ']',
 307             '$val',
 308             '$val'
 309         );
 310     }
 311     push @source => $self->_generate_type_constraint_check(
 312         $attr,
 313         ('$type_constraint_bodies[' . $index . ']'),
 314         ('$type_constraints[' . $index . ']'),
 315         '$val'
 316     );
 317     return @source;
 318 }
 319
 320 sub _generate_type_coercion {
 321     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 322     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 323 }
 324
 325 sub _generate_type_constraint_check {
 326     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 327     return (
 328         $self->_inline_throw_error('"Attribute (' # FIXME add 'dad'
 329         . $attr->name
 330         . ') does not pass the type constraint because: " . '
 331         . $type_constraint_obj . '->get_message(' . $value_name . ')')
 332         . "\n\t unless " .  $type_constraint_cv . '->(' . $value_name . ');'
 333     );
 334 }
 335
 336 sub _generate_default_value {
 337     my ($self, $attr, $index) = @_;
 338     # NOTE:
 339     # default values can either be CODE refs
 340     # in which case we need to call them. Or
 341     # they can be scalars (strings/numbers)
 342     # in which case we can just deal with them
 343     # in the code we eval.
 344     if ($attr->is_default_a_coderef) {
 345         return '$attrs->[' . $index . ']->default($instance)';
 346     }
 347     else {
 348         return q{"} . quotemeta( $attr->default ) . q{"};
 349     }
 350 }
 351
 352 1;
 353
 354 __END__
 355
 356 =pod
 357
 358 =head1 NAME
 359
 360 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 361
 362 =head1 DESCRIPTION
 363
 364 This class is a subclass of L<Class::MOP::Class::Constructor> that
 365 provides additional Moose-specific functionality
 366
 367 To understand this class, you should read the the
 368 L<Class::MOP::Class::Constructor> documentation as well.
 369
 370 =head1 INHERITANCE
 371
 372 C<Moose::Meta::Method::Constructor> is a subclass of
 373 L<Moose::Meta::Method> I<and> L<Class::MOP::Method::Constructor>.
 374
 375 =head1 AUTHORS
 376
 377 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 378
 379 =head1 COPYRIGHT AND LICENSE
 380
 381 Copyright 2006-2009 by Infinity Interactive, Inc.
 382
 383 L<http://www.iinteractive.com>
 384
 385 This library is free software; you can redistribute it and/or modify
 386 it under the same terms as Perl itself.
 387
 388 =cut
 389