lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken', 'looks_like_number', 'refaddr';
   8
   9 our $VERSION   = '1.08';
  10 our $AUTHORITY = 'cpan:STEVAN';
  11
  12 use base 'Moose::Meta::Method',
  13          'Class::MOP::Method::Constructor';
  14
  15 sub new {
  16     my $class   = shift;
  17     my %options = @_;
  18
  19     my $meta = $options{metaclass};
  20
  21     (ref $options{options} eq 'HASH')
  22         || $class->throw_error("You must pass a hash of options", data => $options{options});
  23
  24     ($options{package_name} && $options{name})
  25         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  26
  27     my $self = bless {
  28         'body'          => undef,
  29         'package_name'  => $options{package_name},
  30         'name'          => $options{name},
  31         'options'       => $options{options},
  32         'associated_metaclass' => $meta,
  33         '_expected_method_class' => $options{_expected_method_class} || 'Moose::Object',
  34     } => $class;
  35
  36     # we don't want this creating
  37     # a cycle in the code, if not
  38     # needed
  39     weaken($self->{'associated_metaclass'});
  40
  41     $self->_initialize_body;
  42
  43     return $self;
  44 }
  45
  46 ## method
  47
  48 sub _initialize_body {
  49     my $self = shift;
  50     # TODO:
  51     # the %options should also include a both
  52     # a call 'initializer' and call 'SUPER::'
  53     # options, which should cover approx 90%
  54     # of the possible use cases (even if it
  55     # requires some adaption on the part of
  56     # the author, after all, nothing is free)
  57     my $source = 'sub {';
  58     $source .= "\n" . 'my $_instance = shift;';
  59
  60     $source .= "\n" . 'my $class = Scalar::Util::blessed($_instance) || $_instance;';
  61
  62     $source .= "\n" . "if (\$class ne '" . $self->associated_metaclass->name
  63             .  "') {";
  64     $source .= "\n    return "
  65             .  $self->_generate_fallback_constructor('$class') . ";";
  66     $source .= "\n}\n";
  67
  68     $source .= $self->_generate_params('$params', '$class');
  69     $source .= $self->_generate_instance('$instance', '$class');
  70     $source .= $self->_generate_slot_initializers;
  71
  72     $source .= $self->_generate_triggers();
  73     $source .= ";\n" . $self->_generate_BUILDALL();
  74
  75     $source .= ";\nreturn \$instance";
  76     $source .= ";\n" . '}';
  77     warn $source if $self->options->{debug};
  78
  79     # We need to check if the attribute ->can('type_constraint')
  80     # since we may be trying to immutabilize a Moose meta class,
  81     # which in turn has attributes which are Class::MOP::Attribute
  82     # objects, rather than Moose::Meta::Attribute. And
  83     # Class::MOP::Attribute attributes have no type constraints.
  84     # However we need to make sure we leave an undef value there
  85     # because the inlined code is using the index of the attributes
  86     # to determine where to find the type constraint
  87
  88     my $attrs = $self->_attributes;
  89
  90     my @type_constraints = map {
  91         $_->can('type_constraint') ? $_->type_constraint : undef
  92     } @$attrs;
  93
  94     my @type_constraint_bodies = map {
  95         defined $_ ? $_->_compiled_type_constraint : undef;
  96     } @type_constraints;
  97
  98     my ( $code, $e ) = $self->_compile_code(
  99         code => $source,
 100         environment => {
 101             '$meta'  => \$self,
 102             '$attrs' => \$attrs,
 103             '@type_constraints' => \@type_constraints,
 104             '@type_constraint_bodies' => \@type_constraint_bodies,
 105         },
 106     );
 107
 108     $self->throw_error(
 109         "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$e",
 110         error => $e, data => $source )
 111         if $e;
 112
 113     $self->{'body'} = $code;
 114 }
 115
 116 sub _generate_fallback_constructor {
 117     my ( $self, $class_var ) = @_;
 118     "${class_var}->Moose::Object::new(\@_)";
 119 }
 120
 121 sub _generate_params {
 122     my ( $self, $var, $class_var ) = @_;
 123     "my $var = " . $self->_generate_BUILDARGS( $class_var, '@_' ) . ";\n";
 124 }
 125
 126 sub _generate_instance {
 127     my ( $self, $var, $class_var ) = @_;
 128     "my $var = "
 129         . $self->_meta_instance->inline_create_instance($class_var) . ";\n";
 130 }
 131
 132 sub _generate_slot_initializers {
 133     my ($self) = @_;
 134     return (join ";\n" => map {
 135         $self->_generate_slot_initializer($_)
 136     } 0 .. (@{$self->_attributes} - 1)) . ";\n";
 137 }
 138
 139 sub _generate_BUILDARGS {
 140     my ( $self, $class, $args ) = @_;
 141
 142     my $buildargs = $self->associated_metaclass->find_method_by_name("BUILDARGS");
 143
 144     if ( $args eq '@_' and ( !$buildargs or $buildargs->body == \&Moose::Object::BUILDARGS ) ) {
 145         return join("\n",
 146             'do {',
 147             $self->_inline_throw_error('"Single parameters to new() must be a HASH ref"', 'data => $_[0]'),
 148             '    if scalar @_ == 1 && !( defined $_[0] && ref $_[0] eq q{HASH} );',
 149             '(scalar @_ == 1) ? {%{$_[0]}} : {@_};',
 150             '}',
 151         );
 152     } else {
 153         return $class . "->BUILDARGS($args)";
 154     }
 155 }
 156
 157 sub _generate_BUILDALL {
 158     my $self = shift;
 159     my @BUILD_calls;
 160     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 161         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD($params)';
 162     }
 163     return join ";\n" => @BUILD_calls;
 164 }
 165
 166 sub _generate_triggers {
 167     my $self = shift;
 168     my @trigger_calls;
 169     foreach my $i ( 0 .. $#{ $self->_attributes } ) {
 170         my $attr = $self->_attributes->[$i];
 171
 172         next unless $attr->can('has_trigger') && $attr->has_trigger;
 173
 174         my $init_arg = $attr->init_arg;
 175
 176         next unless defined $init_arg;
 177
 178         push @trigger_calls => '(exists $params->{\''
 179             . $init_arg
 180             . '\'}) && do {'
 181             . "\n    "
 182             . '$attrs->['
 183             . $i
 184             . ']->trigger->('
 185             . '$instance, '
 186             . $self->_meta_instance->inline_get_slot_value(
 187                   '$instance',
 188                   $attr->name,
 189               )
 190             . ', '
 191             . ');' . "\n}";
 192     }
 193
 194     return join ";\n" => @trigger_calls;
 195 }
 196
 197 sub _generate_slot_initializer {
 198     my $self  = shift;
 199     my $index = shift;
 200
 201     my $attr = $self->_attributes->[$index];
 202
 203     my @source = ('## ' . $attr->name);
 204
 205     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 206
 207     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 208         push @source => ('(exists $params->{\'' . $attr->init_arg . '\'}) ' .
 209                         '|| ' . $self->_inline_throw_error('"Attribute (' . quotemeta($attr->name) . ') is required"') .';');
 210     }
 211
 212     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 213
 214         if ( defined( my $init_arg = $attr->init_arg ) ) {
 215             push @source => 'if (exists $params->{\'' . $init_arg . '\'}) {';
 216             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 217             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 218                 if $is_moose;
 219             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 220             push @source => "} else {";
 221         }
 222             my $default;
 223             if ( $attr->has_default ) {
 224                 $default = $self->_generate_default_value($attr, $index);
 225             }
 226             else {
 227                my $builder = $attr->builder;
 228                $default = '$instance->' . $builder;
 229             }
 230
 231             push @source => '{'; # wrap this to avoid my $val overwrite warnings
 232             push @source => ('my $val = ' . $default . ';');
 233             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 234                 if $is_moose;
 235             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 236             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 237
 238         push @source => "}" if defined $attr->init_arg;
 239     }
 240     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 241         push @source => '(exists $params->{\'' . $init_arg . '\'}) && do {';
 242
 243             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 244             if ($is_moose && $attr->has_type_constraint) {
 245                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 246                     push @source => $self->_generate_type_coercion(
 247                         $attr,
 248                         '$type_constraints[' . $index . ']',
 249                         '$val',
 250                         '$val'
 251                     );
 252                 }
 253                 push @source => $self->_generate_type_constraint_check(
 254                     $attr,
 255                     '$type_constraint_bodies[' . $index . ']',
 256                     '$type_constraints[' . $index . ']',
 257                     '$val'
 258                 );
 259             }
 260             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 261
 262         push @source => "}";
 263     }
 264
 265     return join "\n" => @source;
 266 }
 267
 268 sub _generate_slot_assignment {
 269     my ($self, $attr, $value, $index) = @_;
 270
 271     my $source;
 272
 273     if ($attr->has_initializer) {
 274         $source = (
 275             '$attrs->[' . $index . ']->set_initial_value($instance, ' . $value . ');'
 276         );
 277     }
 278     else {
 279         $source = (
 280             $self->_meta_instance->inline_set_slot_value(
 281                 '$instance',
 282                 $attr->name,
 283                 $value
 284             ) . ';'
 285         );
 286     }
 287
 288     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 289
 290     if ($is_moose && $attr->is_weak_ref) {
 291         $source .= (
 292             "\n" .
 293             $self->_meta_instance->inline_weaken_slot_value(
 294                 '$instance',
 295                 $attr->name
 296             ) .
 297             ' if ref ' . $value . ';'
 298         );
 299     }
 300
 301     return $source;
 302 }
 303
 304 sub _generate_type_constraint_and_coercion {
 305     my ($self, $attr, $index) = @_;
 306
 307     return unless $attr->has_type_constraint;
 308
 309     my @source;
 310     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 311         push @source => $self->_generate_type_coercion(
 312             $attr,
 313             '$type_constraints[' . $index . ']',
 314             '$val',
 315             '$val'
 316         );
 317     }
 318     push @source => $self->_generate_type_constraint_check(
 319         $attr,
 320         ('$type_constraint_bodies[' . $index . ']'),
 321         ('$type_constraints[' . $index . ']'),
 322         '$val'
 323     );
 324     return @source;
 325 }
 326
 327 sub _generate_type_coercion {
 328     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 329     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 330 }
 331
 332 sub _generate_type_constraint_check {
 333     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 334     return (
 335         $self->_inline_throw_error('"Attribute (' # FIXME add 'dad'
 336         . quotemeta( $attr->name )
 337         . ') does not pass the type constraint because: " . '
 338         . $type_constraint_obj . '->get_message(' . $value_name . ')')
 339         . "\n\t unless " .  $type_constraint_cv . '->(' . $value_name . ');'
 340     );
 341 }
 342
 343 sub _generate_default_value {
 344     my ($self, $attr, $index) = @_;
 345     # NOTE:
 346     # default values can either be CODE refs
 347     # in which case we need to call them. Or
 348     # they can be scalars (strings/numbers)
 349     # in which case we can just deal with them
 350     # in the code we eval.
 351     if ($attr->is_default_a_coderef) {
 352         return '$attrs->[' . $index . ']->default($instance)';
 353     }
 354     else {
 355         return q{"} . quotemeta( $attr->default ) . q{"};
 356     }
 357 }
 358
 359 1;
 360
 361 __END__
 362
 363 =pod
 364
 365 =head1 NAME
 366
 367 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 368
 369 =head1 DESCRIPTION
 370
 371 This class is a subclass of L<Class::MOP::Method::Constructor> that
 372 provides additional Moose-specific functionality
 373
 374 To understand this class, you should read the the
 375 L<Class::MOP::Method::Constructor> documentation as well.
 376
 377 =head1 INHERITANCE
 378
 379 C<Moose::Meta::Method::Constructor> is a subclass of
 380 L<Moose::Meta::Method> I<and> L<Class::MOP::Method::Constructor>.
 381
 382 =head1 BUGS
 383
 384 See L<Moose/BUGS> for details on reporting bugs.
 385
 386 =head1 AUTHORS
 387
 388 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 389
 390 =head1 COPYRIGHT AND LICENSE
 391
 392 Copyright 2006-2010 by Infinity Interactive, Inc.
 393
 394 L<http://www.iinteractive.com>
 395
 396 This library is free software; you can redistribute it and/or modify
 397 it under the same terms as Perl itself.
 398
 399 =cut
 400