lib/Class/C3.pm

   1
   2 package Class::C3;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.15_06';
   8
   9 our $C3_IN_CORE;
  10 our $C3_XS;
  11
  12 BEGIN {
  13     if($] > 5.009_004) {
  14         $C3_IN_CORE = 1;
  15     }
  16     else {
  17         eval "require Class::C3::XS";
  18         my $error = $@;
  19         if(!$error) {
  20             $C3_XS = 1;
  21         }
  22         else {
  23             die $error if $error !~ /\blocate\b/;
  24             require Algorithm::C3;
  25             require Class::C3::next;
  26         }
  27     }
  28 }
  29
  30 # this is our global stash of both
  31 # MRO's and method dispatch tables
  32 # the structure basically looks like
  33 # this:
  34 #
  35 #   $MRO{$class} = {
  36 #      MRO => [ <class precendence list> ],
  37 #      methods => {
  38 #          orig => <original location of method>,
  39 #          code => \&<ref to original method>
  40 #      },
  41 #      has_overload_fallback => (1 | 0)
  42 #   }
  43 #
  44 our %MRO;
  45
  46 # use these for debugging ...
  47 sub _dump_MRO_table { %MRO }
  48 our $TURN_OFF_C3 = 0;
  49
  50 # state tracking for initialize()/uninitialize()
  51 our $_initialized = 0;
  52
  53 sub import {
  54     my $class = caller();
  55     # skip if the caller is main::
  56     # since that is clearly not relevant
  57     return if $class eq 'main';
  58
  59     return if $TURN_OFF_C3;
  60     mro::set_mro($class, 'c3') if $C3_IN_CORE;
  61
  62     # make a note to calculate $class
  63     # during INIT phase
  64     $MRO{$class} = undef unless exists $MRO{$class};
  65 }
  66
  67 ## initializers
  68
  69 sub initialize {
  70     %next::METHOD_CACHE = ();
  71     # why bother if we don't have anything ...
  72     return unless keys %MRO;
  73     if($C3_IN_CORE) {
  74         mro::set_mro($_, 'c3') for keys %MRO;
  75     }
  76     else {
  77         if($_initialized) {
  78             uninitialize();
  79             $MRO{$_} = undef foreach keys %MRO;
  80         }
  81         _calculate_method_dispatch_tables();
  82         _apply_method_dispatch_tables();
  83         $_initialized = 1;
  84     }
  85 }
  86
  87 sub uninitialize {
  88     # why bother if we don't have anything ...
  89     %next::METHOD_CACHE = ();
  90     return unless keys %MRO;
  91     if($C3_IN_CORE) {
  92         mro::set_mro($_, 'dfs') for keys %MRO;
  93     }
  94     else {
  95         _remove_method_dispatch_tables();
  96         $_initialized = 0;
  97     }
  98 }
  99
 100 sub reinitialize { goto &initialize }
 101
 102 ## functions for applying C3 to classes
 103
 104 sub _calculate_method_dispatch_tables {
 105     return if $C3_IN_CORE;
 106     my %merge_cache;
 107     foreach my $class (keys %MRO) {
 108         _calculate_method_dispatch_table($class, \%merge_cache);
 109     }
 110 }
 111
 112 sub _calculate_method_dispatch_table {
 113     return if $C3_IN_CORE;
 114     my ($class, $merge_cache) = @_;
 115     no strict 'refs';
 116     my @MRO = calculateMRO($class, $merge_cache);
 117     $MRO{$class} = { MRO => \@MRO };
 118     my $has_overload_fallback;
 119     my %methods;
 120     # NOTE:
 121     # we do @MRO[1 .. $#MRO] here because it
 122     # makes no sense to interogate the class
 123     # which you are calculating for.
 124     foreach my $local (@MRO[1 .. $#MRO]) {
 125         # if overload has tagged this module to
 126         # have use "fallback", then we want to
 127         # grab that value
 128         $has_overload_fallback = ${"${local}::()"}
 129             if !defined $has_overload_fallback && defined ${"${local}::()"};
 130         foreach my $method (grep { defined &{"${local}::$_"} } keys %{"${local}::"}) {
 131             # skip if already overriden in local class
 132             next unless !defined *{"${class}::$method"}{CODE};
 133             $methods{$method} = {
 134                 orig => "${local}::$method",
 135                 code => \&{"${local}::$method"}
 136             } unless exists $methods{$method};
 137         }
 138     }
 139     # now stash them in our %MRO table
 140     $MRO{$class}->{methods} = \%methods;
 141     $MRO{$class}->{has_overload_fallback} = $has_overload_fallback;
 142 }
 143
 144 sub _apply_method_dispatch_tables {
 145     return if $C3_IN_CORE;
 146     foreach my $class (keys %MRO) {
 147         _apply_method_dispatch_table($class);
 148     }
 149 }
 150
 151 sub _apply_method_dispatch_table {
 152     return if $C3_IN_CORE;
 153     my $class = shift;
 154     no strict 'refs';
 155     ${"${class}::()"} = $MRO{$class}->{has_overload_fallback}
 156         if !defined &{"${class}::()"}
 157            && defined $MRO{$class}->{has_overload_fallback};
 158     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 159         if ( $method =~ /^\(/ ) {
 160             my $orig = $MRO{$class}->{methods}->{$method}->{orig};
 161             ${"${class}::$method"} = $$orig if defined $$orig;
 162         }
 163         *{"${class}::$method"} = $MRO{$class}->{methods}->{$method}->{code};
 164     }
 165 }
 166
 167 sub _remove_method_dispatch_tables {
 168     return if $C3_IN_CORE;
 169     foreach my $class (keys %MRO) {
 170         _remove_method_dispatch_table($class);
 171     }
 172 }
 173
 174 sub _remove_method_dispatch_table {
 175     return if $C3_IN_CORE;
 176     my $class = shift;
 177     no strict 'refs';
 178     delete ${"${class}::"}{"()"} if $MRO{$class}->{has_overload_fallback};
 179     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 180         delete ${"${class}::"}{$method}
 181             if defined *{"${class}::${method}"}{CODE} &&
 182                (*{"${class}::${method}"}{CODE} eq $MRO{$class}->{methods}->{$method}->{code});
 183     }
 184 }
 185
 186 sub calculateMRO {
 187     my ($class, $merge_cache) = @_;
 188
 189     return Algorithm::C3::merge($class, sub {
 190         no strict 'refs';
 191         @{$_[0] . '::ISA'};
 192     }, $merge_cache);
 193 }
 194
 195 # Method overrides to support 5.9.5+ or Class::C3::XS
 196
 197 sub _core_calculateMRO { @{mro::get_linear_isa($_[0])} }
 198
 199 if($C3_IN_CORE) {
 200     no warnings 'redefine';
 201     *Class::C3::calculateMRO = \&_core_calculateMRO;
 202 }
 203 elsif($C3_XS) {
 204     no warnings 'redefine';
 205     *Class::C3::calculateMRO = \&Class::C3::XS::calculateMRO;
 206     *Class::C3::_calculate_method_dispatch_table
 207         = \&Class::C3::XS::_calculate_method_dispatch_table;
 208 }
 209
 210 1;
 211
 212 __END__
 213
 214 =pod
 215
 216 =head1 NAME
 217
 218 Class::C3 - A pragma to use the C3 method resolution order algortihm
 219
 220 =head1 SYNOPSIS
 221
 222     package A;
 223     use Class::C3;
 224     sub hello { 'A::hello' }
 225
 226     package B;
 227     use base 'A';
 228     use Class::C3;
 229
 230     package C;
 231     use base 'A';
 232     use Class::C3;
 233
 234     sub hello { 'C::hello' }
 235
 236     package D;
 237     use base ('B', 'C');
 238     use Class::C3;
 239
 240     # Classic Diamond MI pattern
 241     #    <A>
 242     #   /   \
 243     # <B>   <C>
 244     #   \   /
 245     #    <D>
 246
 247     package main;
 248
 249     # initializez the C3 module
 250     # (formerly called in INIT)
 251     Class::C3::initialize();
 252
 253     print join ', ' => Class::C3::calculateMRO('Diamond_D') # prints D, B, C, A
 254
 255     print D->hello() # prints 'C::hello' instead of the standard p5 'A::hello'
 256
 257     D->can('hello')->();          # can() also works correctly
 258     UNIVERSAL::can('D', 'hello'); # as does UNIVERSAL::can()
 259
 260 =head1 SPECIAL NOTE FOR 0.15_06
 261
 262 To try this with the new perl core c3 support,
 263 download the most recent copy perl-current:
 264
 265 http://mirrors.develooper.com/perl/APC/perl-current-snap/
 266
 267 sh Configure -Dusedevel -Dprefix=/where/I/want/it -d -e && make && make test && make install
 268
 269 then try your C3-using software against this perl + Class::C3 0.15_06.
 270
 271 =head1 DESCRIPTION
 272
 273 This is pragma to change Perl 5's standard method resolution order from depth-first left-to-right
 274 (a.k.a - pre-order) to the more sophisticated C3 method resolution order.
 275
 276 =head2 What is C3?
 277
 278 C3 is the name of an algorithm which aims to provide a sane method resolution order under multiple
 279 inheritence. It was first introduced in the langauge Dylan (see links in the L<SEE ALSO> section),
 280 and then later adopted as the prefered MRO (Method Resolution Order) for the new-style classes in
 281 Python 2.3. Most recently it has been adopted as the 'canonical' MRO for Perl 6 classes, and the
 282 default MRO for Parrot objects as well.
 283
 284 =head2 How does C3 work.
 285
 286 C3 works by always preserving local precendence ordering. This essentially means that no class will
 287 appear before any of it's subclasses. Take the classic diamond inheritence pattern for instance:
 288
 289      <A>
 290     /   \
 291   <B>   <C>
 292     \   /
 293      <D>
 294
 295 The standard Perl 5 MRO would be (D, B, A, C). The result being that B<A> appears before B<C>, even
 296 though B<C> is the subclass of B<A>. The C3 MRO algorithm however, produces the following MRO
 297 (D, B, C, A), which does not have this same issue.
 298
 299 This example is fairly trival, for more complex examples and a deeper explaination, see the links in
 300 the L<SEE ALSO> section.
 301
 302 =head2 How does this module work?
 303
 304 This module uses a technique similar to Perl 5's method caching. When C<Class::C3::initialize> is
 305 called, this module calculates the MRO of all the classes which called C<use Class::C3>. It then
 306 gathers information from the symbol tables of each of those classes, and builds a set of method
 307 aliases for the correct dispatch ordering. Once all these C3-based method tables are created, it
 308 then adds the method aliases into the local classes symbol table.
 309
 310 The end result is actually classes with pre-cached method dispatch. However, this caching does not
 311 do well if you start changing your C<@ISA> or messing with class symbol tables, so you should consider
 312 your classes to be effectively closed. See the L<CAVEATS> section for more details.
 313
 314 =head1 OPTIONAL LOWERCASE PRAGMA
 315
 316 This release also includes an optional module B<c3> in the F<opt/> folder. I did not include this in
 317 the regular install since lowercase module names are considered I<"bad"> by some people. However I
 318 think that code looks much nicer like this:
 319
 320   package MyClass;
 321   use c3;
 322
 323 The the more clunky:
 324
 325   package MyClass;
 326   use Class::C3;
 327
 328 But hey, it's your choice, thats why it is optional.
 329
 330 =head1 FUNCTIONS
 331
 332 =over 4
 333
 334 =item B<calculateMRO ($class)>
 335
 336 Given a C<$class> this will return an array of class names in the proper C3 method resolution order.
 337
 338 =item B<initialize>
 339
 340 This B<must be called> to initalize the C3 method dispatch tables, this module B<will not work> if
 341 you do not do this. It is advised to do this as soon as possible B<after> loading any classes which
 342 use C3. Here is a quick code example:
 343
 344   package Foo;
 345   use Class::C3;
 346   # ... Foo methods here
 347
 348   package Bar;
 349   use Class::C3;
 350   use base 'Foo';
 351   # ... Bar methods here
 352
 353   package main;
 354
 355   Class::C3::initialize(); # now it is safe to use Foo and Bar
 356
 357 This function used to be called automatically for you in the INIT phase of the perl compiler, but
 358 that lead to warnings if this module was required at runtime. After discussion with my user base
 359 (the L<DBIx::Class> folks), we decided that calling this in INIT was more of an annoyance than a
 360 convience. I apologize to anyone this causes problems for (although i would very suprised if I had
 361 any other users other than the L<DBIx::Class> folks). The simplest solution of course is to define
 362 your own INIT method which calls this function.
 363
 364 NOTE:
 365
 366 If C<initialize> detects that C<initialize> has already been executed, it will L</uninitialize> and
 367 clear the MRO cache first.
 368
 369 =item B<uninitialize>
 370
 371 Calling this function results in the removal of all cached methods, and the restoration of the old Perl 5
 372 style dispatch order (depth-first, left-to-right).
 373
 374 =item B<reinitialize>
 375
 376 This is an alias for L</initialize> above.
 377
 378 =back
 379
 380 =head1 METHOD REDISPATCHING
 381
 382 It is always useful to be able to re-dispatch your method call to the "next most applicable method". This
 383 module provides a pseudo package along the lines of C<SUPER::> or C<NEXT::> which will re-dispatch the
 384 method along the C3 linearization. This is best show with an examples.
 385
 386   # a classic diamond MI pattern ...
 387      <A>
 388     /   \
 389   <B>   <C>
 390     \   /
 391      <D>
 392
 393   package A;
 394   use c3;
 395   sub foo { 'A::foo' }
 396
 397   package B;
 398   use base 'A';
 399   use c3;
 400   sub foo { 'B::foo => ' . (shift)->next::method() }
 401
 402   package B;
 403   use base 'A';
 404   use c3;
 405   sub foo { 'C::foo => ' . (shift)->next::method() }
 406
 407   package D;
 408   use base ('B', 'C');
 409   use c3;
 410   sub foo { 'D::foo => ' . (shift)->next::method() }
 411
 412   print D->foo; # prints out "D::foo => B::foo => C::foo => A::foo"
 413
 414 A few things to note. First, we do not require you to add on the method name to the C<next::method>
 415 call (this is unlike C<NEXT::> and C<SUPER::> which do require that). This helps to enforce the rule
 416 that you cannot dispatch to a method of a different name (this is how C<NEXT::> behaves as well).
 417
 418 The next thing to keep in mind is that you will need to pass all arguments to C<next::method> it can
 419 not automatically use the current C<@_>.
 420
 421 If C<next::method> cannot find a next method to re-dispatch the call to, it will throw an exception.
 422 You can use C<next::can> to see if C<next::method> will succeed before you call it like so:
 423
 424   $self->next::method(@_) if $self->next::can;
 425
 426 Additionally, you can use C<maybe::next::method> as a shortcut to only call the next method if it exists.
 427 The previous example could be simply written as:
 428
 429   $self->maybe::next::method(@_);
 430
 431 There are some caveats about using C<next::method>, see below for those.
 432
 433 =head1 CAVEATS
 434
 435 This module used to be labeled as I<experimental>, however it has now been pretty heavily tested by
 436 the good folks over at L<DBIx::Class> and I am confident this module is perfectly usable for
 437 whatever your needs might be.
 438
 439 But there are still caveats, so here goes ...
 440
 441 =over 4
 442
 443 =item Use of C<SUPER::>.
 444
 445 The idea of C<SUPER::> under multiple inheritence is ambigious, and generally not recomended anyway.
 446 However, it's use in conjuntion with this module is very much not recommended, and in fact very
 447 discouraged. The recommended approach is to instead use the supplied C<next::method> feature, see
 448 more details on it's usage above.
 449
 450 =item Changing C<@ISA>.
 451
 452 It is the author's opinion that changing C<@ISA> at runtime is pure insanity anyway. However, people
 453 do it, so I must caveat. Any changes to the C<@ISA> will not be reflected in the MRO calculated by this
 454 module, and therefor probably won't even show up. If you do this, you will need to call C<reinitialize>
 455 in order to recalulate B<all> method dispatch tables. See the C<reinitialize> documentation and an example
 456 in F<t/20_reinitialize.t> for more information.
 457
 458 =item Adding/deleting methods from class symbol tables.
 459
 460 This module calculates the MRO for each requested class by interogatting the symbol tables of said classes.
 461 So any symbol table manipulation which takes place after our INIT phase is run will not be reflected in
 462 the calculated MRO. Just as with changing the C<@ISA>, you will need to call C<reinitialize> for any
 463 changes you make to take effect.
 464
 465 =item Calling C<next::method> from methods defined outside the class
 466
 467 There is an edge case when using C<next::method> from within a subroutine which was created in a different
 468 module than the one it is called from. It sounds complicated, but it really isn't. Here is an example which
 469 will not work correctly:
 470
 471   *Foo::foo = sub { (shift)->next::method(@_) };
 472
 473 The problem exists because the anonymous subroutine being assigned to the glob C<*Foo::foo> will show up
 474 in the call stack as being called C<__ANON__> and not C<foo> as you might expect. Since C<next::method>
 475 uses C<caller> to find the name of the method it was called in, it will fail in this case.
 476
 477 But fear not, there is a simple solution. The module C<Sub::Name> will reach into the perl internals and
 478 assign a name to an anonymous subroutine for you. Simply do this:
 479
 480   use Sub::Name 'subname';
 481   *Foo::foo = subname 'Foo::foo' => sub { (shift)->next::method(@_) };
 482
 483 and things will Just Work. Of course this is not always possible to do, but to be honest, I just can't
 484 manage to find a workaround for it, so until someone gives me a working patch this will be a known
 485 limitation of this module.
 486
 487 =back
 488
 489 =head1 COMPATIBILITY
 490
 491 If your software requires Perl 5.9.5 or higher, you do not need L<Class::C3>, you can simply C<use mro 'c3'>, and not worry about C<initialize()>, avoid some of the above caveats, and get the best possible performance.  See L<mro> for more details.
 492
 493 If your software is meant to work on earlier Perls, use L<Class::C3> as documented here.  L<Class::C3> will detect Perl 5.9.5+ and take advantage of the core support when available.
 494
 495 =head1 Class::C3::XS
 496
 497 This module will load L<Class::C3::XS> if it's installed and you are running on a Perl version older than 5.9.5.  Installing this is recommended when possible, as it results in significant performance improvements (but unlike the 5.9.5+ core support, it still has all of the same caveats as L<Class::C3>).
 498
 499 =head1 CODE COVERAGE
 500
 501 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
 502 module's test suite.
 503
 504  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 505  File                           stmt   bran   cond    sub    pod   time  total
 506  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 507  Class/C3.pm                    98.3   84.4   80.0   96.2  100.0   98.4   94.4
 508  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 509  Total                          98.3   84.4   80.0   96.2  100.0   98.4   94.4
 510  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 511
 512 =head1 SEE ALSO
 513
 514 =head2 The original Dylan paper
 515
 516 =over 4
 517
 518 =item L<http://www.webcom.com/haahr/dylan/linearization-oopsla96.html>
 519
 520 =back
 521
 522 =head2 The prototype Perl 6 Object Model uses C3
 523
 524 =over 4
 525
 526 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel/>
 527
 528 =back
 529
 530 =head2 Parrot now uses C3
 531
 532 =over 4
 533
 534 =item L<http://aspn.activestate.com/ASPN/Mail/Message/perl6-internals/2746631>
 535
 536 =item L<http://use.perl.org/~autrijus/journal/25768>
 537
 538 =back
 539
 540 =head2 Python 2.3 MRO related links
 541
 542 =over 4
 543
 544 =item L<http://www.python.org/2.3/mro.html>
 545
 546 =item L<http://www.python.org/2.2.2/descrintro.html#mro>
 547
 548 =back
 549
 550 =head2 C3 for TinyCLOS
 551
 552 =over 4
 553
 554 =item L<http://www.call-with-current-continuation.org/eggs/c3.html>
 555
 556 =back
 557
 558 =head1 ACKNOWLEGEMENTS
 559
 560 =over 4
 561
 562 =item Thanks to Matt S. Trout for using this module in his module L<DBIx::Class>
 563 and finding many bugs and providing fixes.
 564
 565 =item Thanks to Justin Guenther for making C<next::method> more robust by handling
 566 calls inside C<eval> and anon-subs.
 567
 568 =item Thanks to Robert Norris for adding support for C<next::can> and
 569 C<maybe::next::method>.
 570
 571 =back
 572
 573 =head1 AUTHOR
 574
 575 Stevan Little, E<lt>stevan@iinteractive.comE<gt>
 576
 577 Brandon L. Black, E<lt>blblack@gmail.comE<gt>
 578
 579 =head1 COPYRIGHT AND LICENSE
 580
 581 Copyright 2005, 2006 by Infinity Interactive, Inc.
 582
 583 L<http://www.iinteractive.com>
 584
 585 This library is free software; you can redistribute it and/or modify
 586 it under the same terms as Perl itself.
 587
 588 =cut