lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.02';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14
  15 use Class::MOP;
  16
  17 use Moose::Meta::Class;
  18 use Moose::Meta::Attribute;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21
  22 use Moose::Object;
  23 use Moose::Util::TypeConstraints;
  24
  25 sub import {
  26         shift;
  27         my $pkg = caller();
  28
  29         # we should never export to main
  30         return if $pkg eq 'main';
  31
  32         Moose::Util::TypeConstraints->import($pkg);
  33
  34         # make a subtype for each Moose class
  35     subtype $pkg
  36         => as Object
  37         => where { $_->isa($pkg) };
  38
  39         my $meta;
  40         if ($pkg->can('meta')) {
  41                 $meta = $pkg->meta();
  42                 (blessed($meta) && $meta->isa('Class::MOP::Class'))
  43                         || confess "Whoops, not møøsey enough";
  44         }
  45         else {
  46                 $meta = Moose::Meta::Class->initialize($pkg => (
  47                         ':attribute_metaclass' => 'Moose::Meta::Attribute'
  48                 ));
  49                 $meta->add_method('meta' => sub {
  50                         # re-initialize so it inherits properly
  51                         Moose::Meta::Class->initialize($pkg => (
  52                                 ':attribute_metaclass' => 'Moose::Meta::Attribute'
  53                         ));
  54                 })
  55         }
  56
  57         # NOTE:
  58         # &alias_method will install the method, but it
  59         # will not name it with
  60
  61         # handle superclasses
  62         $meta->alias_method('extends' => subname 'Moose::extends' => sub {
  63             $_->require for @_;
  64             $meta->superclasses(@_)
  65         });
  66
  67         # handle attributes
  68         $meta->alias_method('has' => subname 'Moose::has' => sub {
  69                 my ($name, %options) = @_;
  70                 if (exists $options{is}) {
  71                         if ($options{is} eq 'ro') {
  72                                 $options{reader} = $name;
  73                         }
  74                         elsif ($options{is} eq 'rw') {
  75                                 $options{accessor} = $name;
  76                         }
  77                 }
  78                 if (exists $options{isa}) {
  79                     # allow for anon-subtypes here ...
  80                     if (blessed($options{isa}) && $options{isa}->isa('Moose::Meta::TypeConstraint')) {
  81                                 $options{type_constraint} = $options{isa};
  82                         }
  83                         else {
  84                             # otherwise assume it is a constraint
  85                             my $constraint = find_type_constraint($options{isa});
  86                             # if the constraing it not found ....
  87                             unless (defined $constraint) {
  88                                 # assume it is a foreign class, and make
  89                                 # an anon constraint for it
  90                                 $constraint = subtype Object => where { $_->isa($options{isa}) };
  91                             }
  92                 $options{type_constraint} = $constraint;
  93                         }
  94                 }
  95                 $meta->add_attribute($name, %options)
  96         });
  97
  98         # handle method modifers
  99         $meta->alias_method('before' => subname 'Moose::before' => sub {
 100                 my $code = pop @_;
 101                 $meta->add_before_method_modifier($_, $code) for @_;
 102         });
 103         $meta->alias_method('after'  => subname 'Moose::after' => sub {
 104                 my $code = pop @_;
 105                 $meta->add_after_method_modifier($_, $code) for @_;
 106         });
 107         $meta->alias_method('around' => subname 'Moose::around' => sub {
 108                 my $code = pop @_;
 109                 $meta->add_around_method_modifier($_, $code) for @_;
 110         });
 111
 112         # make sure they inherit from Moose::Object
 113         $meta->superclasses('Moose::Object')
 114        unless $meta->superclasses();
 115
 116         # we recommend using these things
 117         # so export them for them
 118         $meta->alias_method('confess' => \&Carp::confess);
 119         $meta->alias_method('blessed' => \&Scalar::Util::blessed);
 120 }
 121
 122 1;
 123
 124 __END__
 125
 126 =pod
 127
 128 =head1 NAME
 129
 130 Moose - Moose, it's the new Camel
 131
 132 =head1 SYNOPSIS
 133
 134   package Point;
 135   use Moose;
 136
 137   has 'x' => (isa => 'Int', is => 'rw');
 138   has 'y' => (isa => 'Int', is => 'rw');
 139
 140   sub clear {
 141       my $self = shift;
 142       $self->x(0);
 143       $self->y(0);
 144   }
 145
 146   package Point3D;
 147   use Moose;
 148
 149   extends 'Point';
 150
 151   has 'z' => (isa => 'Int');
 152
 153   after 'clear' => sub {
 154       my $self = shift;
 155       $self->{z} = 0;
 156   };
 157
 158 =head1 CAVEAT
 159
 160 This is a B<very> early release of this module, it still needs
 161 some fine tuning and B<lots> more documentation. I am adopting
 162 the I<release early and release often> approach with this module,
 163 so keep an eye on your favorite CPAN mirror!
 164
 165 =head1 DESCRIPTION
 166
 167 Moose is an extension of the Perl 5 object system.
 168
 169 =head2 Another object system!?!?
 170
 171 Yes, I know there has been an explosion recently of new ways to
 172 build object's in Perl 5, most of them based on inside-out objects,
 173 and other such things. Moose is different because it is not a new
 174 object system for Perl 5, but instead an extension of the existing
 175 object system.
 176
 177 Moose is built on top of L<Class::MOP>, which is a metaclass system
 178 for Perl 5. This means that Moose not only makes building normal
 179 Perl 5 objects better, but it also provides the power of metaclass
 180 programming.
 181
 182 =head2 What does Moose stand for??
 183
 184 Moose doesn't stand for one thing in particular, however, if you
 185 want, here are a few of my favorites, feel free to contribute
 186 more :)
 187
 188 =over 4
 189
 190 =item Make Other Object Systems Envious
 191
 192 =item Makes Object Orientation So Easy
 193
 194 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 195
 196 =item Most Other Object Systems Emasculate
 197
 198 =item My Overcraft Overfilled (with) Some Eels
 199
 200 =item Moose Often Ovulate Sorta Early
 201
 202 =item Many Overloaded Object Systems Exists
 203
 204 =item Moose Offers Often Super Extensions
 205
 206 =back
 207
 208 =head1 BUILDING CLASSES WITH MOOSE
 209
 210 Moose makes every attempt to provide as much convience during class
 211 construction/definition, but still stay out of your way if you want
 212 it to. Here are some of the features Moose provides:
 213
 214 Unless specified with C<extends>, any class which uses Moose will
 215 inherit from L<Moose::Object>.
 216
 217 Moose will also manage all attributes (including inherited ones) that
 218 are defined with C<has>. And assuming that you call C<new> which is
 219 inherited from L<Moose::Object>, then this includes properly initializing
 220 all instance slots, setting defaults where approprtiate and performing any
 221 type constraint checking or coercion.
 222
 223 =head1 EXPORTED FUNCTIONS
 224
 225 Moose will export a number of functions into the class's namespace, which
 226 can then be used to set up the class. These functions all work directly
 227 on the current class.
 228
 229 =over 4
 230
 231 =item B<meta>
 232
 233 This is a method which provides access to the current class's metaclass.
 234
 235 =item B<extends (@superclasses)>
 236
 237 This function will set the superclass(es) for the current class.
 238
 239 This approach is recommended instead of C<use base>, because C<use base>
 240 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 241 replace it. This is important to ensure that classes which do not have
 242 superclasses properly inherit from L<Moose::Object>.
 243
 244 =item B<has ($name, %options)>
 245
 246 This will install an attribute of a given C<$name> into the current class.
 247 The list of C<%options> are the same as those provided by both
 248 L<Class::MOP::Attribute> and L<Moose::Meta::Attribute>, in addition to a
 249 few convience ones provided by Moose which are listed below:
 250
 251 =over 4
 252
 253 =item I<is =E<gt> 'rw'|'ro'>
 254
 255 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 256 only). These will create either a read/write accessor or a read-only
 257 accessor respectively, using the same name as the C<$name> of the attribute.
 258
 259 If you need more control over how your accessors are named, you can use the
 260 I<reader>, I<writer> and I<accessor> options inherited from L<Moose::Meta::Attribute>.
 261
 262 =item I<isa =E<gt> $type_name>
 263
 264 The I<isa> option uses Moose's type constraint facilities to set up runtime
 265 type checking for this attribute. Moose will perform the checks during class
 266 construction, and within any accessors. The C<$type_name> argument must be a
 267 string. The string can be either a class name, or a type defined using
 268 Moose's type defintion features.
 269
 270 =back
 271
 272 =item B<before $name|@names =E<gt> sub { ... }>
 273
 274 =item B<after $name|@names =E<gt> sub { ... }>
 275
 276 =item B<around $name|@names =E<gt> sub { ... }>
 277
 278 This three items are syntactic sugar for the before, after and around method
 279 modifier features that L<Class::MOP> provides. More information on these can
 280 be found in the L<Class::MOP> documentation for now.
 281
 282 =item B<confess>
 283
 284 This is the C<Carp::confess> function, and exported here beause I use it
 285 all the time. This feature may change in the future, so you have been warned.
 286
 287 =item B<blessed>
 288
 289 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 290 use it all the time. It is highly recommended that this is used instead of
 291 C<ref> anywhere you need to test for an object's class name.
 292
 293 =back
 294
 295 =head1 ACKNOWLEDGEMENTS
 296
 297 =over 4
 298
 299 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 300
 301 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 302
 303 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 304 and it certainly wouldn't have this name ;P
 305
 306 =item The basis of the TypeContraints module was Rob Kinyon's idea
 307 originally, I just ran with it.
 308
 309 =item Thanks to mst & chansen and the whole #moose poose for all the
 310 ideas/feature-requests/encouragement
 311
 312 =back
 313
 314 =head1 SEE ALSO
 315
 316 =over 4
 317
 318 =item L<Class::MOP> documentation
 319
 320 =item The #moose channel on irc.perl.org
 321
 322 =item L<http://forum2.org/moose/>
 323
 324 =back
 325
 326 =head1 BUGS
 327
 328 All complex software has bugs lurking in it, and this module is no
 329 exception. If you find a bug please either email me, or add the bug
 330 to cpan-RT.
 331
 332 =head1 AUTHOR
 333
 334 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 335
 336 =head1 COPYRIGHT AND LICENSE
 337
 338 Copyright 2006 by Infinity Interactive, Inc.
 339
 340 L<http://www.iinteractive.com>
 341
 342 This library is free software; you can redistribute it and/or modify
 343 it under the same terms as Perl itself.
 344
 345 =cut