lib/Moose/Meta/Attribute.pm

   1
   2 package Moose::Meta::Attribute;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::MOP ();
   8 use Scalar::Util 'blessed', 'weaken';
   9 use List::MoreUtils 'any';
  10 use Try::Tiny;
  11 use overload     ();
  12
  13 our $VERSION   = '1.17';
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 use Moose::Deprecated;
  17 use Moose::Meta::Method::Accessor;
  18 use Moose::Meta::Method::Delegation;
  19 use Moose::Util ();
  20 use Moose::Util::TypeConstraints ();
  21 use Class::MOP::MiniTrait;
  22
  23 use base 'Class::MOP::Attribute', 'Moose::Meta::Mixin::AttributeCore';
  24
  25 Class::MOP::MiniTrait::apply(__PACKAGE__, 'Moose::Meta::Object::Trait');
  26
  27 __PACKAGE__->meta->add_attribute('traits' => (
  28     reader    => 'applied_traits',
  29     predicate => 'has_applied_traits',
  30 ));
  31
  32 # we need to have a ->does method in here to
  33 # more easily support traits, and the introspection
  34 # of those traits. We extend the does check to look
  35 # for metatrait aliases.
  36 sub does {
  37     my ($self, $role_name) = @_;
  38     my $name = try {
  39         Moose::Util::resolve_metatrait_alias(Attribute => $role_name)
  40     };
  41     return 0 if !defined($name); # failed to load class
  42     return $self->Moose::Object::does($name);
  43 }
  44
  45 sub throw_error {
  46     my $self = shift;
  47     my $class = ( ref $self && $self->associated_class ) || "Moose::Meta::Class";
  48     unshift @_, "message" if @_ % 2 == 1;
  49     unshift @_, attr => $self if ref $self;
  50     unshift @_, $class;
  51     my $handler = $class->can("throw_error"); # to avoid incrementing depth by 1
  52     goto $handler;
  53 }
  54
  55 sub new {
  56     my ($class, $name, %options) = @_;
  57     $class->_process_options($name, \%options) unless $options{__hack_no_process_options}; # used from clone()... YECHKKK FIXME ICKY YUCK GROSS
  58
  59     delete $options{__hack_no_process_options};
  60
  61     my %attrs =
  62         ( map { $_ => 1 }
  63           grep { defined }
  64           map { $_->init_arg() }
  65           $class->meta()->get_all_attributes()
  66         );
  67
  68     my @bad = sort grep { ! $attrs{$_} }  keys %options;
  69
  70     if (@bad)
  71     {
  72         Carp::cluck "Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad";
  73     }
  74
  75     return $class->SUPER::new($name, %options);
  76 }
  77
  78 sub interpolate_class_and_new {
  79     my ($class, $name, %args) = @_;
  80
  81     my ( $new_class, @traits ) = $class->interpolate_class(\%args);
  82
  83     $new_class->new($name, %args, ( scalar(@traits) ? ( traits => \@traits ) : () ) );
  84 }
  85
  86 sub interpolate_class {
  87     my ($class, $options) = @_;
  88
  89     $class = ref($class) || $class;
  90
  91     if ( my $metaclass_name = delete $options->{metaclass} ) {
  92         my $new_class = Moose::Util::resolve_metaclass_alias( Attribute => $metaclass_name );
  93
  94         if ( $class ne $new_class ) {
  95             if ( $new_class->can("interpolate_class") ) {
  96                 return $new_class->interpolate_class($options);
  97             } else {
  98                 $class = $new_class;
  99             }
 100         }
 101     }
 102
 103     my @traits;
 104
 105     if (my $traits = $options->{traits}) {
 106         my $i = 0;
 107         while ($i < @$traits) {
 108             my $trait = $traits->[$i++];
 109             next if ref($trait); # options to a trait we discarded
 110
 111             $trait = Moose::Util::resolve_metatrait_alias(Attribute => $trait)
 112                   || $trait;
 113
 114             next if $class->does($trait);
 115
 116             push @traits, $trait;
 117
 118             # are there options?
 119             push @traits, $traits->[$i++]
 120                 if $traits->[$i] && ref($traits->[$i]);
 121         }
 122
 123         if (@traits) {
 124             my $anon_class = Moose::Meta::Class->create_anon_class(
 125                 superclasses => [ $class ],
 126                 roles        => [ @traits ],
 127                 cache        => 1,
 128             );
 129
 130             $class = $anon_class->name;
 131         }
 132     }
 133
 134     return ( wantarray ? ( $class, @traits ) : $class );
 135 }
 136
 137 # ...
 138
 139 # method-generating options shouldn't be overridden
 140 sub illegal_options_for_inheritance {
 141     qw(reader writer accessor clearer predicate)
 142 }
 143
 144 # NOTE/TODO
 145 # This method *must* be able to handle
 146 # Class::MOP::Attribute instances as
 147 # well. Yes, I know that is wrong, but
 148 # apparently we didn't realize it was
 149 # doing that and now we have some code
 150 # which is dependent on it. The real
 151 # solution of course is to push this
 152 # feature back up into Class::MOP::Attribute
 153 # but I not right now, I am too lazy.
 154 # However if you are reading this and
 155 # looking for something to do,.. please
 156 # be my guest.
 157 # - stevan
 158 sub clone_and_inherit_options {
 159     my ($self, %options) = @_;
 160
 161     # NOTE:
 162     # we may want to extends a Class::MOP::Attribute
 163     # in which case we need to be able to use the
 164     # core set of legal options that have always
 165     # been here. But we allows Moose::Meta::Attribute
 166     # instances to changes them.
 167     # - SL
 168     my @illegal_options = $self->can('illegal_options_for_inheritance')
 169         ? $self->illegal_options_for_inheritance
 170         : ();
 171
 172     my @found_illegal_options = grep { exists $options{$_} && exists $self->{$_} ? $_ : undef } @illegal_options;
 173     (scalar @found_illegal_options == 0)
 174         || $self->throw_error("Illegal inherited options => (" . (join ', ' => @found_illegal_options) . ")", data => \%options);
 175
 176     if ($options{isa}) {
 177         my $type_constraint;
 178         if (blessed($options{isa}) && $options{isa}->isa('Moose::Meta::TypeConstraint')) {
 179             $type_constraint = $options{isa};
 180         }
 181         else {
 182             $type_constraint = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options{isa});
 183             (defined $type_constraint)
 184                 || $self->throw_error("Could not find the type constraint '" . $options{isa} . "'", data => $options{isa});
 185         }
 186
 187         $options{type_constraint} = $type_constraint;
 188     }
 189
 190     if ($options{does}) {
 191         my $type_constraint;
 192         if (blessed($options{does}) && $options{does}->isa('Moose::Meta::TypeConstraint')) {
 193             $type_constraint = $options{does};
 194         }
 195         else {
 196             $type_constraint = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options{does});
 197             (defined $type_constraint)
 198                 || $self->throw_error("Could not find the type constraint '" . $options{does} . "'", data => $options{does});
 199         }
 200
 201         $options{type_constraint} = $type_constraint;
 202     }
 203
 204     # NOTE:
 205     # this doesn't apply to Class::MOP::Attributes,
 206     # so we can ignore it for them.
 207     # - SL
 208     if ($self->can('interpolate_class')) {
 209         ( $options{metaclass}, my @traits ) = $self->interpolate_class(\%options);
 210
 211         my %seen;
 212         my @all_traits = grep { $seen{$_}++ } @{ $self->applied_traits || [] }, @traits;
 213         $options{traits} = \@all_traits if @all_traits;
 214     }
 215
 216     $self->_modify_attr_options_for_lazy_build( $self->name, \%options );
 217
 218     $self->clone(%options);
 219 }
 220
 221 sub clone {
 222     my ( $self, %params ) = @_;
 223
 224     my $class = delete $params{metaclass} || ref $self;
 225
 226     my ( @init, @non_init );
 227
 228     foreach my $attr ( grep { $_->has_value($self) } Class::MOP::class_of($self)->get_all_attributes ) {
 229         push @{ $attr->has_init_arg ? \@init : \@non_init }, $attr;
 230     }
 231
 232     my %new_params = ( ( map { $_->init_arg => $_->get_value($self) } @init ), %params );
 233
 234     my $name = delete $new_params{name};
 235
 236     my $clone = $class->new($name, %new_params, __hack_no_process_options => 1 );
 237
 238     foreach my $attr ( @non_init ) {
 239         $attr->set_value($clone, $attr->get_value($self));
 240     }
 241
 242     return $clone;
 243 }
 244
 245 sub _process_options {
 246     my ($class, $name, $options) = @_;
 247
 248     if (exists $options->{is}) {
 249
 250         ### -------------------------
 251         ## is => ro, writer => _foo    # turns into (reader => foo, writer => _foo) as before
 252         ## is => rw, writer => _foo    # turns into (reader => foo, writer => _foo)
 253         ## is => rw, accessor => _foo  # turns into (accessor => _foo)
 254         ## is => ro, accessor => _foo  # error, accesor is rw
 255         ### -------------------------
 256
 257         if ($options->{is} eq 'ro') {
 258             $class->throw_error("Cannot define an accessor name on a read-only attribute, accessors are read/write", data => $options)
 259                 if exists $options->{accessor};
 260             $options->{reader} ||= $name;
 261         }
 262         elsif ($options->{is} eq 'rw') {
 263             if ($options->{writer}) {
 264                 $options->{reader} ||= $name;
 265             }
 266             else {
 267                 $options->{accessor} ||= $name;
 268             }
 269         }
 270         elsif ($options->{is} eq 'bare') {
 271             # do nothing, but don't complain (later) about missing methods
 272         }
 273         else {
 274             $class->throw_error("I do not understand this option (is => " . $options->{is} . ") on attribute ($name)", data => $options->{is});
 275         }
 276     }
 277
 278     if (exists $options->{isa}) {
 279         if (exists $options->{does}) {
 280             if (try { $options->{isa}->can('does') }) {
 281                 ($options->{isa}->does($options->{does}))
 282                     || $class->throw_error("Cannot have an isa option and a does option if the isa does not do the does on attribute ($name)", data => $options);
 283             }
 284             else {
 285                 $class->throw_error("Cannot have an isa option which cannot ->does() on attribute ($name)", data => $options);
 286             }
 287         }
 288
 289         # allow for anon-subtypes here ...
 290         if (blessed($options->{isa}) && $options->{isa}->isa('Moose::Meta::TypeConstraint')) {
 291             $options->{type_constraint} = $options->{isa};
 292         }
 293         else {
 294             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($options->{isa});
 295         }
 296     }
 297     elsif (exists $options->{does}) {
 298         # allow for anon-subtypes here ...
 299         if (blessed($options->{does}) && $options->{does}->isa('Moose::Meta::TypeConstraint')) {
 300                 $options->{type_constraint} = $options->{does};
 301         }
 302         else {
 303             $options->{type_constraint} = Moose::Util::TypeConstraints::find_or_create_does_type_constraint($options->{does});
 304         }
 305     }
 306
 307     if (exists $options->{coerce} && $options->{coerce}) {
 308         (exists $options->{type_constraint})
 309             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)", data => $options);
 310         $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)", data => $options)
 311             if $options->{weak_ref};
 312
 313         unless ( $options->{type_constraint}->has_coercion ) {
 314             my $type = $options->{type_constraint}->name;
 315
 316             Moose::Deprecated::deprecated(
 317                 feature => 'coerce without coercion',
 318                 message =>
 319                     "You cannot coerce an attribute ($name) unless its type ($type) has a coercion"
 320             );
 321         }
 322     }
 323
 324     if (exists $options->{trigger}) {
 325         ('CODE' eq ref $options->{trigger})
 326             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)", data => $options->{trigger});
 327     }
 328
 329     if (exists $options->{auto_deref} && $options->{auto_deref}) {
 330         (exists $options->{type_constraint})
 331             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)", data => $options);
 332         ($options->{type_constraint}->is_a_type_of('ArrayRef') ||
 333          $options->{type_constraint}->is_a_type_of('HashRef'))
 334             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)", data => $options);
 335     }
 336
 337     $class->_modify_attr_options_for_lazy_build( $name, $options );
 338
 339     if (exists $options->{lazy} && $options->{lazy}) {
 340         (exists $options->{default} || defined $options->{builder} )
 341             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it", data => $options);
 342     }
 343
 344     if ( $options->{required} && !( ( !exists $options->{init_arg} || defined $options->{init_arg} ) || exists $options->{default} || defined $options->{builder} ) ) {
 345         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg", data => $options);
 346     }
 347
 348 }
 349
 350 sub _modify_attr_options_for_lazy_build {
 351     my ( $class, $name, $options ) = @_;
 352
 353     return unless $options->{lazy_build};
 354
 355     $class->throw_error(
 356         "You can not use lazy_build and default for the same attribute ($name)",
 357         data => $options )
 358         if exists $options->{default};
 359
 360     $options->{lazy} = 1;
 361     $options->{builder} ||= "_build_${name}";
 362     if ( $name =~ /^_/ ) {
 363         $options->{clearer}   ||= "_clear${name}";
 364         $options->{predicate} ||= "_has${name}";
 365     }
 366     else {
 367         $options->{clearer}   ||= "clear_${name}";
 368         $options->{predicate} ||= "has_${name}";
 369     }
 370 }
 371
 372 sub initialize_instance_slot {
 373     my ($self, $meta_instance, $instance, $params) = @_;
 374     my $init_arg = $self->init_arg();
 375     # try to fetch the init arg from the %params ...
 376
 377     my $val;
 378     my $value_is_set;
 379     if ( defined($init_arg) and exists $params->{$init_arg}) {
 380         $val = $params->{$init_arg};
 381         $value_is_set = 1;
 382     }
 383     else {
 384         # skip it if it's lazy
 385         return if $self->is_lazy;
 386         # and die if it's required and doesn't have a default value
 387         $self->throw_error("Attribute (" . $self->name . ") is required", object => $instance, data => $params)
 388             if $self->is_required && !$self->has_default && !$self->has_builder;
 389
 390         # if nothing was in the %params, we can use the
 391         # attribute's default value (if it has one)
 392         if ($self->has_default) {
 393             $val = $self->default($instance);
 394             $value_is_set = 1;
 395         }
 396         elsif ($self->has_builder) {
 397             $val = $self->_call_builder($instance);
 398             $value_is_set = 1;
 399         }
 400     }
 401
 402     return unless $value_is_set;
 403
 404     $val = $self->_coerce_and_verify( $val, $instance );
 405
 406     $self->set_initial_value($instance, $val);
 407
 408     if ( ref $val && $self->is_weak_ref ) {
 409         $self->_weaken_value($instance);
 410     }
 411 }
 412
 413 sub _call_builder {
 414     my ( $self, $instance ) = @_;
 415
 416     my $builder = $self->builder();
 417
 418     return $instance->$builder()
 419         if $instance->can( $self->builder );
 420
 421     $self->throw_error(  blessed($instance)
 422             . " does not support builder method '"
 423             . $self->builder
 424             . "' for attribute '"
 425             . $self->name
 426             . "'",
 427             object => $instance,
 428      );
 429 }
 430
 431 ## Slot management
 432
 433 # FIXME:
 434 # this duplicates too much code from
 435 # Class::MOP::Attribute, we need to
 436 # refactor these bits eventually.
 437 # - SL
 438 sub _set_initial_slot_value {
 439     my ($self, $meta_instance, $instance, $value) = @_;
 440
 441     my $slot_name = $self->name;
 442
 443     return $meta_instance->set_slot_value($instance, $slot_name, $value)
 444         unless $self->has_initializer;
 445
 446     my $callback = sub {
 447         my $val = $self->_coerce_and_verify( shift, $instance );;
 448
 449         $meta_instance->set_slot_value($instance, $slot_name, $val);
 450     };
 451
 452     my $initializer = $self->initializer;
 453
 454     # most things will just want to set a value, so make it first arg
 455     $instance->$initializer($value, $callback, $self);
 456 }
 457
 458 sub set_value {
 459     my ($self, $instance, @args) = @_;
 460     my $value = $args[0];
 461
 462     my $attr_name = $self->name;
 463
 464     if ($self->is_required and not @args) {
 465         $self->throw_error("Attribute ($attr_name) is required", object => $instance);
 466     }
 467
 468     $value = $self->_coerce_and_verify( $value, $instance );
 469
 470     my @old;
 471     if ( $self->has_trigger && $self->has_value($instance) ) {
 472         @old = $self->get_value($instance, 'for trigger');
 473     }
 474
 475     $self->SUPER::set_value($instance, $value);
 476
 477     if ( ref $value && $self->is_weak_ref ) {
 478         $self->_weaken_value($instance);
 479     }
 480
 481     if ($self->has_trigger) {
 482         $self->trigger->($instance, $value, @old);
 483     }
 484 }
 485
 486 sub _weaken_value {
 487     my ( $self, $instance ) = @_;
 488
 489     my $meta_instance = Class::MOP::Class->initialize( blessed($instance) )
 490         ->get_meta_instance;
 491
 492     $meta_instance->weaken_slot_value( $instance, $self->name );
 493 }
 494
 495 sub get_value {
 496     my ($self, $instance, $for_trigger) = @_;
 497
 498     if ($self->is_lazy) {
 499         unless ($self->has_value($instance)) {
 500             my $value;
 501             if ($self->has_default) {
 502                 $value = $self->default($instance);
 503             } elsif ( $self->has_builder ) {
 504                 $value = $self->_call_builder($instance);
 505             }
 506
 507             $value = $self->_coerce_and_verify( $value, $instance );
 508
 509             $self->set_initial_value($instance, $value);
 510         }
 511     }
 512
 513     if ( $self->should_auto_deref && ! $for_trigger ) {
 514
 515         my $type_constraint = $self->type_constraint;
 516
 517         if ($type_constraint->is_a_type_of('ArrayRef')) {
 518             my $rv = $self->SUPER::get_value($instance);
 519             return unless defined $rv;
 520             return wantarray ? @{ $rv } : $rv;
 521         }
 522         elsif ($type_constraint->is_a_type_of('HashRef')) {
 523             my $rv = $self->SUPER::get_value($instance);
 524             return unless defined $rv;
 525             return wantarray ? %{ $rv } : $rv;
 526         }
 527         else {
 528             $self->throw_error("Can not auto de-reference the type constraint '" . $type_constraint->name . "'", object => $instance, type_constraint => $type_constraint);
 529         }
 530
 531     }
 532     else {
 533
 534         return $self->SUPER::get_value($instance);
 535     }
 536 }
 537
 538 ## installing accessors
 539
 540 sub accessor_metaclass { 'Moose::Meta::Method::Accessor' }
 541
 542 sub install_accessors {
 543     my $self = shift;
 544     $self->SUPER::install_accessors(@_);
 545     $self->install_delegation if $self->has_handles;
 546     return;
 547 }
 548
 549 sub _check_associated_methods {
 550     my $self = shift;
 551     unless (
 552         @{ $self->associated_methods }
 553         || ($self->_is_metadata || '') eq 'bare'
 554     ) {
 555         Carp::cluck(
 556             'Attribute (' . $self->name . ') of class '
 557             . $self->associated_class->name
 558             . ' has no associated methods'
 559             . ' (did you mean to provide an "is" argument?)'
 560             . "\n"
 561         )
 562     }
 563 }
 564
 565 sub _process_accessors {
 566     my $self = shift;
 567     my ($type, $accessor, $generate_as_inline_methods) = @_;
 568     $accessor = (keys %$accessor)[0] if (ref($accessor)||'') eq 'HASH';
 569     my $method = $self->associated_class->get_method($accessor);
 570     if ($method && !$method->isa('Class::MOP::Method::Accessor')
 571      && (!$self->definition_context
 572       || $method->package_name eq $self->definition_context->{package})) {
 573         Carp::cluck(
 574             "You are overwriting a locally defined method ($accessor) with "
 575           . "an accessor"
 576         );
 577     }
 578     if (!$self->associated_class->has_method($accessor)
 579      && $self->associated_class->has_package_symbol('&' . $accessor)) {
 580         Carp::cluck(
 581             "You are overwriting a locally defined function ($accessor) with "
 582           . "an accessor"
 583         );
 584     }
 585     $self->SUPER::_process_accessors(@_);
 586 }
 587
 588 sub remove_accessors {
 589     my $self = shift;
 590     $self->SUPER::remove_accessors(@_);
 591     $self->remove_delegation if $self->has_handles;
 592     return;
 593 }
 594
 595 sub inline_set {
 596     my $self = shift;
 597     my ( $instance, $value ) = @_;
 598
 599     my $mi = $self->associated_class->get_meta_instance;
 600
 601     my $code
 602         = $mi->inline_set_slot_value( $instance, $self->slots, $value ) . ";";
 603     $code
 604         .= $mi->inline_weaken_slot_value( $instance, $self->slots, $value )
 605         . "    if ref $value;"
 606         if $self->is_weak_ref;
 607
 608     return $code;
 609 }
 610
 611 sub install_delegation {
 612     my $self = shift;
 613
 614     # NOTE:
 615     # Here we canonicalize the 'handles' option
 616     # this will sort out any details and always
 617     # return an hash of methods which we want
 618     # to delagate to, see that method for details
 619     my %handles = $self->_canonicalize_handles;
 620
 621
 622     # install the delegation ...
 623     my $associated_class = $self->associated_class;
 624     foreach my $handle (keys %handles) {
 625         my $method_to_call = $handles{$handle};
 626         my $class_name = $associated_class->name;
 627         my $name = "${class_name}::${handle}";
 628
 629             (!$associated_class->has_method($handle))
 630                 || $self->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation", method_name => $handle);
 631
 632         # NOTE:
 633         # handles is not allowed to delegate
 634         # any of these methods, as they will
 635         # override the ones in your class, which
 636         # is almost certainly not what you want.
 637
 638         # FIXME warn when $handle was explicitly specified, but not if the source is a regex or something
 639         #cluck("Not delegating method '$handle' because it is a core method") and
 640         next if $class_name->isa("Moose::Object") and $handle =~ /^BUILD|DEMOLISH$/ || Moose::Object->can($handle);
 641
 642         my $method = $self->_make_delegation_method($handle, $method_to_call);
 643
 644         $self->associated_class->add_method($method->name, $method);
 645         $self->associate_method($method);
 646     }
 647 }
 648
 649 sub remove_delegation {
 650     my $self = shift;
 651     my %handles = $self->_canonicalize_handles;
 652     my $associated_class = $self->associated_class;
 653     foreach my $handle (keys %handles) {
 654         next unless any { $handle eq $_ }
 655                     map { $_->name }
 656                     @{ $self->associated_methods };
 657         $self->associated_class->remove_method($handle);
 658     }
 659 }
 660
 661 # private methods to help delegation ...
 662
 663 sub _canonicalize_handles {
 664     my $self    = shift;
 665     my $handles = $self->handles;
 666     if (my $handle_type = ref($handles)) {
 667         if ($handle_type eq 'HASH') {
 668             return %{$handles};
 669         }
 670         elsif ($handle_type eq 'ARRAY') {
 671             return map { $_ => $_ } @{$handles};
 672         }
 673         elsif ($handle_type eq 'Regexp') {
 674             ($self->has_type_constraint)
 675                 || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)", data => $handles);
 676             return map  { ($_ => $_) }
 677                    grep { /$handles/ } $self->_get_delegate_method_list;
 678         }
 679         elsif ($handle_type eq 'CODE') {
 680             return $handles->($self, $self->_find_delegate_metaclass);
 681         }
 682         elsif (blessed($handles) && $handles->isa('Moose::Meta::TypeConstraint::DuckType')) {
 683             return map { $_ => $_ } @{ $handles->methods };
 684         }
 685         elsif (blessed($handles) && $handles->isa('Moose::Meta::TypeConstraint::Role')) {
 686             $handles = $handles->role;
 687         }
 688         else {
 689             $self->throw_error("Unable to canonicalize the 'handles' option with $handles", data => $handles);
 690         }
 691     }
 692
 693     Class::MOP::load_class($handles);
 694     my $role_meta = Class::MOP::class_of($handles);
 695
 696     (blessed $role_meta && $role_meta->isa('Moose::Meta::Role'))
 697         || $self->throw_error("Unable to canonicalize the 'handles' option with $handles because its metaclass is not a Moose::Meta::Role", data => $handles);
 698
 699     return map { $_ => $_ }
 700         map { $_->name }
 701         grep { !$_->isa('Class::MOP::Method::Meta') } (
 702         $role_meta->_get_local_methods,
 703         $role_meta->get_required_method_list,
 704         );
 705 }
 706
 707 sub _get_delegate_method_list {
 708     my $self = shift;
 709     my $meta = $self->_find_delegate_metaclass;
 710     if ($meta->isa('Class::MOP::Class')) {
 711         return map  { $_->name }  # NOTE: !never! delegate &meta
 712                grep { $_->package_name ne 'Moose::Object' && !$_->isa('Class::MOP::Method::Meta') }
 713                     $meta->get_all_methods;
 714     }
 715     elsif ($meta->isa('Moose::Meta::Role')) {
 716         return $meta->get_method_list;
 717     }
 718     else {
 719         $self->throw_error("Unable to recognize the delegate metaclass '$meta'", data => $meta);
 720     }
 721 }
 722
 723 sub _find_delegate_metaclass {
 724     my $self = shift;
 725     if (my $class = $self->_isa_metadata) {
 726         unless ( Class::MOP::is_class_loaded($class) ) {
 727             $self->throw_error(
 728                 sprintf(
 729                     'The %s attribute is trying to delegate to a class which has not been loaded - %s',
 730                     $self->name, $class
 731                 )
 732             );
 733         }
 734         # we might be dealing with a non-Moose class,
 735         # and need to make our own metaclass. if there's
 736         # already a metaclass, it will be returned
 737         return Class::MOP::Class->initialize($class);
 738     }
 739     elsif (my $role = $self->_does_metadata) {
 740         unless ( Class::MOP::is_class_loaded($class) ) {
 741             $self->throw_error(
 742                 sprintf(
 743                     'The %s attribute is trying to delegate to a role which has not been loaded - %s',
 744                     $self->name, $role
 745                 )
 746             );
 747         }
 748
 749         return Class::MOP::class_of($role);
 750     }
 751     else {
 752         $self->throw_error("Cannot find delegate metaclass for attribute " . $self->name);
 753     }
 754 }
 755
 756 sub delegation_metaclass { 'Moose::Meta::Method::Delegation' }
 757
 758 sub _make_delegation_method {
 759     my ( $self, $handle_name, $method_to_call ) = @_;
 760
 761     my @curried_arguments;
 762
 763     ($method_to_call, @curried_arguments) = @$method_to_call
 764         if 'ARRAY' eq ref($method_to_call);
 765
 766     return $self->delegation_metaclass->new(
 767         name               => $handle_name,
 768         package_name       => $self->associated_class->name,
 769         attribute          => $self,
 770         delegate_to_method => $method_to_call,
 771         curried_arguments  => \@curried_arguments,
 772     );
 773 }
 774
 775 sub _coerce_and_verify {
 776     my $self     = shift;
 777     my $val      = shift;
 778     my $instance = shift;
 779
 780     return $val unless $self->has_type_constraint;
 781
 782     $val = $self->type_constraint->coerce($val)
 783         if $self->should_coerce && $self->type_constraint->has_coercion;
 784
 785     $self->verify_against_type_constraint($val, instance => $instance);
 786
 787     return $val;
 788 }
 789
 790 sub verify_against_type_constraint {
 791     my $self = shift;
 792     my $val  = shift;
 793
 794     return 1 if !$self->has_type_constraint;
 795
 796     my $type_constraint = $self->type_constraint;
 797
 798     $type_constraint->check($val)
 799         || $self->throw_error("Attribute ("
 800                  . $self->name
 801                  . ") does not pass the type constraint because: "
 802                  . $type_constraint->get_message($val), data => $val, @_);
 803 }
 804
 805 package Moose::Meta::Attribute::Custom::Moose;
 806 sub register_implementation { 'Moose::Meta::Attribute' }
 807
 808 1;
 809
 810 __END__
 811
 812 =pod
 813
 814 =head1 NAME
 815
 816 Moose::Meta::Attribute - The Moose attribute metaclass
 817
 818 =head1 DESCRIPTION
 819
 820 This class is a subclass of L<Class::MOP::Attribute> that provides
 821 additional Moose-specific functionality.
 822
 823 To really understand this class, you will need to start with the
 824 L<Class::MOP::Attribute> documentation. This class can be understood
 825 as a set of additional features on top of the basic feature provided
 826 by that parent class.
 827
 828 =head1 INHERITANCE
 829
 830 C<Moose::Meta::Attribute> is a subclass of L<Class::MOP::Attribute>.
 831
 832 =head1 METHODS
 833
 834 Many of the documented below override methods in
 835 L<Class::MOP::Attribute> and add Moose specific features.
 836
 837 =head2 Creation
 838
 839 =over 4
 840
 841 =item B<< Moose::Meta::Attribute->new(%options) >>
 842
 843 This method overrides the L<Class::MOP::Attribute> constructor.
 844
 845 Many of the options below are described in more detail in the
 846 L<Moose::Manual::Attributes> document.
 847
 848 It adds the following options to the constructor:
 849
 850 =over 8
 851
 852 =item * is => 'ro', 'rw', 'bare'
 853
 854 This provides a shorthand for specifying the C<reader>, C<writer>, or
 855 C<accessor> names. If the attribute is read-only ('ro') then it will
 856 have a C<reader> method with the same attribute as the name.
 857
 858 If it is read-write ('rw') then it will have an C<accessor> method
 859 with the same name. If you provide an explicit C<writer> for a
 860 read-write attribute, then you will have a C<reader> with the same
 861 name as the attribute, and a C<writer> with the name you provided.
 862
 863 Use 'bare' when you are deliberately not installing any methods
 864 (accessor, reader, etc.) associated with this attribute; otherwise,
 865 Moose will issue a deprecation warning when this attribute is added to a
 866 metaclass.
 867
 868 =item * isa => $type
 869
 870 This option accepts a type. The type can be a string, which should be
 871 a type name. If the type name is unknown, it is assumed to be a class
 872 name.
 873
 874 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 875
 876 If you I<also> provide a C<does> option, then your C<isa> option must
 877 be a class name, and that class must do the role specified with
 878 C<does>.
 879
 880 =item * does => $role
 881
 882 This is short-hand for saying that the attribute's type must be an
 883 object which does the named role.
 884
 885 =item * coerce => $bool
 886
 887 This option is only valid for objects with a type constraint
 888 (C<isa>) that defined a coercion. If this is true, then coercions will be applied whenever
 889 this attribute is set.
 890
 891 You can make both this and the C<weak_ref> option true.
 892
 893 =item * trigger => $sub
 894
 895 This option accepts a subroutine reference, which will be called after
 896 the attribute is set.
 897
 898 =item * required => $bool
 899
 900 An attribute which is required must be provided to the constructor. An
 901 attribute which is required can also have a C<default> or C<builder>,
 902 which will satisfy its required-ness.
 903
 904 A required attribute must have a C<default>, C<builder> or a
 905 non-C<undef> C<init_arg>
 906
 907 =item * lazy => $bool
 908
 909 A lazy attribute must have a C<default> or C<builder>. When an
 910 attribute is lazy, the default value will not be calculated until the
 911 attribute is read.
 912
 913 =item * weak_ref => $bool
 914
 915 If this is true, the attribute's value will be stored as a weak
 916 reference.
 917
 918 =item * auto_deref => $bool
 919
 920 If this is true, then the reader will dereference the value when it is
 921 called. The attribute must have a type constraint which defines the
 922 attribute as an array or hash reference.
 923
 924 =item * lazy_build => $bool
 925
 926 Setting this to true makes the attribute lazy and provides a number of
 927 default methods.
 928
 929   has 'size' => (
 930       is         => 'ro',
 931       lazy_build => 1,
 932   );
 933
 934 is equivalent to this:
 935
 936   has 'size' => (
 937       is        => 'ro',
 938       lazy      => 1,
 939       builder   => '_build_size',
 940       clearer   => 'clear_size',
 941       predicate => 'has_size',
 942   );
 943
 944 =item * documentation
 945
 946 An arbitrary string that can be retrieved later by calling C<<
 947 $attr->documentation >>.
 948
 949 =back
 950
 951 =item B<< $attr->clone(%options) >>
 952
 953 This creates a new attribute based on attribute being cloned. You must
 954 supply a C<name> option to provide a new name for the attribute.
 955
 956 The C<%options> can only specify options handled by
 957 L<Class::MOP::Attribute>.
 958
 959 =back
 960
 961 =head2 Value management
 962
 963 =over 4
 964
 965 =item B<< $attr->initialize_instance_slot($meta_instance, $instance, $params) >>
 966
 967 This method is used internally to initialize the attribute's slot in
 968 the object C<$instance>.
 969
 970 This overrides the L<Class::MOP::Attribute> method to handle lazy
 971 attributes, weak references, and type constraints.
 972
 973 =item B<get_value>
 974
 975 =item B<set_value>
 976
 977   eval { $point->meta->get_attribute('x')->set_value($point, 'forty-two') };
 978   if($@) {
 979     print "Oops: $@\n";
 980   }
 981
 982 I<Attribute (x) does not pass the type constraint (Int) with 'forty-two'>
 983
 984 Before setting the value, a check is made on the type constraint of
 985 the attribute, if it has one, to see if the value passes it. If the
 986 value fails to pass, the set operation dies with a L</throw_error>.
 987
 988 Any coercion to convert values is done before checking the type constraint.
 989
 990 To check a value against a type constraint before setting it, fetch the
 991 attribute instance using L<Class::MOP::Class/find_attribute_by_name>,
 992 fetch the type_constraint from the attribute using L<Moose::Meta::Attribute/type_constraint>
 993 and call L<Moose::Meta::TypeConstraint/check>. See L<Moose::Cookbook::Basics::Recipe4>
 994 for an example.
 995
 996 =back
 997
 998 =head2 Attribute Accessor generation
 999
1000 =over 4
1001
1002 =item B<< $attr->install_accessors >>
1003
1004 This method overrides the parent to also install delegation methods.
1005
1006 If, after installing all methods, the attribute object has no associated
1007 methods, it throws an error unless C<< is => 'bare' >> was passed to the
1008 attribute constructor.  (Trying to add an attribute that has no associated
1009 methods is almost always an error.)
1010
1011 =item B<< $attr->remove_accessors >>
1012
1013 This method overrides the parent to also remove delegation methods.
1014
1015 =item B<< $attr->inline_set($instance_var, $value_var) >>
1016
1017 This method return a code snippet suitable for inlining the relevant
1018 operation. It expect strings containing variable names to be used in the
1019 inlining, like C<'$self'> or C<'$_[1]'>.
1020
1021 =item B<< $attr->install_delegation >>
1022
1023 This method adds its delegation methods to the attribute's associated
1024 class, if it has any to add.
1025
1026 =item B<< $attr->remove_delegation >>
1027
1028 This method remove its delegation methods from the attribute's
1029 associated class.
1030
1031 =item B<< $attr->accessor_metaclass >>
1032
1033 Returns the accessor metaclass name, which defaults to
1034 L<Moose::Meta::Method::Accessor>.
1035
1036 =item B<< $attr->delegation_metaclass >>
1037
1038 Returns the delegation metaclass name, which defaults to
1039 L<Moose::Meta::Method::Delegation>.
1040
1041 =back
1042
1043 =head2 Additional Moose features
1044
1045 These methods are not found in the superclass. They support features
1046 provided by Moose.
1047
1048 =over 4
1049
1050 =item B<< $attr->does($role) >>
1051
1052 This indicates whether the I<attribute itself> does the given
1053 role. The role can be given as a full class name, or as a resolvable
1054 trait name.
1055
1056 Note that this checks the attribute itself, not its type constraint,
1057 so it is checking the attribute's metaclass and any traits applied to
1058 the attribute.
1059
1060 =item B<< Moose::Meta::Class->interpolate_class_and_new($name, %options) >>
1061
1062 This is an alternate constructor that handles the C<metaclass> and
1063 C<traits> options.
1064
1065 Effectively, this method is a factory that finds or creates the
1066 appropriate class for the given C<metaclass> and/or C<traits>.
1067
1068 Once it has the appropriate class, it will call C<< $class->new($name,
1069 %options) >> on that class.
1070
1071 =item B<< $attr->clone_and_inherit_options(%options) >>
1072
1073 This method supports the C<has '+foo'> feature. It does various bits
1074 of processing on the supplied C<%options> before ultimately calling
1075 the C<clone> method.
1076
1077 One of its main tasks is to make sure that the C<%options> provided
1078 does not include the options returned by the
1079 C<illegal_options_for_inheritance> method.
1080
1081 =item B<< $attr->illegal_options_for_inheritance >>
1082
1083 This returns a blacklist of options that can not be overridden in a
1084 subclass's attribute definition.
1085
1086 This exists to allow a custom metaclass to change or add to the list
1087 of options which can not be changed.
1088
1089 =item B<< $attr->type_constraint >>
1090
1091 Returns the L<Moose::Meta::TypeConstraint> object for this attribute,
1092 if it has one.
1093
1094 =item B<< $attr->has_type_constraint >>
1095
1096 Returns true if this attribute has a type constraint.
1097
1098 =item B<< $attr->verify_against_type_constraint($value) >>
1099
1100 Given a value, this method returns true if the value is valid for the
1101 attribute's type constraint. If the value is not valid, it throws an
1102 error.
1103
1104 =item B<< $attr->handles >>
1105
1106 This returns the value of the C<handles> option passed to the
1107 constructor.
1108
1109 =item B<< $attr->has_handles >>
1110
1111 Returns true if this attribute performs delegation.
1112
1113 =item B<< $attr->is_weak_ref >>
1114
1115 Returns true if this attribute stores its value as a weak reference.
1116
1117 =item B<< $attr->is_required >>
1118
1119 Returns true if this attribute is required to have a value.
1120
1121 =item B<< $attr->is_lazy >>
1122
1123 Returns true if this attribute is lazy.
1124
1125 =item B<< $attr->is_lazy_build >>
1126
1127 Returns true if the C<lazy_build> option was true when passed to the
1128 constructor.
1129
1130 =item B<< $attr->should_coerce >>
1131
1132 Returns true if the C<coerce> option passed to the constructor was
1133 true.
1134
1135 =item B<< $attr->should_auto_deref >>
1136
1137 Returns true if the C<auto_deref> option passed to the constructor was
1138 true.
1139
1140 =item B<< $attr->trigger >>
1141
1142 This is the subroutine reference that was in the C<trigger> option
1143 passed to the constructor, if any.
1144
1145 =item B<< $attr->has_trigger >>
1146
1147 Returns true if this attribute has a trigger set.
1148
1149 =item B<< $attr->documentation >>
1150
1151 Returns the value that was in the C<documentation> option passed to
1152 the constructor, if any.
1153
1154 =item B<< $attr->has_documentation >>
1155
1156 Returns true if this attribute has any documentation.
1157
1158 =item B<< $attr->applied_traits >>
1159
1160 This returns an array reference of all the traits which were applied
1161 to this attribute. If none were applied, this returns C<undef>.
1162
1163 =item B<< $attr->has_applied_traits >>
1164
1165 Returns true if this attribute has any traits applied.
1166
1167 =back
1168
1169 =head1 BUGS
1170
1171 See L<Moose/BUGS> for details on reporting bugs.
1172
1173 =head1 AUTHOR
1174
1175 Stevan Little E<lt>stevan@iinteractive.comE<gt>
1176
1177 Yuval Kogman E<lt>nothingmuch@woobling.comE<gt>
1178
1179 =head1 COPYRIGHT AND LICENSE
1180
1181 Copyright 2006-2010 by Infinity Interactive, Inc.
1182
1183 L<http://www.iinteractive.com>
1184
1185 This library is free software; you can redistribute it and/or modify
1186 it under the same terms as Perl itself.
1187
1188 =cut