lib/Moose/Meta/Method/Constructor.pm

   1
   2 package Moose::Meta::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp ();
   8 use Scalar::Util 'blessed', 'weaken', 'looks_like_number', 'refaddr';
   9
  10 our $VERSION   = '1.25';
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Constructor';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     my $meta = $options{metaclass};
  21
  22     (ref $options{options} eq 'HASH')
  23         || $class->throw_error("You must pass a hash of options", data => $options{options});
  24
  25     ($options{package_name} && $options{name})
  26         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  27
  28     my $self = bless {
  29         'body'          => undef,
  30         'package_name'  => $options{package_name},
  31         'name'          => $options{name},
  32         'options'       => $options{options},
  33         'associated_metaclass' => $meta,
  34         '_expected_method_class' => $options{_expected_method_class} || 'Moose::Object',
  35     } => $class;
  36
  37     # we don't want this creating
  38     # a cycle in the code, if not
  39     # needed
  40     weaken($self->{'associated_metaclass'});
  41
  42     $self->_initialize_body;
  43
  44     return $self;
  45 }
  46
  47 ## method
  48
  49 sub _initialize_body {
  50     my $self = shift;
  51     # TODO:
  52     # the %options should also include a both
  53     # a call 'initializer' and call 'SUPER::'
  54     # options, which should cover approx 90%
  55     # of the possible use cases (even if it
  56     # requires some adaption on the part of
  57     # the author, after all, nothing is free)
  58     my $source = 'sub {';
  59     $source .= "\n" . 'my $_instance = shift;';
  60
  61     $source .= "\n" . 'my $class = Scalar::Util::blessed($_instance) || $_instance;';
  62
  63     $source .= "\n" . "if (\$class ne '" . $self->associated_metaclass->name
  64             .  "') {";
  65     $source .= "\n    return "
  66             .  $self->_generate_fallback_constructor('$class') . ";";
  67     $source .= "\n}\n";
  68
  69     $source .= $self->_generate_params('$params', '$class');
  70     $source .= $self->_generate_instance('$instance', '$class');
  71     $source .= $self->_generate_slot_initializers;
  72
  73     $source .= $self->_generate_triggers();
  74     $source .= ";\n" . $self->_generate_BUILDALL();
  75
  76     $source .= ";\nreturn \$instance";
  77     $source .= ";\n" . '}';
  78     warn $source if $self->options->{debug};
  79
  80     # We need to check if the attribute ->can('type_constraint')
  81     # since we may be trying to immutabilize a Moose meta class,
  82     # which in turn has attributes which are Class::MOP::Attribute
  83     # objects, rather than Moose::Meta::Attribute. And
  84     # Class::MOP::Attribute attributes have no type constraints.
  85     # However we need to make sure we leave an undef value there
  86     # because the inlined code is using the index of the attributes
  87     # to determine where to find the type constraint
  88
  89     my $attrs = $self->_attributes;
  90
  91     my @type_constraints = map {
  92         $_->can('type_constraint') ? $_->type_constraint : undef
  93     } @$attrs;
  94
  95     my @type_constraint_bodies = map {
  96         defined $_ ? $_->_compiled_type_constraint : undef;
  97     } @type_constraints;
  98
  99     my $defaults = [map { $_->default } @$attrs];
 100
 101     my ( $code, $e ) = $self->_compile_code(
 102         code => $source,
 103         environment => {
 104             '$meta'  => \$self,
 105             '$attrs' => \$attrs,
 106             '$defaults' => \$defaults,
 107             '@type_constraints' => \@type_constraints,
 108             '@type_constraint_bodies' => \@type_constraint_bodies,
 109         },
 110     );
 111
 112     $self->throw_error(
 113         "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$e",
 114         error => $e, data => $source )
 115         if $e;
 116
 117     $self->{'body'} = $code;
 118 }
 119
 120 sub _generate_fallback_constructor {
 121     my ( $self, $class_var ) = @_;
 122     "${class_var}->Moose::Object::new(\@_)";
 123 }
 124
 125 sub _generate_params {
 126     my ( $self, $var, $class_var ) = @_;
 127     "my $var = " . $self->_generate_BUILDARGS( $class_var, '@_' ) . ";\n";
 128 }
 129
 130 sub _generate_instance {
 131     my ( $self, $var, $class_var ) = @_;
 132     "my $var = "
 133         . $self->associated_metaclass->inline_create_instance($class_var) . ";\n";
 134 }
 135
 136 sub _generate_slot_initializers {
 137     my ($self) = @_;
 138     return (join ";\n" => map {
 139         $self->_generate_slot_initializer($_)
 140     } 0 .. (@{$self->_attributes} - 1)) . ";\n";
 141 }
 142
 143 sub _generate_BUILDARGS {
 144     my ( $self, $class, $args ) = @_;
 145
 146     my $buildargs = $self->associated_metaclass->find_method_by_name("BUILDARGS");
 147
 148     if ( $args eq '@_'
 149         and ( !$buildargs or $buildargs->body == \&Moose::Object::BUILDARGS )
 150         ) {
 151
 152         # This is the same logic as Moose::Object::BUILDARGS
 153         return sprintf( <<'EOF', $self->_inline_throw_error( q{'Single parameters to new() must be a HASH ref'}, 'data => $_[0]' ) );
 154 do {
 155     my $params;
 156     if ( scalar @_ == 1 ) {
 157         unless ( defined $_[0] && ref $_[0] eq 'HASH' ) {
 158             %s
 159         }
 160         $params = { %%{ $_[0] } };
 161     }
 162     elsif ( @_ %% 2 ) {
 163         Carp::carp(
 164             "The new() method for $class expects a hash reference or a key/value list."
 165                 . " You passed an odd number of arguments" );
 166         $params = { @_, undef };
 167     }
 168     else {
 169         $params = {@_};
 170     }
 171     $params
 172 };
 173 EOF
 174             ;
 175     }
 176     else {
 177         return $class . "->BUILDARGS($args)";
 178     }
 179 }
 180
 181 sub _generate_BUILDALL {
 182     my $self = shift;
 183     my @BUILD_calls;
 184     foreach my $method (reverse $self->associated_metaclass->find_all_methods_by_name('BUILD')) {
 185         push @BUILD_calls => '$instance->' . $method->{class} . '::BUILD($params)';
 186     }
 187     return join ";\n" => @BUILD_calls;
 188 }
 189
 190 sub _generate_triggers {
 191     my $self = shift;
 192     my @trigger_calls;
 193     foreach my $i ( 0 .. $#{ $self->_attributes } ) {
 194         my $attr = $self->_attributes->[$i];
 195
 196         next unless $attr->can('has_trigger') && $attr->has_trigger;
 197
 198         my $init_arg = $attr->init_arg;
 199
 200         next unless defined $init_arg;
 201
 202         push @trigger_calls => '(exists $params->{\''
 203             . $init_arg
 204             . '\'}) && do {'
 205             . "\n    "
 206             . '$attrs->['
 207             . $i
 208             . ']->trigger->('
 209             . '$instance, '
 210             . $attr->inline_get('$instance')
 211             . ', '
 212             . ');' . "\n}";
 213     }
 214
 215     return join ";\n" => @trigger_calls;
 216 }
 217
 218 sub _generate_slot_initializer {
 219     my $self  = shift;
 220     my $index = shift;
 221
 222     my $attr = $self->_attributes->[$index];
 223
 224     my @source = ('## ' . $attr->name);
 225
 226     my $is_moose = $attr->isa('Moose::Meta::Attribute'); # XXX FIXME
 227
 228     if ($is_moose && defined($attr->init_arg) && $attr->is_required && !$attr->has_default && !$attr->has_builder) {
 229         push @source => ('(exists $params->{\'' . $attr->init_arg . '\'}) ' .
 230                         '|| ' . $self->_inline_throw_error('"Attribute (' . quotemeta($attr->name) . ') is required"') .';');
 231     }
 232
 233     if (($attr->has_default || $attr->has_builder) && !($is_moose && $attr->is_lazy)) {
 234
 235         if ( defined( my $init_arg = $attr->init_arg ) ) {
 236             push @source => 'if (exists $params->{\'' . $init_arg . '\'}) {';
 237             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 238             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 239                 if $is_moose;
 240             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 241             push @source => "} else {";
 242         }
 243             my $default;
 244             if ( $attr->has_default ) {
 245                 $default = $self->_generate_default_value($attr, $index);
 246             }
 247             else {
 248                my $builder = $attr->builder;
 249                $default = '$instance->' . $builder;
 250             }
 251
 252             push @source => '{'; # wrap this to avoid my $val overwrite warnings
 253             push @source => ('my $val = ' . $default . ';');
 254             push @source => $self->_generate_type_constraint_and_coercion($attr, $index)
 255                 if $is_moose;
 256             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 257             push @source => '}'; # close - wrap this to avoid my $val overrite warnings
 258
 259         push @source => "}" if defined $attr->init_arg;
 260     }
 261     elsif ( defined( my $init_arg = $attr->init_arg ) ) {
 262         push @source => '(exists $params->{\'' . $init_arg . '\'}) && do {';
 263
 264             push @source => ('my $val = $params->{\'' . $init_arg . '\'};');
 265             if ($is_moose && $attr->has_type_constraint) {
 266                 if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 267                     push @source => $self->_generate_type_coercion(
 268                         $attr,
 269                         '$type_constraints[' . $index . ']',
 270                         '$val',
 271                         '$val'
 272                     );
 273                 }
 274                 push @source => $self->_generate_type_constraint_check(
 275                     $attr,
 276                     '$type_constraint_bodies[' . $index . ']',
 277                     '$type_constraints[' . $index . ']',
 278                     '$val'
 279                 );
 280             }
 281             push @source => $self->_generate_slot_assignment($attr, '$val', $index);
 282
 283         push @source => "}";
 284     }
 285
 286     return join "\n" => @source;
 287 }
 288
 289 sub _generate_slot_assignment {
 290     my ($self, $attr, $value, $index) = @_;
 291
 292     my $source;
 293
 294     if ( $attr->has_initializer ) {
 295         return
 296               '$attrs->['
 297             . $index
 298             . ']->set_initial_value($instance, '
 299             . $value . ');';
 300     }
 301     else {
 302         return $attr->inline_set(
 303             '$instance',
 304             $value
 305         ) . ';';
 306     }
 307
 308     return $source;
 309 }
 310
 311 sub _generate_type_constraint_and_coercion {
 312     my ($self, $attr, $index) = @_;
 313
 314     return unless $attr->has_type_constraint;
 315
 316     my @source;
 317     if ($attr->should_coerce && $attr->type_constraint->has_coercion) {
 318         push @source => $self->_generate_type_coercion(
 319             $attr,
 320             '$type_constraints[' . $index . ']',
 321             '$val',
 322             '$val'
 323         );
 324     }
 325     push @source => $self->_generate_type_constraint_check(
 326         $attr,
 327         ('$type_constraint_bodies[' . $index . ']'),
 328         ('$type_constraints[' . $index . ']'),
 329         '$val'
 330     );
 331     return @source;
 332 }
 333
 334 sub _generate_type_coercion {
 335     my ($self, $attr, $type_constraint_name, $value_name, $return_value_name) = @_;
 336     return ($return_value_name . ' = ' . $type_constraint_name .  '->coerce(' . $value_name . ');');
 337 }
 338
 339 sub _generate_type_constraint_check {
 340     my ($self, $attr, $type_constraint_cv, $type_constraint_obj, $value_name) = @_;
 341     return (
 342         $self->_inline_throw_error('"Attribute (' # FIXME add 'dad'
 343         . quotemeta( $attr->name )
 344         . ') does not pass the type constraint because: " . '
 345         . $type_constraint_obj . '->get_message(' . $value_name . ')')
 346         . "\n\t unless " .  $type_constraint_cv . '->(' . $value_name . ');'
 347     );
 348 }
 349
 350 1;
 351
 352 __END__
 353
 354 =pod
 355
 356 =head1 NAME
 357
 358 Moose::Meta::Method::Constructor - Method Meta Object for constructors
 359
 360 =head1 DESCRIPTION
 361
 362 This class is a subclass of L<Class::MOP::Method::Constructor> that
 363 provides additional Moose-specific functionality
 364
 365 To understand this class, you should read the the
 366 L<Class::MOP::Method::Constructor> documentation as well.
 367
 368 =head1 INHERITANCE
 369
 370 C<Moose::Meta::Method::Constructor> is a subclass of
 371 L<Moose::Meta::Method> I<and> L<Class::MOP::Method::Constructor>.
 372
 373 =head1 BUGS
 374
 375 See L<Moose/BUGS> for details on reporting bugs.
 376
 377 =head1 AUTHORS
 378
 379 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 380
 381 =head1 COPYRIGHT AND LICENSE
 382
 383 Copyright 2006-2010 by Infinity Interactive, Inc.
 384
 385 L<http://www.iinteractive.com>
 386
 387 This library is free software; you can redistribute it and/or modify
 388 it under the same terms as Perl itself.
 389
 390 =cut
 391