lib/Moose/Meta/Method/Accessor.pm

   1
   2 package Moose::Meta::Method::Accessor;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION   = '1.25';
   8 $VERSION = eval $VERSION;
   9 our $AUTHORITY = 'cpan:STEVAN';
  10
  11 use base 'Moose::Meta::Method',
  12          'Class::MOP::Method::Accessor';
  13
  14 sub _error_thrower {
  15     my $self = shift;
  16     ( ref $self && $self->associated_attribute ) || $self->SUPER::_error_thrower();
  17 }
  18
  19 sub _eval_code {
  20     my ( $self, $source ) = @_;
  21
  22     my $environment = $self->_eval_environment;
  23
  24     my ( $code, $e ) = $self->_compile_code( environment => $environment, code => $source );
  25
  26     $self->throw_error(
  27         "Could not create writer for '${\$self->associated_attribute->name}' because $e \n code: $source",
  28         error => $e, data => $source )
  29         if $e;
  30
  31     return $code;
  32 }
  33
  34 sub _eval_environment {
  35     my $self = shift;
  36
  37     my $attr                = $self->associated_attribute;
  38     my $type_constraint_obj = $attr->type_constraint;
  39
  40     return {
  41         '$attr'                => \$attr,
  42         '$meta'                => \$self,
  43         '$type_constraint_obj' => \$type_constraint_obj,
  44         '$type_constraint'     => \(
  45               $type_constraint_obj
  46             ? $type_constraint_obj->_compiled_type_constraint
  47             : undef
  48         ),
  49     };
  50 }
  51
  52 sub _generate_accessor_method_inline {
  53     my $self        = $_[0];
  54     my $inv         = '$_[0]';
  55     my $value_name  = $self->_value_needs_copy ? '$val' : '$_[1]';
  56
  57     $self->_eval_code('sub { ' . "\n"
  58     . $self->_inline_pre_body(@_) . "\n"
  59     . 'if (scalar(@_) >= 2) {' . "\n"
  60         . $self->_inline_copy_value . "\n"
  61         . $self->_inline_check_required . "\n"
  62         . $self->_inline_check_coercion($value_name) . "\n"
  63         . $self->_inline_check_constraint($value_name) . "\n"
  64         . $self->_inline_get_old_value_for_trigger($inv, $value_name) . "\n"
  65         . $self->_inline_store($inv, $value_name) . "\n"
  66         . $self->_inline_trigger($inv, $value_name, '@old') . "\n"
  67     . ' }' . "\n"
  68     . $self->_inline_check_lazy($inv) . "\n"
  69     . $self->_inline_post_body(@_) . "\n"
  70     . 'return ' . $self->_inline_auto_deref($self->_inline_get($inv)) . "\n"
  71     . ' }');
  72 }
  73
  74 sub _generate_writer_method_inline {
  75     my $self        = $_[0];
  76     my $inv         = '$_[0]';
  77     my $value_name  = $self->_value_needs_copy ? '$val' : '$_[1]';
  78
  79     $self->_eval_code('sub { '
  80     . $self->_inline_pre_body(@_)
  81     . $self->_inline_copy_value
  82     . $self->_inline_check_required
  83     . $self->_inline_check_coercion($value_name)
  84     . $self->_inline_check_constraint($value_name)
  85     . $self->_inline_get_old_value_for_trigger($inv, $value_name) . "\n"
  86     . $self->_inline_store($inv, $value_name)
  87     . $self->_inline_post_body(@_)
  88     . $self->_inline_trigger($inv, $value_name, '@old')
  89     . ' }');
  90 }
  91
  92 sub _generate_reader_method_inline {
  93     my $self        = $_[0];
  94     my $inv         = '$_[0]';
  95     my $slot_access = $self->_inline_get($inv);
  96
  97     $self->_eval_code('sub {'
  98     . $self->_inline_pre_body(@_)
  99     . $self->_inline_throw_error('"Cannot assign a value to a read-only accessor"', 'data => \@_') . ' if @_ > 1;'
 100     . $self->_inline_check_lazy($inv)
 101     . $self->_inline_post_body(@_)
 102     . 'return ' . $self->_inline_auto_deref( $slot_access ) . ';'
 103     . '}');
 104 }
 105
 106 sub _inline_copy_value {
 107     return '' unless shift->_value_needs_copy;
 108     return 'my $val = $_[1];'
 109 }
 110
 111 sub _value_needs_copy {
 112     my $attr = (shift)->associated_attribute;
 113     return $attr->should_coerce;
 114 }
 115
 116 sub _instance_is_inlinable {
 117     my $self = shift;
 118     return $self->associated_attribute->associated_class->instance_metaclass->is_inlinable;
 119 }
 120
 121 sub _generate_reader_method {
 122     my $self = shift;
 123     $self->_instance_is_inlinable ? $self->_generate_reader_method_inline(@_)
 124                                   : $self->SUPER::_generate_reader_method(@_);
 125 }
 126
 127 sub _generate_writer_method {
 128     my $self = shift;
 129     $self->_instance_is_inlinable ? $self->_generate_writer_method_inline(@_)
 130                                   : $self->SUPER::_generate_writer_method(@_);
 131 }
 132
 133 sub _generate_accessor_method {
 134     my $self = shift;
 135     $self->_instance_is_inlinable ? $self->_generate_accessor_method_inline(@_)
 136                                   : $self->SUPER::_generate_accessor_method(@_);
 137 }
 138
 139 sub _generate_predicate_method {
 140     my $self = shift;
 141     $self->_instance_is_inlinable ? $self->_generate_predicate_method_inline(@_)
 142                                   : $self->SUPER::_generate_predicate_method(@_);
 143 }
 144
 145 sub _generate_clearer_method {
 146     my $self = shift;
 147     $self->_instance_is_inlinable ? $self->_generate_clearer_method_inline(@_)
 148                                   : $self->SUPER::_generate_clearer_method(@_);
 149 }
 150
 151 sub _inline_pre_body  { '' }
 152 sub _inline_post_body { '' }
 153
 154 sub _inline_check_constraint {
 155     my ($self, $value) = @_;
 156
 157     my $attr = $self->associated_attribute;
 158
 159     return '' unless $attr->has_type_constraint;
 160
 161     my $attr_name = quotemeta( $attr->name );
 162
 163     qq{\$type_constraint->($value) || } . $self->_inline_throw_error(qq{"Attribute ($attr_name) does not pass the type constraint because: " . \$type_constraint_obj->get_message($value)}, "data => $value") . ";";
 164 }
 165
 166 sub _inline_check_coercion {
 167     my ($self, $value) = @_;
 168
 169     my $attr = $self->associated_attribute;
 170
 171     return '' unless $attr->should_coerce && $attr->type_constraint->has_coercion;
 172     return "$value = \$attr->type_constraint->coerce($value);";
 173 }
 174
 175 sub _inline_check_required {
 176     my $self = shift;
 177     my $attr = $self->associated_attribute;
 178
 179     return '' unless $attr->is_required;
 180
 181     my $attr_name = quotemeta( $attr->name );
 182
 183     return qq{(\@_ >= 2) || } . $self->_inline_throw_error(qq{"Attribute ($attr_name) is required, so cannot be set to undef"}) . ';' # defined $_[1] is not good enough
 184 }
 185
 186 sub _inline_check_lazy {
 187     my ($self, $instance) = @_;
 188
 189     my $attr = $self->associated_attribute;
 190
 191     return '' unless $attr->is_lazy;
 192
 193     my $slot_exists = $self->_inline_has($instance);
 194
 195     my $code = 'unless (' . $slot_exists . ') {' . "\n";
 196     if ($attr->has_type_constraint) {
 197         if ($attr->has_default || $attr->has_builder) {
 198             if ($attr->has_default) {
 199                 $code .= '    my $default = $attr->default(' . $instance . ');'."\n";
 200             }
 201             elsif ($attr->has_builder) {
 202                 $code .= '    my $default;'."\n".
 203                          '    if(my $builder = '.$instance.'->can($attr->builder)){ '."\n".
 204                          '        $default = '.$instance.'->$builder; '. "\n    } else {\n" .
 205                          '        ' . $self->_inline_throw_error(q{sprintf "%s does not support builder method '%s' for attribute '%s'", ref(} . $instance . ') || '.$instance.', $attr->builder, $attr->name') .
 206                          ';'. "\n    }";
 207             }
 208             $code .= $self->_inline_check_coercion('$default') . "\n";
 209             $code .= $self->_inline_check_constraint('$default', 'lazy') . "\n";
 210             $code .= '    ' . $self->_inline_init_slot($attr, $instance, '$default') . "\n";
 211         }
 212         else {
 213             $code .= '    ' . $self->_inline_init_slot($attr, $instance, 'undef') . "\n";
 214         }
 215
 216     } else {
 217         if ($attr->has_default) {
 218             $code .= '    ' . $self->_inline_init_slot($attr, $instance, ('$attr->default(' . $instance . ')')) . "\n";
 219         }
 220         elsif ($attr->has_builder) {
 221             $code .= '    if (my $builder = '.$instance.'->can($attr->builder)) { ' . "\n"
 222                   .  '       ' . $self->_inline_init_slot($attr, $instance, ($instance . '->$builder'))
 223                   .  "\n    } else {\n"
 224                   .  '        ' . $self->_inline_throw_error(q{sprintf "%s does not support builder method '%s' for attribute '%s'", ref(} . $instance . ') || '.$instance.', $attr->builder, $attr->name')
 225                   .  ';'. "\n    }";
 226         }
 227         else {
 228             $code .= '    ' . $self->_inline_init_slot($attr, $instance, 'undef') . "\n";
 229         }
 230     }
 231     $code .= "}\n";
 232     return $code;
 233 }
 234
 235 sub _inline_init_slot {
 236     my ($self, $attr, $inv, $value) = @_;
 237     if ($attr->has_initializer) {
 238         return ('$attr->set_initial_value(' . $inv . ', ' . $value . ');');
 239     }
 240     else {
 241         return $self->_inline_store($inv, $value);
 242     }
 243 }
 244
 245 sub _inline_store {
 246     my ( $self, $instance, $value ) = @_;
 247
 248     return $self->associated_attribute->inline_set( $instance, $value );
 249 }
 250
 251 sub _inline_get_old_value_for_trigger {
 252     my ( $self, $instance ) = @_;
 253
 254     my $attr = $self->associated_attribute;
 255     return '' unless $attr->has_trigger;
 256
 257     return
 258           'my @old = '
 259         . $self->_inline_has($instance) . q{ ? }
 260         . $self->_inline_get($instance) . q{ : ()} . ";\n";
 261 }
 262
 263 sub _inline_trigger {
 264     my ($self, $instance, $value, $old_value) = @_;
 265     my $attr = $self->associated_attribute;
 266     return '' unless $attr->has_trigger;
 267     return sprintf('$attr->trigger->(%s, %s, %s);', $instance, $value, $old_value);
 268 }
 269
 270 sub _inline_get {
 271     my ($self, $instance) = @_;
 272
 273     return $self->associated_attribute->inline_get($instance);
 274 }
 275
 276 sub _inline_has {
 277     my ($self, $instance) = @_;
 278
 279     return $self->associated_attribute->inline_has($instance);
 280 }
 281
 282 sub _inline_auto_deref {
 283     my ( $self, $ref_value ) = @_;
 284         my $attr = $self->associated_attribute;
 285
 286     return $ref_value unless $attr->should_auto_deref;
 287
 288     my $type_constraint = $attr->type_constraint;
 289
 290     my $sigil;
 291     if ($type_constraint->is_a_type_of('ArrayRef')) {
 292         $sigil = '@';
 293     }
 294     elsif ($type_constraint->is_a_type_of('HashRef')) {
 295         $sigil = '%';
 296     }
 297     else {
 298         $self->throw_error( "Can not auto de-reference the type constraint '"
 299                 . quotemeta( $type_constraint->name )
 300                 . "'", type_constraint => $type_constraint );
 301     }
 302
 303     "(wantarray() ? $sigil\{ ( $ref_value ) || return } : ( $ref_value ) )";
 304 }
 305
 306 1;
 307
 308 __END__
 309
 310 =pod
 311
 312 =head1 NAME
 313
 314 Moose::Meta::Method::Accessor - A Moose Method metaclass for accessors
 315
 316 =head1 DESCRIPTION
 317
 318 This class is a subclass of L<Class::MOP::Method::Accessor> that
 319 provides additional Moose-specific functionality, all of which is
 320 private.
 321
 322 To understand this class, you should read the the
 323 L<Class::MOP::Method::Accessor> documentation.
 324
 325 =head1 BUGS
 326
 327 See L<Moose/BUGS> for details on reporting bugs.
 328
 329 =head1 AUTHOR
 330
 331 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 332
 333 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
 334
 335 =head1 COPYRIGHT AND LICENSE
 336
 337 Copyright 2006-2010 by Infinity Interactive, Inc.
 338
 339 L<http://www.iinteractive.com>
 340
 341 This library is free software; you can redistribute it and/or modify
 342 it under the same terms as Perl itself.
 343
 344 =cut