lib/Moose.pm

   1
   2 package Moose;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.09_03';
   8
   9 use Scalar::Util 'blessed', 'reftype';
  10 use Carp         'confess';
  11 use Sub::Name    'subname';
  12
  13 use UNIVERSAL::require;
  14 use Sub::Exporter;
  15
  16 use Class::MOP;
  17
  18 use Moose::Meta::Class;
  19 use Moose::Meta::TypeConstraint;
  20 use Moose::Meta::TypeCoercion;
  21 use Moose::Meta::Attribute;
  22 use Moose::Meta::Instance;
  23
  24 use Moose::Object;
  25 use Moose::Util::TypeConstraints;
  26
  27 {
  28     my $CALLER;
  29
  30     sub _init_meta {
  31         my $class = $CALLER;
  32
  33         # make a subtype for each Moose class
  34         subtype $class
  35             => as 'Object'
  36             => where { $_->isa($class) }
  37         unless find_type_constraint($class);
  38
  39         my $meta;
  40         if ($class->can('meta')) {
  41             # NOTE:
  42             # this is the case where the metaclass pragma
  43             # was used before the 'use Moose' statement to
  44             # override a specific class
  45             $meta = $class->meta();
  46             (blessed($meta) && $meta->isa('Moose::Meta::Class'))
  47                 || confess "Whoops, not møøsey enough";
  48         }
  49         else {
  50             # NOTE:
  51             # this is broken currently, we actually need
  52             # to allow the possiblity of an inherited
  53             # meta, which will not be visible until the
  54             # user 'extends' first. This needs to have
  55             # more intelligence to it
  56             $meta = Moose::Meta::Class->initialize($class);
  57             $meta->add_method('meta' => sub {
  58                 # re-initialize so it inherits properly
  59                 Moose::Meta::Class->initialize(blessed($_[0]) || $_[0]);
  60             })
  61         }
  62
  63         # make sure they inherit from Moose::Object
  64         $meta->superclasses('Moose::Object')
  65            unless $meta->superclasses();
  66     }
  67
  68     my %exports = (
  69         extends => sub {
  70             my $class = $CALLER;
  71             return subname 'Moose::extends' => sub ($;@) {
  72                 _load_all_classes(@_);
  73                 my $meta = $class->meta;
  74                 foreach my $super (@_) {
  75                     # don't bother if it does not have a meta.
  76                     next unless $super->can('meta');
  77                     # if it's meta is a vanilla Moose,
  78                     # then we can safely ignore it.
  79                     next if blessed($super->meta) eq 'Moose::Meta::Class';
  80                     # but if we have anything else,
  81                     # we need to check it out ...
  82                     unless (# see if of our metaclass is incompatible
  83                             ($meta->isa(blessed($super->meta)) &&
  84                              # and see if our instance metaclass is incompatible
  85                              $meta->instance_metaclass->isa($super->meta->instance_metaclass)) &&
  86                             # ... and if we are just a vanilla Moose
  87                             $meta->isa('Moose::Meta::Class')) {
  88                         # re-initialize the meta ...
  89                         my $super_meta = $super->meta;
  90                         # NOTE:
  91                         # We might want to consider actually
  92                         # transfering any attributes from the
  93                         # original meta into this one, but in
  94                         # general you should not have any there
  95                         # at this point anyway, so it's very
  96                         # much an obscure edge case anyway
  97                         $meta = $super_meta->reinitialize($class => (
  98                             ':attribute_metaclass' => $super_meta->attribute_metaclass,
  99                             ':method_metaclass'    => $super_meta->method_metaclass,
 100                             ':instance_metaclass'  => $super_meta->instance_metaclass,
 101                         ));
 102                     }
 103                 }
 104                 $meta->superclasses(@_);
 105             };
 106         },
 107         with => sub {
 108             my $class = $CALLER;
 109             return subname 'Moose::with' => sub ($;@) {
 110                 my (@roles) = @_;
 111                 _load_all_classes(@roles);
 112                 ($_->can('meta') && $_->meta->isa('Moose::Meta::Role'))
 113                     || confess "You can only consume roles, $_ is not a Moose role"
 114                         foreach @roles;
 115                 if (scalar @roles == 1) {
 116                     $roles[0]->meta->apply($class->meta);
 117                 }
 118                 else {
 119                     Moose::Meta::Role->combine(
 120                         map { $_->meta } @roles
 121                     )->apply($class->meta);
 122                 }
 123             };
 124         },
 125         has => sub {
 126             my $class = $CALLER;
 127             return subname 'Moose::has' => sub ($;%) {
 128                 my ($name, %options) = @_;
 129                 my $meta = $class->meta;
 130                 if ($name =~ /^\+(.*)/) {
 131                     my $inherited_attr = $meta->find_attribute_by_name($1);
 132                     (defined $inherited_attr)
 133                         || confess "Could not find an attribute by the name of '$1' to inherit from";
 134                     my $new_attr;
 135                     if ($inherited_attr->isa('Moose::Meta::Attribute')) {
 136                         $new_attr = $inherited_attr->clone_and_inherit_options(%options);
 137                     }
 138                     else {
 139                         # NOTE:
 140                         # kind of a kludge to handle Class::MOP::Attributes
 141                         $new_attr = Moose::Meta::Attribute::clone_and_inherit_options(
 142                             $inherited_attr, %options
 143                         );
 144                     }
 145                     $meta->add_attribute($new_attr);
 146                 }
 147                 else {
 148                     if ($options{metaclass}) {
 149                         _load_all_classes($options{metaclass});
 150                         $meta->add_attribute($options{metaclass}->new($name, %options));
 151                     }
 152                     else {
 153                         $meta->add_attribute($name, %options);
 154                     }
 155                 }
 156             };
 157         },
 158         before => sub {
 159             my $class = $CALLER;
 160             return subname 'Moose::before' => sub (@&) {
 161                 my $code = pop @_;
 162                 my $meta = $class->meta;
 163                 $meta->add_before_method_modifier($_, $code) for @_;
 164             };
 165         },
 166         after => sub {
 167             my $class = $CALLER;
 168             return subname 'Moose::after' => sub (@&) {
 169                 my $code = pop @_;
 170                 my $meta = $class->meta;
 171                 $meta->add_after_method_modifier($_, $code) for @_;
 172             };
 173         },
 174         around => sub {
 175             my $class = $CALLER;
 176             return subname 'Moose::around' => sub (@&) {
 177                 my $code = pop @_;
 178                 my $meta = $class->meta;
 179                 $meta->add_around_method_modifier($_, $code) for @_;
 180             };
 181         },
 182         super => sub {
 183             return subname 'Moose::super' => sub {};
 184         },
 185         override => sub {
 186             my $class = $CALLER;
 187             return subname 'Moose::override' => sub ($&) {
 188                 my ($name, $method) = @_;
 189                 $class->meta->add_override_method_modifier($name => $method);
 190             };
 191         },
 192         inner => sub {
 193             return subname 'Moose::inner' => sub {};
 194         },
 195         augment => sub {
 196             my $class = $CALLER;
 197             return subname 'Moose::augment' => sub (@&) {
 198                 my ($name, $method) = @_;
 199                 $class->meta->add_augment_method_modifier($name => $method);
 200             };
 201         },
 202         confess => sub {
 203             return \&Carp::confess;
 204         },
 205         blessed => sub {
 206             return \&Scalar::Util::blessed;
 207         }
 208     );
 209
 210     my $exporter = Sub::Exporter::build_exporter({
 211         exports => \%exports,
 212         groups  => {
 213             default => [':all']
 214         }
 215     });
 216
 217     sub import {
 218         $CALLER = caller();
 219
 220         strict->import;
 221         warnings->import;
 222
 223         # we should never export to main
 224         return if $CALLER eq 'main';
 225
 226         _init_meta();
 227
 228         goto $exporter;
 229     }
 230 }
 231
 232 ## Utility functions
 233
 234 sub _load_all_classes {
 235     foreach my $super (@_) {
 236         # see if this is already
 237         # loaded in the symbol table
 238         next if _is_class_already_loaded($super);
 239         # otherwise require it ...
 240         ($super->require)
 241             || confess "Could not load superclass '$super' because : " . $UNIVERSAL::require::ERROR;
 242     }
 243 }
 244
 245 sub _is_class_already_loaded {
 246         my $name = shift;
 247         no strict 'refs';
 248         return 1 if defined ${"${name}::VERSION"} || defined @{"${name}::ISA"};
 249         foreach (keys %{"${name}::"}) {
 250                 next if substr($_, -2, 2) eq '::';
 251                 return 1 if defined &{"${name}::$_"};
 252         }
 253     return 0;
 254 }
 255
 256 1;
 257
 258 __END__
 259
 260 =pod
 261
 262 =head1 NAME
 263
 264 Moose - Moose, it's the new Camel
 265
 266 =head1 SYNOPSIS
 267
 268   package Point;
 269   use strict;
 270   use warnings;
 271   use Moose;
 272
 273   has 'x' => (is => 'rw', isa => 'Int');
 274   has 'y' => (is => 'rw', isa => 'Int');
 275
 276   sub clear {
 277       my $self = shift;
 278       $self->x(0);
 279       $self->y(0);
 280   }
 281
 282   package Point3D;
 283   use strict;
 284   use warnings;
 285   use Moose;
 286
 287   extends 'Point';
 288
 289   has 'z' => (is => 'rw', isa => 'Int');
 290
 291   after 'clear' => sub {
 292       my $self = shift;
 293       $self->z(0);
 294   };
 295
 296 =head1 CAVEAT
 297
 298 Moose is a rapidly maturing module, and is already being used by
 299 a number of people. It's test suite is growing larger by the day,
 300 and the docs should soon follow.
 301
 302 This said, Moose is not yet finished, and should still be considered
 303 to be evolving. Much of the outer API is stable, but the internals
 304 are still subject to change (although not without serious thought
 305 given to it).
 306
 307 For more details, please refer to the L<FUTURE PLANS> section of
 308 this document.
 309
 310 =head1 DESCRIPTION
 311
 312 Moose is an extension of the Perl 5 object system.
 313
 314 =head2 Another object system!?!?
 315
 316 Yes, I know there has been an explosion recently of new ways to
 317 build object's in Perl 5, most of them based on inside-out objects,
 318 and other such things. Moose is different because it is not a new
 319 object system for Perl 5, but instead an extension of the existing
 320 object system.
 321
 322 Moose is built on top of L<Class::MOP>, which is a metaclass system
 323 for Perl 5. This means that Moose not only makes building normal
 324 Perl 5 objects better, but it also provides the power of metaclass
 325 programming.
 326
 327 =head2 Can I use this in production? Or is this just an experiment?
 328
 329 Moose is I<based> on the prototypes and experiments I did for the Perl 6
 330 meta-model, however Moose is B<NOT> an experiment/prototype, it is
 331 for B<real>. I will be deploying Moose into production environments later
 332 this year, and I have all intentions of using it as my de-facto class
 333 builderfrom now on.
 334
 335 =head2 Is Moose just Perl 6 in Perl 5?
 336
 337 No. While Moose is very much inspired by Perl 6, it is not. Instead, it
 338 is an OO system for Perl 5. I built Moose because I was tired or writing
 339 the same old boring Perl 5 OO code, and drooling over Perl 6 OO. So
 340 instead of switching to Ruby, I wrote Moose :)
 341
 342 =head1 BUILDING CLASSES WITH MOOSE
 343
 344 Moose makes every attempt to provide as much convience during class
 345 construction/definition, but still stay out of your way if you want
 346 it to. Here are a few items to note when building classes with Moose.
 347
 348 Unless specified with C<extends>, any class which uses Moose will
 349 inherit from L<Moose::Object>.
 350
 351 Moose will also manage all attributes (including inherited ones) that
 352 are defined with C<has>. And assuming that you call C<new> which is
 353 inherited from L<Moose::Object>, then this includes properly initializing
 354 all instance slots, setting defaults where approprtiate and performing any
 355 type constraint checking or coercion.
 356
 357 =head1 EXPORTED FUNCTIONS
 358
 359 Moose will export a number of functions into the class's namespace, which
 360 can then be used to set up the class. These functions all work directly
 361 on the current class.
 362
 363 =over 4
 364
 365 =item B<meta>
 366
 367 This is a method which provides access to the current class's metaclass.
 368
 369 =item B<extends (@superclasses)>
 370
 371 This function will set the superclass(es) for the current class.
 372
 373 This approach is recommended instead of C<use base>, because C<use base>
 374 actually C<push>es onto the class's C<@ISA>, whereas C<extends> will
 375 replace it. This is important to ensure that classes which do not have
 376 superclasses properly inherit from L<Moose::Object>.
 377
 378 =item B<with (@roles)>
 379
 380 This will apply a given set of C<@roles> to the local class. Role support
 381 is currently under heavy development, see L<Moose::Role> for more details.
 382
 383 =item B<has ($name, %options)>
 384
 385 This will install an attribute of a given C<$name> into the current class.
 386 The list of C<%options> are the same as those provided by
 387 L<Class::MOP::Attribute>, in addition to the list below which are provided
 388 by Moose (L<Moose::Meta::Attribute> to be more specific):
 389
 390 =over 4
 391
 392 =item I<is =E<gt> 'rw'|'ro'>
 393
 394 The I<is> option accepts either I<rw> (for read/write) or I<ro> (for read
 395 only). These will create either a read/write accessor or a read-only
 396 accessor respectively, using the same name as the C<$name> of the attribute.
 397
 398 If you need more control over how your accessors are named, you can use the
 399 I<reader>, I<writer> and I<accessor> options inherited from L<Class::MOP::Attribute>.
 400
 401 =item I<isa =E<gt> $type_name>
 402
 403 The I<isa> option uses Moose's type constraint facilities to set up runtime
 404 type checking for this attribute. Moose will perform the checks during class
 405 construction, and within any accessors. The C<$type_name> argument must be a
 406 string. The string can be either a class name, or a type defined using
 407 Moose's type defintion features.
 408
 409 =item I<coerce =E<gt> (1|0)>
 410
 411 This will attempt to use coercion with the supplied type constraint to change
 412 the value passed into any accessors of constructors. You B<must> have supplied
 413 a type constraint in order for this to work. See L<Moose::Cookbook::Recipe5>
 414 for an example usage.
 415
 416 =item I<does =E<gt> $role_name>
 417
 418 This will accept the name of a role which the value stored in this attribute
 419 is expected to have consumed.
 420
 421 =item I<required =E<gt> (1|0)>
 422
 423 This marks the attribute as being required. This means a value must be supplied
 424 during class construction, and the attribute can never be set to C<undef> with
 425 an accessor.
 426
 427 =item I<weak_ref =E<gt> (1|0)>
 428
 429 This will tell the class to strore the value of this attribute as a weakened
 430 reference. If an attribute is a weakened reference, it can B<not> also be coerced.
 431
 432 =item I<lazy =E<gt> (1|0)>
 433
 434 This will tell the class to not create this slot until absolutely nessecary.
 435 If an attribute is marked as lazy it B<must> have a default supplied.
 436
 437 =item I<auto_deref =E<gt> (1|0)>
 438
 439 This tells the accessor whether to automatically de-reference the value returned.
 440 This is only legal if your C<isa> option is either an C<ArrayRef> or C<HashRef>.
 441
 442 =item I<trigger =E<gt> $code>
 443
 444 The trigger option is a CODE reference which will be called after the value of
 445 the attribute is set. The CODE ref will be passed the instance itself, the
 446 updated value and the attribute meta-object (this is for more advanced fiddling
 447 and can typically be ignored in most cases). You can B<not> have a trigger on
 448 a read-only attribute.
 449
 450 =item I<handles =E<gt> [ @handles ]>
 451
 452 There is experimental support for attribute delegation using the C<handles>
 453 option. More docs to come later.
 454
 455 =back
 456
 457 =item B<before $name|@names =E<gt> sub { ... }>
 458
 459 =item B<after $name|@names =E<gt> sub { ... }>
 460
 461 =item B<around $name|@names =E<gt> sub { ... }>
 462
 463 This three items are syntactic sugar for the before, after and around method
 464 modifier features that L<Class::MOP> provides. More information on these can
 465 be found in the L<Class::MOP> documentation for now.
 466
 467 =item B<super>
 468
 469 The keyword C<super> is a noop when called outside of an C<override> method. In
 470 the context of an C<override> method, it will call the next most appropriate
 471 superclass method with the same arguments as the original method.
 472
 473 =item B<override ($name, &sub)>
 474
 475 An C<override> method, is a way of explictly saying "I am overriding this
 476 method from my superclass". You can call C<super> within this method, and
 477 it will work as expected. The same thing I<can> be accomplished with a normal
 478 method call and the C<SUPER::> pseudo-package, it is really your choice.
 479
 480 =item B<inner>
 481
 482 The keyword C<inner>, much like C<super>, is a no-op outside of the context of
 483 an C<augment> method. You can think of C<inner> as being the inverse of
 484 C<super>, the details of how C<inner> and C<augment> work is best described in
 485 the L<Moose::Cookbook>.
 486
 487 =item B<augment ($name, &sub)>
 488
 489 An C<augment> method, is a way of explictly saying "I am augmenting this
 490 method from my superclass". Once again, the details of how C<inner> and
 491 C<augment> work is best described in the L<Moose::Cookbook>.
 492
 493 =item B<confess>
 494
 495 This is the C<Carp::confess> function, and exported here beause I use it
 496 all the time. This feature may change in the future, so you have been warned.
 497
 498 =item B<blessed>
 499
 500 This is the C<Scalar::Uti::blessed> function, it is exported here beause I
 501 use it all the time. It is highly recommended that this is used instead of
 502 C<ref> anywhere you need to test for an object's class name.
 503
 504 =back
 505
 506 =head1 FUTURE PLANS
 507
 508 Here is just a sampling of the plans we have in store for Moose:
 509
 510 =over 4
 511
 512 =item *
 513
 514 Compiling Moose classes/roles into C<.pmc> files for faster loading and execution.
 515
 516 =item *
 517
 518 Supporting sealed and finalized classes in Moose. This will allow greater control
 519 of the extensions of frameworks and such.
 520
 521 =back
 522
 523 =head1 MISC.
 524
 525 =head2 What does Moose stand for??
 526
 527 Moose doesn't stand for one thing in particular, however, if you
 528 want, here are a few of my favorites, feel free to contribute
 529 more :)
 530
 531 =over 4
 532
 533 =item Make Other Object Systems Envious
 534
 535 =item Makes Object Orientation So Easy
 536
 537 =item Makes Object Orientation Spiffy- Er  (sorry ingy)
 538
 539 =item Most Other Object Systems Emasculate
 540
 541 =item Moose Often Ovulate Sorta Early
 542
 543 =item Moose Offers Often Super Extensions
 544
 545 =item Meta Object Orientation Syntax Extensions
 546
 547 =back
 548
 549 =head1 CAVEATS
 550
 551 =over 4
 552
 553 =item *
 554
 555 It should be noted that C<super> and C<inner> can B<not> be used in the same
 556 method. However, they can be combined together with the same class hierarchy,
 557 see F<t/014_override_augment_inner_super.t> for an example.
 558
 559 The reason that this is so is because C<super> is only valid within a method
 560 with the C<override> modifier, and C<inner> will never be valid within an
 561 C<override> method. In fact, C<augment> will skip over any C<override> methods
 562 when searching for it's appropriate C<inner>.
 563
 564 This might seem like a restriction, but I am of the opinion that keeping these
 565 two features seperate (but interoperable) actually makes them easy to use since
 566 their behavior is then easier to predict. Time will tell if I am right or not.
 567
 568 =back
 569
 570 =head1 ACKNOWLEDGEMENTS
 571
 572 =over 4
 573
 574 =item I blame Sam Vilain for introducing me to the insanity that is meta-models.
 575
 576 =item I blame Audrey Tang for then encouraging my meta-model habit in #perl6.
 577
 578 =item Without Yuval "nothingmuch" Kogman this module would not be possible,
 579 and it certainly wouldn't have this name ;P
 580
 581 =item The basis of the TypeContraints module was Rob Kinyon's idea
 582 originally, I just ran with it.
 583
 584 =item Thanks to mst & chansen and the whole #moose poose for all the
 585 ideas/feature-requests/encouragement
 586
 587 =back
 588
 589 =head1 SEE ALSO
 590
 591 =over 4
 592
 593 =item L<Class::MOP> documentation
 594
 595 =item The #moose channel on irc.perl.org
 596
 597 =item L<http://forum2.org/moose/>
 598
 599 =item L<http://www.cs.utah.edu/plt/publications/oopsla04-gff.pdf>
 600
 601 This paper (suggested by lbr on #moose) was what lead to the implementation
 602 of the C<super>/C<overrride> and C<inner>/C<augment> features. If you really
 603 want to understand this feature, I suggest you read this.
 604
 605 =back
 606
 607 =head1 BUGS
 608
 609 All complex software has bugs lurking in it, and this module is no
 610 exception. If you find a bug please either email me, or add the bug
 611 to cpan-RT.
 612
 613 =head1 AUTHOR
 614
 615 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 616
 617 Christian Hansen E<lt>chansen@cpan.orgE<gt>
 618
 619 Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
 620
 621 =head1 COPYRIGHT AND LICENSE
 622
 623 Copyright 2006 by Infinity Interactive, Inc.
 624
 625 L<http://www.iinteractive.com>
 626
 627 This library is free software; you can redistribute it and/or modify
 628 it under the same terms as Perl itself.
 629
 630 =cut