lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.12';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12 use B            'svref_2object';
  13
  14 use UNIVERSAL::require;
  15 use Sub::Exporter;
  16
  17 use Class::MOP;
  18
  19 use Moose::Meta::Class;
  20 use Moose::Meta::TypeConstraint;
  21 use Moose::Meta::TypeCoercion;
  22 use Moose::Meta::Attribute;
  23 use Moose::Meta::Instance;
  24
  25 use Moose::Object;
  26 use Moose::Util::TypeConstraints;
  27
  28 {
  29     my $CALLER;
  30
  31     sub _init_meta {
  32         my $class = $CALLER;
  33
  34         # make a subtype for each Moose class
  35         subtype $class
  36             => as 'Object'
  37             => where { $_->isa($class) }
  38         unless find_type_constraint($class);
  39
  40         my $meta;
  41         if ($class->can('meta')) {
  42             # NOTE:
  43             # this is the case where the metaclass pragma
  44             # was used before the 'use Moose' statement to
  45             # override a specific class
  46             $meta = $class->meta();
  47             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  48                 || confess "You already have a &meta function, but it does not return a Moose::Meta::Class";
  49         }
  50         else {
  51             # NOTE:
  52             # this is broken currently, we actually need
  53             # to allow the possiblity of an inherited
  54             # meta, which will not be visible until the
  55             # user 'extends' first. This needs to have
  56             # more intelligence to it
  57             $meta = Moose::Meta::Class->initialize($class);
  58             $meta->add_method('meta' => sub {
  59                 # re-initialize so it inherits properly
  60                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  61             })
  62         }
  63
  64         # make sure they inherit from Moose::Object
  65         $meta->superclasses('Moose::Object')
  66            unless $meta->superclasses();
  67     }
  68
  69     my %exports = (
  70         extends => sub {
  71             my $class = $CALLER;
  72             return subname 'Moose::extends' => sub (@) {
  73                 confess "Must derive at least one class" unless @_;
  74                 _load_all_classes(@_);
  75                 # this checks the metaclass to make sure
  76                 # it is correct, sometimes it can get out
  77                 # of sync when the classes are being built
  78                 my $meta = $class->meta->_fix_metaclass_incompatability(@_);
  79                 $meta->superclasses(@_);
  80             };
  81         },
  82         with => sub {
  83             my $class = $CALLER;
  84             return subname 'Moose::with' => sub (@) {
  85                 my (@roles) = @_;
  86                 confess "Must specify at least one role" unless @roles;
  87                 _load_all_classes(@roles);
  88                 $class->meta->_apply_all_roles(@roles);
  89             };
  90         },
  91         has => sub {
  92             my $class = $CALLER;
  93             return subname 'Moose::has' => sub ($;%) {
  94                 my ($name, %options) = @_;
  95                 $class->meta->_process_attribute($name, %options);
  96             };
  97         },
  98         before => sub {
  99             my $class = $CALLER;
 100             return subname 'Moose::before' => sub (@&) {
 101                 my $code = pop @_;
 102                 my $meta = $class->meta;
 103                 $meta->add_before_method_modifier($_, $code) for @_;
 104             };
 105         },
 106         after => sub {
 107             my $class = $CALLER;
 108             return subname 'Moose::after' => sub (@&) {
 109                 my $code = pop @_;
 110                 my $meta = $class->meta;
 111                 $meta->add_after_method_modifier($_, $code) for @_;
 112             };
 113         },
 114         around => sub {
 115             my $class = $CALLER;
 116             return subname 'Moose::around' => sub (@&) {
 117                 my $code = pop @_;
 118                 my $meta = $class->meta;
 119                 $meta->add_around_method_modifier($_, $code) for @_;
 120             };
 121         },
 122         super => sub {
 123             return subname 'Moose::super' => sub {};
 124         },
 125         override => sub {
 126             my $class = $CALLER;
 127             return subname 'Moose::override' => sub ($&) {
 128                 my ($name, $method) = @_;
 129                 $class->meta->add_override_method_modifier($name => $method);
 130             };
 131         },
 132         inner => sub {
 133             return subname 'Moose::inner' => sub {};
 134         },
 135         augment => sub {
 136             my $class = $CALLER;
 137             return subname 'Moose::augment' => sub (@&) {
 138                 my ($name, $method) = @_;
 139                 $class->meta->add_augment_method_modifier($name => $method);
 140             };
 141         },
 142
 143         # NOTE:
 144         # this is experimental for now ...
 145         self => sub {
 146             return subname 'Moose::self' => sub {};
 147         },
 148         method => sub {
 149             my $class = $CALLER;
 150             return subname 'Moose::method' => sub {
 151                 my ($name, $method) = @_;
 152                 $class->meta->add_method($name, sub {
 153                     my $self = shift;
 154                     no strict   'refs';
 155                     no warnings 'redefine';
 156                     local *{$class->meta->name . '::self'} = sub { $self };
 157                     $method->(@_);
 158                 });
 159             };
 160         },
 161
 162         confess => sub {
 163             return \&Carp::confess;
 164         },
 165         blessed => sub {
 166             return \&Scalar::Util::blessed;
 167         },
 168     );
 169
 170     my $exporter = Sub::Exporter::build_exporter({
 171         exports => \%exports,
 172         groups  => {
 173             default => [':all']
 174         }
 175     });
 176
 177     sub import {
 178         $CALLER = caller();
 179
 180         strict->import;
 181         warnings->import;
 182
 183         # we should never export to main
 184         return if $CALLER eq 'main';
 185
 186         _init_meta();
 187
 188         goto $exporter;
 189     }
 190
 191     sub unimport {
 192         no strict 'refs';
 193         my $class = caller();
 194         # loop through the exports ...
 195         foreach my $name (keys %exports) {
 196             next if $name =~ /inner|super|self/;
 197
 198             # if we find one ...
 199             if (defined &{$class . '::' . $name}) {
 200                 my $keyword = \&{$class . '::' . $name};
 201
 202                 # make sure it is from Moose
 203                 my $pkg_name = eval { svref_2object($keyword)->GV->STASH->NAME };
 204                 next if $@;
 205                 next if $pkg_name ne 'Moose';
 206
 207                 # and if it is from Moose then undef the slot
 208                 delete ${$class . '::'}{$name};
 209             }
 210         }
 211     }
 212 }
 213
 214 ## Utility functions
 215
 216 sub _load_all_classes {
 217     foreach my $super (@_) {
 218         # see if this is already
 219         # loaded in the symbol table
 220         next if _is_class_already_loaded($super);
 221         # otherwise require it ...
 222         ($super->require)
 223             || confess "Could not load module '$super' because : " . $UNIVERSAL::require::ERROR;
 224     }
 225 }
 226
 227 sub _is_class_already_loaded {
 228         my $name = shift;
 229         no strict 'refs';
 230         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 231         foreach (keys %{"${name}::"}) {
 232                 next if substr($_, -2, 2) eq '::';
 233                 return 1 if defined &{"${name}::$_"};
 234         }
 235     return 0;
 236 }
 237
 238 1;
 239
 240 __END__
 241
 242 =pod
 243
 244 =head1 NAME
 245
 246 Moose - A complete modern object system for Perl 5
 247
 248 =head1 SYNOPSIS
 249
 250   package Point;
 251   use strict;
 252   use warnings;
 253   use Moose;
 254
 255   has 'x' => (is => 'rw', isa => 'Int');
 256   has 'y' => (is => 'rw', isa => 'Int');
 257
 258   sub clear {
 259       my $self = shift;
 260       $self->x(0);
 261       $self->y(0);
 262   }
 263
 264   package Point3D;
 265   use strict;
 266   use warnings;
 267   use Moose;
 268
 269   extends 'Point';
 270
 271   has 'z' => (is => 'rw', isa => 'Int');
 272
 273   after 'clear' => sub {
 274       my $self = shift;
 275       $self->z(0);
 276   };
 277
 278 =head1 CAVEAT
 279
 280 Moose is a rapidly maturing module, and is already being used by
 281 a number of people. It's test suite is growing larger by the day,
 282 and the docs should soon follow.
 283
 284 This said, Moose is not yet finished, and should still be considered
 285 to be evolving. Much of the outer API is stable, but the internals
 286 are still subject to change (although not without serious thought
 287 given to it).
 288
 289 For more details, please refer to the L<FUTURE PLANS> section of
 290 this document.
 291
 292 =head1 DESCRIPTION
 293
 294 Moose is an extension of the Perl 5 object system.
 295
 296 =head2 Another object system!?!?
 297
 298 Yes, I know there has been an explosion recently of new ways to
 299 build object's in Perl 5, most of them based on inside-out objects
 300 and other such things. Moose is different because it is not a new
 301 object system for Perl 5, but instead an extension of the existing
 302 object system.
 303
 304 Moose is built on top of L<Class::MOP>, which is a metaclass system
 305 for Perl 5. This means that Moose not only makes building normal
 306 Perl 5 objects better, but it also provides the power of metaclass
 307 programming.
 308
 309 =head2 Can I use this in production? Or is this just an experiment?
 310
 311 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 312 meta-model; however Moose is B<NOT> an experiment/prototype, it is
 313 for B<real>. I will be deploying Moose into production environments later
 314 this year, and I have every intentions of using it as my de facto class
 315 builder from now on.
 316
 317 =head2 Is Moose just Perl 6 in Perl 5?
 318
 319 No. While Moose is very much inspired by Perl 6, it is not itself Perl 6.
 320 Instead, it is an OO system for Perl 5. I built Moose because I was tired or
 321 writing the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 322 instead of switching to Ruby, I wrote Moose :)
 323
 324 =head1 BUILDING CLASSES WITH MOOSE
 325
 326 Moose makes every attempt to provide as much convenience as possible during
 327 class construction/definition, but still stay out of your way if you want it
 328 to. Here are a few items to note when building classes with Moose.
 329
 330 Unless specified with C<extends>, any class which uses Moose will
 331 inherit from L<Moose::Object>.
 332
 333 Moose will also manage all attributes (including inherited ones) that
 334 are defined with C<has>. And assuming that you call C<new>, which is
 335 inherited from L<Moose::Object>, then this includes properly initializing
 336 all instance slots, setting defaults where appropriate, and performing any
 337 type constraint checking or coercion.
 338
 339 =head1 EXPORTED FUNCTIONS
 340
 341 Moose will export a number of functions into the class's namespace which
 342 can then be used to set up the class. These functions all work directly
 343 on the current class.
 344
 345 =over 4
 346
 347 =item B<meta>
 348
 349 This is a method which provides access to the current class's metaclass.
 350
 351 =item B<extends (@superclasses)>
 352
 353 This function will set the superclass(es) for the current class.
 354
 355 This approach is recommended instead of C<use base>, because C<use base>
 356 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 357 replace it. This is important to ensure that classes which do not have
 358 superclasses still properly inherit from L<Moose::Object>.
 359
 360 =item B<with (@roles)>
 361
 362 This will apply a given set of C<@roles> to the local class. Role support
 363 is currently under heavy development; see L<Moose::Role> for more details.
 364
 365 =item B<has ($name, %options)>
 366
 367 This will install an attribute of a given C<$name> into the current class.
 368 The list of C<%options> are the same as those provided by
 369 L<Class::MOP::Attribute>, in addition to the list below which are provided
 370 by Moose (L<Moose::Meta::Attribute> to be more specific):
 371
 372 =over 4
 373
 374 =item I<is =E<gt> 'rw'|'ro'>
 375
 376 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 377 only). These will create either a read/write accessor or a read-only
 378 accessor respectively, using the same name as the C<$name> of the attribute.
 379
 380 If you need more control over how your accessors are named, you can use the
 381 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 382
 383 =item I<isa =E<gt> $type_name>
 384
 385 The I<isa> option uses Moose's type constraint facilities to set up runtime
 386 type checking for this attribute. Moose will perform the checks during class
 387 construction, and within any accessors. The C<$type_name> argument must be a
 388 string. The string can be either a class name or a type defined using
 389 Moose's type definition features.
 390
 391 =item I<coerce =E<gt> (1|0)>
 392
 393 This will attempt to use coercion with the supplied type constraint to change
 394 the value passed into any accessors or constructors. You B<must> have supplied
 395 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 396 for an example usage.
 397
 398 =item I<does =E<gt> $role_name>
 399
 400 This will accept the name of a role which the value stored in this attribute
 401 is expected to have consumed.
 402
 403 =item I<required =E<gt> (1|0)>
 404
 405 This marks the attribute as being required. This means a value must be supplied
 406 during class construction, and the attribute can never be set to C<undef> with
 407 an accessor.
 408
 409 =item I<weak_ref =E<gt> (1|0)>
 410
 411 This will tell the class to store the value of this attribute as a weakened
 412 reference. If an attribute is a weakened reference, it B<cannot> also be
 413 coerced.
 414
 415 =item I<lazy =E<gt> (1|0)>
 416
 417 This will tell the class to not create this slot until absolutely necessary.
 418 If an attribute is marked as lazy it B<must> have a default supplied.
 419
 420 =item I<auto_deref =E<gt> (1|0)>
 421
 422 This tells the accessor whether to automatically dereference the value returned.
 423 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 424
 425 =item I<trigger =E<gt> $code>
 426
 427 The trigger option is a CODE reference which will be called after the value of
 428 the attribute is set. The CODE ref will be passed the instance itself, the
 429 updated value and the attribute meta-object (this is for more advanced fiddling
 430 and can typically be ignored in most cases). You B<cannot> have a trigger on
 431 a read-only attribute.
 432
 433 =item I<handles =E<gt> [ @handles ]>
 434
 435 There is experimental support for attribute delegation using the C<handles>
 436 option. More docs to come later.
 437
 438 =back
 439
 440 =item B<before $name|@names =E<gt> sub { ... }>
 441
 442 =item B<after $name|@names =E<gt> sub { ... }>
 443
 444 =item B<around $name|@names =E<gt> sub { ... }>
 445
 446 This three items are syntactic sugar for the before, after, and around method
 447 modifier features that L<Class::MOP> provides. More information on these can
 448 be found in the L<Class::MOP> documentation for now.
 449
 450 =item B<super>
 451
 452 The keyword C<super> is a no-op when called outside of an C<override> method. In
 453 the context of an C<override> method, it will call the next most appropriate
 454 superclass method with the same arguments as the original method.
 455
 456 =item B<override ($name, &sub)>
 457
 458 An C<override> method is a way of explicitly saying "I am overriding this
 459 method from my superclass". You can call C<super> within this method, and
 460 it will work as expected. The same thing I<can> be accomplished with a normal
 461 method call and the C<SUPER::> pseudo-package; it is really your choice.
 462
 463 =item B<inner>
 464
 465 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 466 an C<augment> method. You can think of C<inner> as being the inverse of
 467 C<super>; the details of how C<inner> and C<augment> work is best described in
 468 the L<Moose::Cookbook>.
 469
 470 =item B<augment ($name, &sub)>
 471
 472 An C<augment> method, is a way of explicitly saying "I am augmenting this
 473 method from my superclass". Once again, the details of how C<inner> and
 474 C<augment> work is best described in the L<Moose::Cookbook>.
 475
 476 =item B<confess>
 477
 478 This is the C<Carp::confess> function, and exported here because I use it
 479 all the time. This feature may change in the future, so you have been warned.
 480
 481 =item B<blessed>
 482
 483 This is the C<Scalar::Uti::blessed> function, it is exported here because I
 484 use it all the time. It is highly recommended that this is used instead of
 485 C<ref> anywhere you need to test for an object's class name.
 486
 487 =back
 488
 489 =head1 UNEXPORTING FUNCTIONS
 490
 491 =head2 B<unimport>
 492
 493 Moose offers a way of removing the keywords it exports though the C<unimport>
 494 method. You simply have to say C<no Moose> at the bottom of your code for this
 495 to work. Here is an example:
 496
 497     package Person;
 498     use Moose;
 499
 500     has 'first_name' => (is => 'rw', isa => 'Str');
 501     has 'last_name'  => (is => 'rw', isa => 'Str');
 502
 503     sub full_name {
 504         my $self = shift;
 505         $self->first_name . ' ' . $self->last_name
 506     }
 507
 508     no Moose; # keywords are removed from the Person package
 509
 510 =head1 MISC.
 511
 512 =head2 What does Moose stand for??
 513
 514 Moose doesn't stand for one thing in particular, however, if you
 515 want, here are a few of my favorites; feel free to contribute
 516 more :)
 517
 518 =over 4
 519
 520 =item Make Other Object Systems Envious
 521
 522 =item Makes Object Orientation So Easy
 523
 524 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 525
 526 =item Most Other Object Systems Emasculate
 527
 528 =item Moose Often Ovulate Sorta Early
 529
 530 =item Moose Offers Often Super Extensions
 531
 532 =item Meta Object Orientation Syntax Extensions
 533
 534 =back
 535
 536 =head1 CAVEATS
 537
 538 =over 4
 539
 540 =item *
 541
 542 It should be noted that C<super> and C<inner> C<cannot> be used in the same
 543 method. However, they can be combined together with the same class hierarchy;
 544 see F<t/014_override_augment_inner_super.t> for an example.
 545
 546 The reason for this is that C<super> is only valid within a method
 547 with the C<override> modifier, and C<inner> will never be valid within an
 548 C<override> method. In fact, C<augment> will skip over any C<override> methods
 549 when searching for its appropriate C<inner>.
 550
 551 This might seem like a restriction, but I am of the opinion that keeping these
 552 two features separate (but interoperable) actually makes them easy to use, since
 553 their behavior is then easier to predict. Time will tell if I am right or not.
 554
 555 =back
 556
 557 =head1 ACKNOWLEDGEMENTS
 558
 559 =over 4
 560
 561 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 562
 563 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 564
 565 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 566 and it certainly wouldn't have this name ;P
 567
 568 =item The basis of the TypeContraints module was Rob Kinyon's idea
 569 originally, I just ran with it.
 570
 571 =item Thanks to mst & chansen and the whole #moose poose for all the
 572 ideas/feature-requests/encouragement
 573
 574 =item Thanks to David "Theory" Wheeler for meta-discussions and spelling fixes.
 575
 576 =back
 577
 578 =head1 SEE ALSO
 579
 580 =over 4
 581
 582 =item L<Class::MOP> documentation
 583
 584 =item The #moose channel on irc.perl.org
 585
 586 =item L<http://forum2.org/moose/>
 587
 588 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 589
 590 This paper (suggested by lbr on #moose) was what lead to the implementation
 591 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 592 want to understand this feature, I suggest you read this.
 593
 594 =back
 595
 596 =head1 BUGS
 597
 598 All complex software has bugs lurking in it, and this module is no
 599 exception. If you find a bug please either email me, or add the bug
 600 to cpan-RT.
 601
 602 =head1 AUTHOR
 603
 604 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 605
 606 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 607
 608 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 609
 610 =head1 COPYRIGHT AND LICENSE
 611
 612 Copyright 2006 by Infinity Interactive, Inc.
 613
 614 L<http://www.iinteractive.com>
 615
 616 This library is free software; you can redistribute it and/or modify
 617 it under the same terms as Perl itself.
 618
 619 =cut