lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.05';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22
  23 use Moose::Object;
  24 use Moose::Util::TypeConstraints;
  25
  26 {
  27     my ( $CALLER, %METAS );
  28
  29     sub _find_meta {
  30         my $class = $CALLER;
  31
  32         return $METAS{$class} if exists $METAS{$class};
  33
  34         # make a subtype for each Moose class
  35         subtype $class
  36             => as 'Object'
  37             => where { $_->isa($class) }
  38         unless find_type_constraint($class);
  39
  40         my $meta;
  41         if ($class->can('meta')) {
  42             $meta = $class->meta();
  43             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  44                 || confess "Whoops, not møøsey enough";
  45         }
  46         else {
  47             $meta = Moose::Meta::Class->initialize($class);
  48             $meta->add_method('meta' => sub {
  49                 # re-initialize so it inherits properly
  50                 Moose::Meta::Class->initialize($class);
  51             })
  52         }
  53
  54         # make sure they inherit from Moose::Object
  55         $meta->superclasses('Moose::Object')
  56            unless $meta->superclasses();
  57
  58         return $METAS{$class} = $meta;
  59     }
  60
  61     my %exports = (
  62         extends => sub {
  63             my $meta = _find_meta();
  64             return subname 'Moose::extends' => sub {
  65                 _load_all_classes(@_);
  66                 $meta->superclasses(@_)
  67             };
  68         },
  69         with => sub {
  70             my $meta = _find_meta();
  71             return subname 'Moose::with' => sub {
  72                 my ($role) = @_;
  73                 _load_all_classes($role);
  74                 $role->meta->apply($meta);
  75             };
  76         },
  77         has => sub {
  78             my $meta = _find_meta();
  79             return subname 'Moose::has' => sub {
  80                 my ($name, %options) = @_;
  81                 if ($name =~ /^\+(.*)/) {
  82                     my $inherited_attr = $meta->find_attribute_by_name($1);
  83                     (defined $inherited_attr)
  84                         || confess "Could not find an attribute by the name of '$1' to inherit from";
  85                     #(scalar keys %options == 1 && exists $options{default})
  86                     #    || confess "Inherited slot specifications can only alter the 'default' option";
  87                     my $new_attr = $inherited_attr->clone(%options);
  88                     $meta->add_attribute($new_attr);
  89                 }
  90                 else {
  91                     if ($options{metaclass}) {
  92                         _load_all_classes($options{metaclass});
  93                         $meta->add_attribute($options{metaclass}->new($name, %options));
  94                     }
  95                     else {
  96                         $meta->add_attribute($name, %options);
  97                     }
  98                 }
  99             };
 100         },
 101         before => sub {
 102             my $meta = _find_meta();
 103             return subname 'Moose::before' => sub {
 104                 my $code = pop @_;
 105                 $meta->add_before_method_modifier($_, $code) for @_;
 106             };
 107         },
 108         after => sub {
 109             my $meta = _find_meta();
 110             return subname 'Moose::after' => sub {
 111                 my $code = pop @_;
 112                 $meta->add_after_method_modifier($_, $code) for @_;
 113             };
 114         },
 115         around => sub {
 116             my $meta = _find_meta();
 117             return subname 'Moose::around' => sub {
 118                 my $code = pop @_;
 119                 $meta->add_around_method_modifier($_, $code) for @_;
 120             };
 121         },
 122         super => sub {
 123             my $meta = _find_meta();
 124             return subname 'Moose::super' => sub {};
 125         },
 126         override => sub {
 127             my $meta = _find_meta();
 128             return subname 'Moose::override' => sub {
 129                 my ($name, $method) = @_;
 130                 $meta->add_override_method_modifier($name => $method);
 131             };
 132         },
 133         inner => sub {
 134             my $meta = _find_meta();
 135             return subname 'Moose::inner' => sub {};
 136         },
 137         augment => sub {
 138             my $meta = _find_meta();
 139             return subname 'Moose::augment' => sub {
 140                 my ($name, $method) = @_;
 141                 $meta->add_augment_method_modifier($name => $method);
 142             };
 143         },
 144         confess => sub {
 145             return \&Carp::confess;
 146         },
 147         blessed => sub {
 148             return \&Scalar::Util::blessed;
 149         }
 150     );
 151
 152     my $exporter = Sub::Exporter::build_exporter({
 153         exports => \%exports,
 154         groups  => {
 155             default => [':all']
 156         }
 157     });
 158
 159     sub import {
 160         $CALLER = caller();
 161
 162         # we should never export to main
 163         return if $CALLER eq 'main';
 164
 165         goto $exporter;
 166     };
 167 }
 168
 169 ## Utility functions
 170
 171 sub _load_all_classes {
 172     foreach my $super (@_) {
 173         # see if this is already
 174         # loaded in the symbol table
 175         next if _is_class_already_loaded($super);
 176         # otherwise require it ...
 177         ($super->require)
 178             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 179     }
 180 }
 181
 182 sub _is_class_already_loaded {
 183         my $name = shift;
 184         no strict 'refs';
 185         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 186         foreach (keys %{"${name}::"}) {
 187                 next if substr($_, -2, 2) eq '::';
 188                 return 1 if defined &{"${name}::$_"};
 189         }
 190     return 0;
 191 }
 192
 193 1;
 194
 195 __END__
 196
 197 =pod
 198
 199 =head1 NAME
 200
 201 Moose - Moose, it's the new Camel
 202
 203 =head1 SYNOPSIS
 204
 205   package Point;
 206   use Moose;
 207
 208   has 'x' => (isa => 'Int', is => 'rw');
 209   has 'y' => (isa => 'Int', is => 'rw');
 210
 211   sub clear {
 212       my $self = shift;
 213       $self->x(0);
 214       $self->y(0);
 215   }
 216
 217   package Point3D;
 218   use Moose;
 219
 220   extends 'Point';
 221
 222   has 'z' => (isa => 'Int');
 223
 224   after 'clear' => sub {
 225       my $self = shift;
 226       $self->{z} = 0;
 227   };
 228
 229 =head1 CAVEAT
 230
 231 This is an early release of this module, it still needs
 232 some fine tuning and B<lots> more documentation. I am adopting
 233 the I<release early and release often> approach with this module,
 234 so keep an eye on your favorite CPAN mirror!
 235
 236 =head1 DESCRIPTION
 237
 238 Moose is an extension of the Perl 5 object system.
 239
 240 =head2 Another object system!?!?
 241
 242 Yes, I know there has been an explosion recently of new ways to
 243 build object's in Perl 5, most of them based on inside-out objects,
 244 and other such things. Moose is different because it is not a new
 245 object system for Perl 5, but instead an extension of the existing
 246 object system.
 247
 248 Moose is built on top of L<Class::MOP>, which is a metaclass system
 249 for Perl 5. This means that Moose not only makes building normal
 250 Perl 5 objects better, but it also provides the power of metaclass
 251 programming.
 252
 253 =head2 What does Moose stand for??
 254
 255 Moose doesn't stand for one thing in particular, however, if you
 256 want, here are a few of my favorites, feel free to contribute
 257 more :)
 258
 259 =over 4
 260
 261 =item Make Other Object Systems Envious
 262
 263 =item Makes Object Orientation So Easy
 264
 265 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 266
 267 =item Most Other Object Systems Emasculate
 268
 269 =item My Overcraft Overfilled (with) Some Eels
 270
 271 =item Moose Often Ovulate Sorta Early
 272
 273 =item Many Overloaded Object Systems Exists
 274
 275 =item Moose Offers Often Super Extensions
 276
 277 =item Meta Object Orientation Syntax Extensions
 278
 279 =back
 280
 281 =head1 BUILDING CLASSES WITH MOOSE
 282
 283 Moose makes every attempt to provide as much convience during class
 284 construction/definition, but still stay out of your way if you want
 285 it to. Here are some of the features Moose provides:
 286
 287 Unless specified with C<extends>, any class which uses Moose will
 288 inherit from L<Moose::Object>.
 289
 290 Moose will also manage all attributes (including inherited ones) that
 291 are defined with C<has>. And assuming that you call C<new> which is
 292 inherited from L<Moose::Object>, then this includes properly initializing
 293 all instance slots, setting defaults where approprtiate and performing any
 294 type constraint checking or coercion.
 295
 296 For more details, see the ever expanding L<Moose::Cookbook>.
 297
 298 =head1 EXPORTED FUNCTIONS
 299
 300 Moose will export a number of functions into the class's namespace, which
 301 can then be used to set up the class. These functions all work directly
 302 on the current class.
 303
 304 =over 4
 305
 306 =item B<meta>
 307
 308 This is a method which provides access to the current class's metaclass.
 309
 310 =item B<extends (@superclasses)>
 311
 312 This function will set the superclass(es) for the current class.
 313
 314 This approach is recommended instead of C<use base>, because C<use base>
 315 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 316 replace it. This is important to ensure that classes which do not have
 317 superclasses properly inherit from L<Moose::Object>.
 318
 319 =item B<with ($role)>
 320
 321 This will apply a given C<$role> to the local class. Role support is
 322 currently very experimental, see L<Moose::Role> for more details.
 323
 324 =item B<has ($name, %options)>
 325
 326 This will install an attribute of a given C<$name> into the current class.
 327 The list of C<%options> are the same as those provided by both
 328 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 329 few convience ones provided by Moose which are listed below:
 330
 331 =over 4
 332
 333 =item I<is =E<gt> 'rw'|'ro'>
 334
 335 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 336 only). These will create either a read/write accessor or a read-only
 337 accessor respectively, using the same name as the C<$name> of the attribute.
 338
 339 If you need more control over how your accessors are named, you can use the
 340 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 341
 342 =item I<isa =E<gt> $type_name>
 343
 344 The I<isa> option uses Moose's type constraint facilities to set up runtime
 345 type checking for this attribute. Moose will perform the checks during class
 346 construction, and within any accessors. The C<$type_name> argument must be a
 347 string. The string can be either a class name, or a type defined using
 348 Moose's type defintion features.
 349
 350 =item I<coerce =E<gt> (1|0)>
 351
 352 This will attempt to use coercion with the supplied type constraint to change
 353 the value passed into any accessors of constructors. You B<must> have supplied
 354 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 355 for an example usage.
 356
 357 =item I<does =E<gt> $role_name>
 358
 359 This will accept the name of a role which the value stored in this attribute
 360 is expected to have consumed.
 361
 362 =item I<required =E<gt> (1|0)>
 363
 364 This marks the attribute as being required. This means a value must be supplied
 365 during class construction, and the attribute can never be set to C<undef> with
 366 an accessor.
 367
 368 =item I<weak_ref =E<gt> (1|0)>
 369
 370 This will tell the class to strore the value of this attribute as a weakened
 371 reference. If an attribute is a weakened reference, it can B<not> also be coerced.
 372
 373 =item I<lazy =E<gt> (1|0)>
 374
 375 This will tell the class to not create this slot until absolutely nessecary.
 376 If an attribute is marked as lazy it B<must> have a default supplied.
 377
 378 =item I<trigger =E<gt> $code>
 379
 380 The trigger option is a CODE reference which will be called after the value of
 381 the attribute is set. The CODE ref will be passed the instance itself, the
 382 updated value and the attribute meta-object (this is for more advanced fiddling
 383 and can typically be ignored in most cases). You can B<not> have a trigger on
 384 a read-only attribute.
 385
 386 =back
 387
 388 =item B<before $name|@names =E<gt> sub { ... }>
 389
 390 =item B<after $name|@names =E<gt> sub { ... }>
 391
 392 =item B<around $name|@names =E<gt> sub { ... }>
 393
 394 This three items are syntactic sugar for the before, after and around method
 395 modifier features that L<Class::MOP> provides. More information on these can
 396 be found in the L<Class::MOP> documentation for now.
 397
 398 =item B<super>
 399
 400 The keyword C<super> is a noop when called outside of an C<override> method. In
 401 the context of an C<override> method, it will call the next most appropriate
 402 superclass method with the same arguments as the original method.
 403
 404 =item B<override ($name, &sub)>
 405
 406 An C<override> method, is a way of explictly saying "I am overriding this
 407 method from my superclass". You can call C<super> within this method, and
 408 it will work as expected. The same thing I<can> be accomplished with a normal
 409 method call and the C<SUPER::> pseudo-package, it is really your choice.
 410
 411 =item B<inner>
 412
 413 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 414 an C<augment> method. You can think of C<inner> as being the inverse of
 415 C<super>, the details of how C<inner> and C<augment> work is best described in
 416 the L<Moose::Cookbook>.
 417
 418 =item B<augment ($name, &sub)>
 419
 420 An C<augment> method, is a way of explictly saying "I am augmenting this
 421 method from my superclass". Once again, the details of how C<inner> and
 422 C<augment> work is best described in the L<Moose::Cookbook>.
 423
 424 =item B<confess>
 425
 426 This is the C<Carp::confess> function, and exported here beause I use it
 427 all the time. This feature may change in the future, so you have been warned.
 428
 429 =item B<blessed>
 430
 431 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 432 use it all the time. It is highly recommended that this is used instead of
 433 C<ref> anywhere you need to test for an object's class name.
 434
 435 =back
 436
 437 =head1 CAVEATS
 438
 439 =over 4
 440
 441 =item *
 442
 443 It should be noted that C<super> and C<inner> can B<not> be used in the same
 444 method. However, they can be combined together with the same class hierarchy,
 445 see F<t/014_override_augment_inner_super.t> for an example.
 446
 447 The reason that this is so is because C<super> is only valid within a method
 448 with the C<override> modifier, and C<inner> will never be valid within an
 449 C<override> method. In fact, C<augment> will skip over any C<override> methods
 450 when searching for it's appropriate C<inner>.
 451
 452 This might seem like a restriction, but I am of the opinion that keeping these
 453 two features seperate (but interoperable) actually makes them easy to use since
 454 their behavior is then easier to predict. Time will tell if I am right or not.
 455
 456 =back
 457
 458 =head1 ACKNOWLEDGEMENTS
 459
 460 =over 4
 461
 462 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 463
 464 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 465
 466 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 467 and it certainly wouldn't have this name ;P
 468
 469 =item The basis of the TypeContraints module was Rob Kinyon's idea
 470 originally, I just ran with it.
 471
 472 =item Thanks to mst & chansen and the whole #moose poose for all the
 473 ideas/feature-requests/encouragement
 474
 475 =back
 476
 477 =head1 SEE ALSO
 478
 479 =over 4
 480
 481 =item L<Class::MOP> documentation
 482
 483 =item The #moose channel on irc.perl.org
 484
 485 =item L<http://forum2.org/moose/>
 486
 487 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 488
 489 This paper (suggested by lbr on #moose) was what lead to the implementation
 490 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 491 want to understand this feature, I suggest you read this.
 492
 493 =back
 494
 495 =head1 BUGS
 496
 497 All complex software has bugs lurking in it, and this module is no
 498 exception. If you find a bug please either email me, or add the bug
 499 to cpan-RT.
 500
 501 =head1 AUTHOR
 502
 503 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 504
 505 =head1 COPYRIGHT AND LICENSE
 506
 507 Copyright 2006 by Infinity Interactive, Inc.
 508
 509 L<http://www.iinteractive.com>
 510
 511 This library is free software; you can redistribute it and/or modify
 512 it under the same terms as Perl itself.
 513
 514 =cut