lib/Moose/Meta/Method/Accessor.pm

   1
   2 package Moose::Meta::Method::Accessor;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION   = '1.09';
   8 $VERSION = eval $VERSION;
   9 our $AUTHORITY = 'cpan:STEVAN';
  10
  11 use base 'Moose::Meta::Method',
  12          'Class::MOP::Method::Accessor';
  13
  14 sub _error_thrower {
  15     my $self = shift;
  16     ( ref $self && $self->associated_attribute ) || $self->SUPER::_error_thrower();
  17 }
  18
  19 sub _eval_code {
  20     my ( $self, $source ) = @_;
  21
  22     # NOTE:
  23     # set up the environment
  24     my $attr = $self->associated_attribute;
  25     my $type_constraint_obj = $attr->type_constraint;
  26     my $environment = {
  27         '$attr' => \$attr,
  28         '$meta' => \$self,
  29         '$type_constraint_obj' => \$type_constraint_obj,
  30         '$type_constraint' => \($type_constraint_obj
  31                                    ? $type_constraint_obj->_compiled_type_constraint
  32                                    : undef),
  33     };
  34
  35     #warn "code for " . $attr->name . " =>\n" . $source . "\n";
  36     my ( $code, $e ) = $self->_compile_code( environment => $environment, code => $source );
  37
  38     $self->throw_error(
  39         "Could not create writer for '${\$self->associated_attribute->name}' because $e \n code: $source",
  40         error => $e, data => $source )
  41         if $e;
  42
  43     return $code;
  44 }
  45
  46 sub _generate_accessor_method_inline {
  47     my $self        = $_[0];
  48     my $attr        = $self->associated_attribute;
  49     my $inv         = '$_[0]';
  50     my $value_name  = $self->_value_needs_copy ? '$val' : '$_[1]';
  51
  52     $self->_eval_code('sub { ' . "\n"
  53     . $self->_inline_pre_body(@_) . "\n"
  54     . 'if (scalar(@_) >= 2) {' . "\n"
  55         . $self->_inline_copy_value . "\n"
  56         . $self->_inline_check_required . "\n"
  57         . $self->_inline_check_coercion($value_name) . "\n"
  58         . $self->_inline_check_constraint($value_name) . "\n"
  59         . $self->_inline_get_old_value_for_trigger($inv, $value_name) . "\n"
  60         . $self->_inline_store($inv, $value_name) . "\n"
  61         . $self->_inline_trigger($inv, $value_name, '@old') . "\n"
  62     . ' }' . "\n"
  63     . $self->_inline_check_lazy($inv) . "\n"
  64     . $self->_inline_post_body(@_) . "\n"
  65     . 'return ' . $self->_inline_auto_deref($self->_inline_get($inv)) . "\n"
  66     . ' }');
  67 }
  68
  69 sub _generate_writer_method_inline {
  70     my $self        = $_[0];
  71     my $attr        = $self->associated_attribute;
  72     my $inv         = '$_[0]';
  73     my $slot_access = $self->_inline_get($inv);
  74     my $value_name  = $self->_value_needs_copy ? '$val' : '$_[1]';
  75
  76     $self->_eval_code('sub { '
  77     . $self->_inline_pre_body(@_)
  78     . $self->_inline_copy_value
  79     . $self->_inline_check_required
  80     . $self->_inline_check_coercion($value_name)
  81     . $self->_inline_check_constraint($value_name)
  82     . $self->_inline_get_old_value_for_trigger($inv, $value_name) . "\n"
  83     . $self->_inline_store($inv, $value_name)
  84     . $self->_inline_post_body(@_)
  85     . $self->_inline_trigger($inv, $value_name, '@old')
  86     . ' }');
  87 }
  88
  89 sub _generate_reader_method_inline {
  90     my $self        = $_[0];
  91     my $attr        = $self->associated_attribute;
  92     my $inv         = '$_[0]';
  93     my $slot_access = $self->_inline_get($inv);
  94
  95     $self->_eval_code('sub {'
  96     . $self->_inline_pre_body(@_)
  97     . $self->_inline_throw_error('"Cannot assign a value to a read-only accessor"', 'data => \@_') . ' if @_ > 1;'
  98     . $self->_inline_check_lazy($inv)
  99     . $self->_inline_post_body(@_)
 100     . 'return ' . $self->_inline_auto_deref( $slot_access ) . ';'
 101     . '}');
 102 }
 103
 104 sub _inline_copy_value {
 105     return '' unless shift->_value_needs_copy;
 106     return 'my $val = $_[1];'
 107 }
 108
 109 sub _value_needs_copy {
 110     my $attr = (shift)->associated_attribute;
 111     return $attr->should_coerce;
 112 }
 113
 114 sub _instance_is_inlinable {
 115     my $self = shift;
 116     return $self->associated_attribute->associated_class->instance_metaclass->is_inlinable;
 117 }
 118
 119 sub _generate_reader_method {
 120     my $self = shift;
 121     $self->_instance_is_inlinable ? $self->_generate_reader_method_inline(@_)
 122                                   : $self->SUPER::_generate_reader_method(@_);
 123 }
 124
 125 sub _generate_writer_method {
 126     my $self = shift;
 127     $self->_instance_is_inlinable ? $self->_generate_writer_method_inline(@_)
 128                                   : $self->SUPER::_generate_writer_method(@_);
 129 }
 130
 131 sub _generate_accessor_method {
 132     my $self = shift;
 133     $self->_instance_is_inlinable ? $self->_generate_accessor_method_inline(@_)
 134                                   : $self->SUPER::_generate_accessor_method(@_);
 135 }
 136
 137 sub _generate_predicate_method {
 138     my $self = shift;
 139     $self->_instance_is_inlinable ? $self->_generate_predicate_method_inline(@_)
 140                                   : $self->SUPER::_generate_predicate_method(@_);
 141 }
 142
 143 sub _generate_clearer_method {
 144     my $self = shift;
 145     $self->_instance_is_inlinable ? $self->_generate_clearer_method_inline(@_)
 146                                   : $self->SUPER::_generate_clearer_method(@_);
 147 }
 148
 149 sub _inline_pre_body  { '' }
 150 sub _inline_post_body { '' }
 151
 152 sub _inline_check_constraint {
 153     my ($self, $value) = @_;
 154
 155     my $attr = $self->associated_attribute;
 156
 157     return '' unless $attr->has_type_constraint;
 158
 159     my $attr_name = quotemeta( $attr->name );
 160
 161     qq{\$type_constraint->($value) || } . $self->_inline_throw_error(qq{"Attribute ($attr_name) does not pass the type constraint because: " . \$type_constraint_obj->get_message($value)}, "data => $value") . ";";
 162 }
 163
 164 sub _inline_check_coercion {
 165     my ($self, $value) = @_;
 166
 167     my $attr = $self->associated_attribute;
 168
 169     return '' unless $attr->should_coerce && $attr->type_constraint->has_coercion;
 170     return "$value = \$attr->type_constraint->coerce($value);";
 171 }
 172
 173 sub _inline_check_required {
 174     my $self = shift;
 175     my $attr = $self->associated_attribute;
 176
 177     return '' unless $attr->is_required;
 178
 179     my $attr_name = quotemeta( $attr->name );
 180
 181     return qq{(\@_ >= 2) || } . $self->_inline_throw_error(qq{"Attribute ($attr_name) is required, so cannot be set to undef"}) . ';' # defined $_[1] is not good enough
 182 }
 183
 184 sub _inline_check_lazy {
 185     my ($self, $instance) = @_;
 186
 187     my $attr = $self->associated_attribute;
 188
 189     return '' unless $attr->is_lazy;
 190
 191     my $slot_exists = $self->_inline_has($instance);
 192
 193     my $code = 'unless (' . $slot_exists . ') {' . "\n";
 194     if ($attr->has_type_constraint) {
 195         if ($attr->has_default || $attr->has_builder) {
 196             if ($attr->has_default) {
 197                 $code .= '    my $default = $attr->default(' . $instance . ');'."\n";
 198             }
 199             elsif ($attr->has_builder) {
 200                 $code .= '    my $default;'."\n".
 201                          '    if(my $builder = '.$instance.'->can($attr->builder)){ '."\n".
 202                          '        $default = '.$instance.'->$builder; '. "\n    } else {\n" .
 203                          '        ' . $self->_inline_throw_error(q{sprintf "%s does not support builder method '%s' for attribute '%s'", ref(} . $instance . ') || '.$instance.', $attr->builder, $attr->name') .
 204                          ';'. "\n    }";
 205             }
 206             $code .= $self->_inline_check_coercion('$default') . "\n";
 207             $code .= $self->_inline_check_constraint('$default') . "\n";
 208             $code .= '    ' . $self->_inline_init_slot($attr, $instance, '$default') . "\n";
 209         }
 210         else {
 211             $code .= '    ' . $self->_inline_init_slot($attr, $instance, 'undef') . "\n";
 212         }
 213
 214     } else {
 215         if ($attr->has_default) {
 216             $code .= '    ' . $self->_inline_init_slot($attr, $instance, ('$attr->default(' . $instance . ')')) . "\n";
 217         }
 218         elsif ($attr->has_builder) {
 219             $code .= '    if (my $builder = '.$instance.'->can($attr->builder)) { ' . "\n"
 220                   .  '       ' . $self->_inline_init_slot($attr, $instance, ($instance . '->$builder'))
 221                   .  "\n    } else {\n"
 222                   .  '        ' . $self->_inline_throw_error(q{sprintf "%s does not support builder method '%s' for attribute '%s'", ref(} . $instance . ') || '.$instance.', $attr->builder, $attr->name')
 223                   .  ';'. "\n    }";
 224         }
 225         else {
 226             $code .= '    ' . $self->_inline_init_slot($attr, $instance, 'undef') . "\n";
 227         }
 228     }
 229     $code .= "}\n";
 230     return $code;
 231 }
 232
 233 sub _inline_init_slot {
 234     my ($self, $attr, $inv, $value) = @_;
 235     if ($attr->has_initializer) {
 236         return ('$attr->set_initial_value(' . $inv . ', ' . $value . ');');
 237     }
 238     else {
 239         return $self->_inline_store($inv, $value);
 240     }
 241 }
 242
 243 sub _inline_store {
 244     my ($self, $instance, $value) = @_;
 245     my $attr = $self->associated_attribute;
 246
 247     my $mi = $attr->associated_class->get_meta_instance;
 248
 249     my $code = $mi->inline_set_slot_value($instance, $attr->slots, $value)    . ";";
 250     $code   .= $mi->inline_weaken_slot_value($instance, $attr->slots, $value) . ";"
 251         if $attr->is_weak_ref;
 252     return $code;
 253 }
 254
 255 sub _inline_get_old_value_for_trigger {
 256     my ( $self, $instance ) = @_;
 257
 258     my $attr = $self->associated_attribute;
 259     return '' unless $attr->has_trigger;
 260
 261     my $mi = $attr->associated_class->get_meta_instance;
 262     my $pred = $mi->inline_is_slot_initialized($instance, $attr->name);
 263
 264     return
 265           'my @old = '
 266         . $pred . q{ ? }
 267         . $self->_inline_get($instance) . q{ : ()} . ";\n";
 268 }
 269
 270 sub _inline_trigger {
 271     my ($self, $instance, $value, $old_value) = @_;
 272     my $attr = $self->associated_attribute;
 273     return '' unless $attr->has_trigger;
 274     return sprintf('$attr->trigger->(%s, %s, %s);', $instance, $value, $old_value);
 275 }
 276
 277 sub _inline_get {
 278     my ($self, $instance) = @_;
 279     my $attr = $self->associated_attribute;
 280
 281     my $mi = $attr->associated_class->get_meta_instance;
 282
 283     return $mi->inline_get_slot_value($instance, $attr->slots);
 284 }
 285
 286 sub _inline_access {
 287     my ($self, $instance) = @_;
 288     my $attr = $self->associated_attribute;
 289
 290     my $mi = $attr->associated_class->get_meta_instance;
 291
 292     return $mi->inline_slot_access($instance, $attr->slots);
 293 }
 294
 295 sub _inline_has {
 296     my ($self, $instance) = @_;
 297     my $attr = $self->associated_attribute;
 298
 299     my $mi = $attr->associated_class->get_meta_instance;
 300
 301     return $mi->inline_is_slot_initialized($instance, $attr->slots);
 302 }
 303
 304 sub _inline_auto_deref {
 305     my ( $self, $ref_value ) = @_;
 306         my $attr = $self->associated_attribute;
 307
 308     return $ref_value unless $attr->should_auto_deref;
 309
 310     my $type_constraint = $attr->type_constraint;
 311
 312     my $sigil;
 313     if ($type_constraint->is_a_type_of('ArrayRef')) {
 314         $sigil = '@';
 315     }
 316     elsif ($type_constraint->is_a_type_of('HashRef')) {
 317         $sigil = '%';
 318     }
 319     else {
 320         $self->throw_error( "Can not auto de-reference the type constraint '"
 321                 . quotemeta( $type_constraint->name )
 322                 . "'", type_constraint => $type_constraint );
 323     }
 324
 325     "(wantarray() ? $sigil\{ ( $ref_value ) || return } : ( $ref_value ) )";
 326 }
 327
 328 1;
 329
 330 __END__
 331
 332 =pod
 333
 334 =head1 NAME
 335
 336 Moose::Meta::Method::Accessor - A Moose Method metaclass for accessors
 337
 338 =head1 DESCRIPTION
 339
 340 This class is a subclass of L<Class::MOP::Method::Accessor> that
 341 provides additional Moose-specific functionality, all of which is
 342 private.
 343
 344 To understand this class, you should read the the
 345 L<Class::MOP::Method::Accessor> documentation.
 346
 347 =head1 BUGS
 348
 349 See L<Moose/BUGS> for details on reporting bugs.
 350
 351 =head1 AUTHOR
 352
 353 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 354
 355 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
 356
 357 =head1 COPYRIGHT AND LICENSE
 358
 359 Copyright 2006-2010 by Infinity Interactive, Inc.
 360
 361 L<http://www.iinteractive.com>
 362
 363 This library is free software; you can redistribute it and/or modify
 364 it under the same terms as Perl itself.
 365
 366 =cut