lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.05';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22
  23 use Moose::Object;
  24 use Moose::Util::TypeConstraints;
  25
  26 {
  27     my ( $CALLER, %METAS );
  28
  29     sub _find_meta {
  30         my $class = $CALLER;
  31
  32         return $METAS{$class} if exists $METAS{$class};
  33
  34         # make a subtype for each Moose class
  35         subtype $class
  36             => as 'Object'
  37             => where { $_->isa($class) }
  38         unless find_type_constraint($class);
  39
  40         my $meta;
  41         if ($class->can('meta')) {
  42             $meta = $class->meta();
  43             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  44                 || confess "Whoops, not møøsey enough";
  45         }
  46         else {
  47             $meta = Moose::Meta::Class->initialize($class);
  48             $meta->add_method('meta' => sub {
  49                 # re-initialize so it inherits properly
  50                 Moose::Meta::Class->initialize($class);
  51             })
  52         }
  53
  54         # make sure they inherit from Moose::Object
  55         $meta->superclasses('Moose::Object')
  56            unless $meta->superclasses();
  57
  58         return $METAS{$class} = $meta;
  59     }
  60
  61     my %exports = (
  62         extends => sub {
  63             my $meta = _find_meta();
  64             return subname 'Moose::extends' => sub {
  65                 _load_all_classes(@_);
  66                 $meta->superclasses(@_)
  67             };
  68         },
  69         with => sub {
  70             my $meta = _find_meta();
  71             return subname 'Moose::with' => sub {
  72                 my ($role) = @_;
  73                 _load_all_classes($role);
  74                 $role->meta->apply($meta);
  75             };
  76         },
  77         has => sub {
  78             my $meta = _find_meta();
  79             return subname 'Moose::has' => sub {
  80                 my ($name, %options) = @_;
  81                 if ($name =~ /^\+(.*)/) {
  82                     my $inherited_attr = $meta->find_attribute_by_name($1);
  83                     (defined $inherited_attr)
  84                         || confess "Could not find an attribute by the name of '$1' to inherit from";
  85                     my $new_attr = $inherited_attr->clone_and_inherit_options(%options);
  86                     $meta->add_attribute($new_attr);
  87                 }
  88                 else {
  89                     if ($options{metaclass}) {
  90                         _load_all_classes($options{metaclass});
  91                         $meta->add_attribute($options{metaclass}->new($name, %options));
  92                     }
  93                     else {
  94                         $meta->add_attribute($name, %options);
  95                     }
  96                 }
  97             };
  98         },
  99         before => sub {
 100             my $meta = _find_meta();
 101             return subname 'Moose::before' => sub {
 102                 my $code = pop @_;
 103                 $meta->add_before_method_modifier($_, $code) for @_;
 104             };
 105         },
 106         after => sub {
 107             my $meta = _find_meta();
 108             return subname 'Moose::after' => sub {
 109                 my $code = pop @_;
 110                 $meta->add_after_method_modifier($_, $code) for @_;
 111             };
 112         },
 113         around => sub {
 114             my $meta = _find_meta();
 115             return subname 'Moose::around' => sub {
 116                 my $code = pop @_;
 117                 $meta->add_around_method_modifier($_, $code) for @_;
 118             };
 119         },
 120         super => sub {
 121             my $meta = _find_meta();
 122             return subname 'Moose::super' => sub {};
 123         },
 124         override => sub {
 125             my $meta = _find_meta();
 126             return subname 'Moose::override' => sub {
 127                 my ($name, $method) = @_;
 128                 $meta->add_override_method_modifier($name => $method);
 129             };
 130         },
 131         inner => sub {
 132             my $meta = _find_meta();
 133             return subname 'Moose::inner' => sub {};
 134         },
 135         augment => sub {
 136             my $meta = _find_meta();
 137             return subname 'Moose::augment' => sub {
 138                 my ($name, $method) = @_;
 139                 $meta->add_augment_method_modifier($name => $method);
 140             };
 141         },
 142         confess => sub {
 143             return \&Carp::confess;
 144         },
 145         blessed => sub {
 146             return \&Scalar::Util::blessed;
 147         }
 148     );
 149
 150     my $exporter = Sub::Exporter::build_exporter({
 151         exports => \%exports,
 152         groups  => {
 153             default => [':all']
 154         }
 155     });
 156
 157     sub import {
 158         $CALLER = caller();
 159
 160         # we should never export to main
 161         return if $CALLER eq 'main';
 162
 163         goto $exporter;
 164     };
 165 }
 166
 167 ## Utility functions
 168
 169 sub _load_all_classes {
 170     foreach my $super (@_) {
 171         # see if this is already
 172         # loaded in the symbol table
 173         next if _is_class_already_loaded($super);
 174         # otherwise require it ...
 175         ($super->require)
 176             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 177     }
 178 }
 179
 180 sub _is_class_already_loaded {
 181         my $name = shift;
 182         no strict 'refs';
 183         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 184         foreach (keys %{"${name}::"}) {
 185                 next if substr($_, -2, 2) eq '::';
 186                 return 1 if defined &{"${name}::$_"};
 187         }
 188     return 0;
 189 }
 190
 191 1;
 192
 193 __END__
 194
 195 =pod
 196
 197 =head1 NAME
 198
 199 Moose - Moose, it's the new Camel
 200
 201 =head1 SYNOPSIS
 202
 203   package Point;
 204   use Moose;
 205
 206   has 'x' => (isa => 'Int', is => 'rw');
 207   has 'y' => (isa => 'Int', is => 'rw');
 208
 209   sub clear {
 210       my $self = shift;
 211       $self->x(0);
 212       $self->y(0);
 213   }
 214
 215   package Point3D;
 216   use Moose;
 217
 218   extends 'Point';
 219
 220   has 'z' => (isa => 'Int');
 221
 222   after 'clear' => sub {
 223       my $self = shift;
 224       $self->{z} = 0;
 225   };
 226
 227 =head1 CAVEAT
 228
 229 This is an early release of this module, it still needs
 230 some fine tuning and B<lots> more documentation. I am adopting
 231 the I<release early and release often> approach with this module,
 232 so keep an eye on your favorite CPAN mirror!
 233
 234 =head1 DESCRIPTION
 235
 236 Moose is an extension of the Perl 5 object system.
 237
 238 =head2 Another object system!?!?
 239
 240 Yes, I know there has been an explosion recently of new ways to
 241 build object's in Perl 5, most of them based on inside-out objects,
 242 and other such things. Moose is different because it is not a new
 243 object system for Perl 5, but instead an extension of the existing
 244 object system.
 245
 246 Moose is built on top of L<Class::MOP>, which is a metaclass system
 247 for Perl 5. This means that Moose not only makes building normal
 248 Perl 5 objects better, but it also provides the power of metaclass
 249 programming.
 250
 251 =head2 What does Moose stand for??
 252
 253 Moose doesn't stand for one thing in particular, however, if you
 254 want, here are a few of my favorites, feel free to contribute
 255 more :)
 256
 257 =over 4
 258
 259 =item Make Other Object Systems Envious
 260
 261 =item Makes Object Orientation So Easy
 262
 263 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 264
 265 =item Most Other Object Systems Emasculate
 266
 267 =item My Overcraft Overfilled (with) Some Eels
 268
 269 =item Moose Often Ovulate Sorta Early
 270
 271 =item Many Overloaded Object Systems Exists
 272
 273 =item Moose Offers Often Super Extensions
 274
 275 =item Meta Object Orientation Syntax Extensions
 276
 277 =back
 278
 279 =head1 BUILDING CLASSES WITH MOOSE
 280
 281 Moose makes every attempt to provide as much convience during class
 282 construction/definition, but still stay out of your way if you want
 283 it to. Here are some of the features Moose provides:
 284
 285 Unless specified with C<extends>, any class which uses Moose will
 286 inherit from L<Moose::Object>.
 287
 288 Moose will also manage all attributes (including inherited ones) that
 289 are defined with C<has>. And assuming that you call C<new> which is
 290 inherited from L<Moose::Object>, then this includes properly initializing
 291 all instance slots, setting defaults where approprtiate and performing any
 292 type constraint checking or coercion.
 293
 294 For more details, see the ever expanding L<Moose::Cookbook>.
 295
 296 =head1 EXPORTED FUNCTIONS
 297
 298 Moose will export a number of functions into the class's namespace, which
 299 can then be used to set up the class. These functions all work directly
 300 on the current class.
 301
 302 =over 4
 303
 304 =item B<meta>
 305
 306 This is a method which provides access to the current class's metaclass.
 307
 308 =item B<extends (@superclasses)>
 309
 310 This function will set the superclass(es) for the current class.
 311
 312 This approach is recommended instead of C<use base>, because C<use base>
 313 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 314 replace it. This is important to ensure that classes which do not have
 315 superclasses properly inherit from L<Moose::Object>.
 316
 317 =item B<with ($role)>
 318
 319 This will apply a given C<$role> to the local class. Role support is
 320 currently very experimental, see L<Moose::Role> for more details.
 321
 322 =item B<has ($name, %options)>
 323
 324 This will install an attribute of a given C<$name> into the current class.
 325 The list of C<%options> are the same as those provided by both
 326 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 327 few convience ones provided by Moose which are listed below:
 328
 329 =over 4
 330
 331 =item I<is =E<gt> 'rw'|'ro'>
 332
 333 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 334 only). These will create either a read/write accessor or a read-only
 335 accessor respectively, using the same name as the C<$name> of the attribute.
 336
 337 If you need more control over how your accessors are named, you can use the
 338 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 339
 340 =item I<isa =E<gt> $type_name>
 341
 342 The I<isa> option uses Moose's type constraint facilities to set up runtime
 343 type checking for this attribute. Moose will perform the checks during class
 344 construction, and within any accessors. The C<$type_name> argument must be a
 345 string. The string can be either a class name, or a type defined using
 346 Moose's type defintion features.
 347
 348 =item I<coerce =E<gt> (1|0)>
 349
 350 This will attempt to use coercion with the supplied type constraint to change
 351 the value passed into any accessors of constructors. You B<must> have supplied
 352 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 353 for an example usage.
 354
 355 =item I<does =E<gt> $role_name>
 356
 357 This will accept the name of a role which the value stored in this attribute
 358 is expected to have consumed.
 359
 360 =item I<required =E<gt> (1|0)>
 361
 362 This marks the attribute as being required. This means a value must be supplied
 363 during class construction, and the attribute can never be set to C<undef> with
 364 an accessor.
 365
 366 =item I<weak_ref =E<gt> (1|0)>
 367
 368 This will tell the class to strore the value of this attribute as a weakened
 369 reference. If an attribute is a weakened reference, it can B<not> also be coerced.
 370
 371 =item I<lazy =E<gt> (1|0)>
 372
 373 This will tell the class to not create this slot until absolutely nessecary.
 374 If an attribute is marked as lazy it B<must> have a default supplied.
 375
 376 =item I<trigger =E<gt> $code>
 377
 378 The trigger option is a CODE reference which will be called after the value of
 379 the attribute is set. The CODE ref will be passed the instance itself, the
 380 updated value and the attribute meta-object (this is for more advanced fiddling
 381 and can typically be ignored in most cases). You can B<not> have a trigger on
 382 a read-only attribute.
 383
 384 =back
 385
 386 =item B<before $name|@names =E<gt> sub { ... }>
 387
 388 =item B<after $name|@names =E<gt> sub { ... }>
 389
 390 =item B<around $name|@names =E<gt> sub { ... }>
 391
 392 This three items are syntactic sugar for the before, after and around method
 393 modifier features that L<Class::MOP> provides. More information on these can
 394 be found in the L<Class::MOP> documentation for now.
 395
 396 =item B<super>
 397
 398 The keyword C<super> is a noop when called outside of an C<override> method. In
 399 the context of an C<override> method, it will call the next most appropriate
 400 superclass method with the same arguments as the original method.
 401
 402 =item B<override ($name, &sub)>
 403
 404 An C<override> method, is a way of explictly saying "I am overriding this
 405 method from my superclass". You can call C<super> within this method, and
 406 it will work as expected. The same thing I<can> be accomplished with a normal
 407 method call and the C<SUPER::> pseudo-package, it is really your choice.
 408
 409 =item B<inner>
 410
 411 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 412 an C<augment> method. You can think of C<inner> as being the inverse of
 413 C<super>, the details of how C<inner> and C<augment> work is best described in
 414 the L<Moose::Cookbook>.
 415
 416 =item B<augment ($name, &sub)>
 417
 418 An C<augment> method, is a way of explictly saying "I am augmenting this
 419 method from my superclass". Once again, the details of how C<inner> and
 420 C<augment> work is best described in the L<Moose::Cookbook>.
 421
 422 =item B<confess>
 423
 424 This is the C<Carp::confess> function, and exported here beause I use it
 425 all the time. This feature may change in the future, so you have been warned.
 426
 427 =item B<blessed>
 428
 429 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 430 use it all the time. It is highly recommended that this is used instead of
 431 C<ref> anywhere you need to test for an object's class name.
 432
 433 =back
 434
 435 =head1 CAVEATS
 436
 437 =over 4
 438
 439 =item *
 440
 441 It should be noted that C<super> and C<inner> can B<not> be used in the same
 442 method. However, they can be combined together with the same class hierarchy,
 443 see F<t/014_override_augment_inner_super.t> for an example.
 444
 445 The reason that this is so is because C<super> is only valid within a method
 446 with the C<override> modifier, and C<inner> will never be valid within an
 447 C<override> method. In fact, C<augment> will skip over any C<override> methods
 448 when searching for it's appropriate C<inner>.
 449
 450 This might seem like a restriction, but I am of the opinion that keeping these
 451 two features seperate (but interoperable) actually makes them easy to use since
 452 their behavior is then easier to predict. Time will tell if I am right or not.
 453
 454 =back
 455
 456 =head1 ACKNOWLEDGEMENTS
 457
 458 =over 4
 459
 460 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 461
 462 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 463
 464 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 465 and it certainly wouldn't have this name ;P
 466
 467 =item The basis of the TypeContraints module was Rob Kinyon's idea
 468 originally, I just ran with it.
 469
 470 =item Thanks to mst & chansen and the whole #moose poose for all the
 471 ideas/feature-requests/encouragement
 472
 473 =back
 474
 475 =head1 SEE ALSO
 476
 477 =over 4
 478
 479 =item L<Class::MOP> documentation
 480
 481 =item The #moose channel on irc.perl.org
 482
 483 =item L<http://forum2.org/moose/>
 484
 485 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 486
 487 This paper (suggested by lbr on #moose) was what lead to the implementation
 488 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 489 want to understand this feature, I suggest you read this.
 490
 491 =back
 492
 493 =head1 BUGS
 494
 495 All complex software has bugs lurking in it, and this module is no
 496 exception. If you find a bug please either email me, or add the bug
 497 to cpan-RT.
 498
 499 =head1 AUTHOR
 500
 501 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 502
 503 =head1 COPYRIGHT AND LICENSE
 504
 505 Copyright 2006 by Infinity Interactive, Inc.
 506
 507 L<http://www.iinteractive.com>
 508
 509 This library is free software; you can redistribute it and/or modify
 510 it under the same terms as Perl itself.
 511
 512 =cut