lib/Moose/Meta/Method/Accessor/Native/Hash/set.pm

   1 package Moose::Meta::Method::Accessor::Native::Hash::set;
   2
   3 use strict;
   4 use warnings;
   5
   6 use List::MoreUtils ();
   7 use Scalar::Util qw( looks_like_number );
   8
   9 use Moose::Role;
  10
  11 with 'Moose::Meta::Method::Accessor::Native::Hash::Writer' => {
  12     -excludes => [
  13         qw(
  14             _minimum_arguments
  15             _maximum_arguments
  16             _inline_process_arguments
  17             _inline_check_arguments
  18             _inline_coerce_new_values
  19             _inline_optimized_set_new_value
  20             _return_value
  21             )
  22     ],
  23 };
  24
  25 sub _minimum_arguments { 2 }
  26
  27 sub _maximum_arguments { undef }
  28
  29 around _inline_check_argument_count => sub {
  30     my $orig = shift;
  31     my $self = shift;
  32
  33     return (
  34         $self->$orig(@_),
  35         'if (@_ % 2) {',
  36             $self->_inline_throw_error(
  37                 sprintf(
  38                     '"You must pass an even number of arguments to %s"',
  39                     $self->delegate_to_method,
  40                 ),
  41             ) . ';',
  42         '}',
  43     );
  44 };
  45
  46 sub _inline_process_arguments {
  47     my $self = shift;
  48
  49     return (
  50         'my @keys_idx = grep { ! ($_ % 2) } 0..$#_;',
  51         'my @values_idx = grep { $_ % 2 } 0..$#_;',
  52     );
  53 }
  54
  55 sub _inline_check_arguments {
  56     my $self = shift;
  57
  58     return (
  59         'for (@keys_idx) {',
  60             'if (!defined($_[$_])) {',
  61                 $self->_inline_throw_error(
  62                     sprintf(
  63                         '"Hash keys passed to %s must be defined"',
  64                         $self->delegate_to_method,
  65                     ),
  66                 ) . ';',
  67             '}',
  68         '}',
  69     );
  70 }
  71
  72 sub _adds_members { 1 }
  73
  74 # We need to override this because while @_ can be written to, we cannot write
  75 # directly to $_[1].
  76 sub _inline_coerce_new_values {
  77     my $self = shift;
  78
  79     return unless $self->associated_attribute->should_coerce;
  80
  81     return unless $self->_tc_member_type_can_coerce;
  82
  83     # Is there a simpler way to do this?
  84     return (
  85         'my $iter = List::MoreUtils::natatime(2, @_);',
  86         '@_ = ();',
  87         'while (my ($key, $val) = $iter->()) {',
  88             'push @_, $key, $member_coercion->($val);',
  89         '}',
  90     );
  91 };
  92
  93 sub _potential_value {
  94     my $self = shift;
  95     my ($slot_access) = @_;
  96
  97     return '{ %{ (' . $slot_access . ') }, @_ }';
  98 }
  99
 100 sub _new_members { '@_[ @values_idx ]' }
 101
 102 sub _inline_optimized_set_new_value {
 103     my $self = shift;
 104     my ($inv, $new, $slot_access) = @_;
 105
 106     return '@{ (' . $slot_access . ') }{ @_[@keys_idx] } = @_[@values_idx];';
 107 }
 108
 109 sub _return_value {
 110     my $self = shift;
 111     my ($slot_access) = @_;
 112
 113     return 'wantarray '
 114              . '? @{ (' . $slot_access . ') }{ @_[@keys_idx] } '
 115              . ': ' . $slot_access . '->{ $_[$keys_idx[0]] }';
 116 }
 117
 118 no Moose::Role;
 119
 120 1;