lib/Class/C3.pm

   1
   2 package Class::C3;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.15_01';
   8
   9 our $C3_IN_CORE;
  10
  11 BEGIN {
  12     eval "require mro"; # XXX in the future, this should be a version check
  13     if($@) {
  14         die $@ if $@ !~ /locate/;
  15 #        eval "require Class::C3::XS";
  16 #        if($@) {
  17 #            die $@ if $@ !~ /locate/;
  18             eval "require Algorithm::C3; require Class::C3::next";
  19             die $@ if $@;
  20 #        }
  21     }
  22     else {
  23         $C3_IN_CORE = 1;
  24     }
  25 }
  26
  27 # this is our global stash of both
  28 # MRO's and method dispatch tables
  29 # the structure basically looks like
  30 # this:
  31 #
  32 #   $MRO{$class} = {
  33 #      MRO => [ <class precendence list> ],
  34 #      methods => {
  35 #          orig => <original location of method>,
  36 #          code => \&<ref to original method>
  37 #      },
  38 #      has_overload_fallback => (1 | 0)
  39 #   }
  40 #
  41 our %MRO;
  42
  43 # use these for debugging ...
  44 sub _dump_MRO_table { %MRO }
  45 our $TURN_OFF_C3 = 0;
  46
  47 # state tracking for initialize()/uninitialize()
  48 our $_initialized = 0;
  49
  50 sub import {
  51     my $class = caller();
  52     # skip if the caller is main::
  53     # since that is clearly not relevant
  54     return if $class eq 'main';
  55
  56     return if $TURN_OFF_C3;
  57     mro::set_mro($class, 'c3') if $C3_IN_CORE;
  58
  59     # make a note to calculate $class
  60     # during INIT phase
  61     $MRO{$class} = undef unless exists $MRO{$class};
  62 }
  63
  64 ## initializers
  65
  66 sub initialize {
  67     %next::METHOD_CACHE = ();
  68     # why bother if we don't have anything ...
  69     return unless keys %MRO;
  70     if($C3_IN_CORE) {
  71         mro::set_mro($_, 'c3') for keys %MRO;
  72     }
  73     else {
  74         if($_initialized) {
  75             uninitialize();
  76             $MRO{$_} = undef foreach keys %MRO;
  77         }
  78         _calculate_method_dispatch_tables();
  79         _apply_method_dispatch_tables();
  80         $_initialized = 1;
  81     }
  82 }
  83
  84 sub uninitialize {
  85     # why bother if we don't have anything ...
  86     %next::METHOD_CACHE = ();
  87     return unless keys %MRO;
  88     if($C3_IN_CORE) {
  89         mro::set_mro($_, 'dfs') for keys %MRO;
  90     }
  91     else {
  92         _remove_method_dispatch_tables();
  93         $_initialized = 0;
  94     }
  95 }
  96
  97 sub reinitialize { goto &initialize }
  98
  99 ## functions for applying C3 to classes
 100
 101 sub _calculate_method_dispatch_tables {
 102     return if $C3_IN_CORE;
 103     my %merge_cache;
 104     foreach my $class (keys %MRO) {
 105         _calculate_method_dispatch_table($class, \%merge_cache);
 106     }
 107 }
 108
 109 sub _calculate_method_dispatch_table {
 110     return if $C3_IN_CORE;
 111     my ($class, $merge_cache) = @_;
 112     no strict 'refs';
 113     my @MRO = calculateMRO($class, $merge_cache);
 114     $MRO{$class} = { MRO => \@MRO };
 115     my $has_overload_fallback = 0;
 116     my %methods;
 117     # NOTE:
 118     # we do @MRO[1 .. $#MRO] here because it
 119     # makes no sense to interogate the class
 120     # which you are calculating for.
 121     foreach my $local (@MRO[1 .. $#MRO]) {
 122         # if overload has tagged this module to
 123         # have use "fallback", then we want to
 124         # grab that value
 125         $has_overload_fallback = ${"${local}::()"}
 126             if defined ${"${local}::()"};
 127         foreach my $method (grep { defined &{"${local}::$_"} } keys %{"${local}::"}) {
 128             # skip if already overriden in local class
 129             next unless !defined *{"${class}::$method"}{CODE};
 130             $methods{$method} = {
 131                 orig => "${local}::$method",
 132                 code => \&{"${local}::$method"}
 133             } unless exists $methods{$method};
 134         }
 135     }
 136     # now stash them in our %MRO table
 137     $MRO{$class}->{methods} = \%methods;
 138     $MRO{$class}->{has_overload_fallback} = $has_overload_fallback;
 139 }
 140
 141 sub _apply_method_dispatch_tables {
 142     return if $C3_IN_CORE;
 143     foreach my $class (keys %MRO) {
 144         _apply_method_dispatch_table($class);
 145     }
 146 }
 147
 148 sub _apply_method_dispatch_table {
 149     return if $C3_IN_CORE;
 150     my $class = shift;
 151     no strict 'refs';
 152     ${"${class}::()"} = $MRO{$class}->{has_overload_fallback}
 153         if $MRO{$class}->{has_overload_fallback};
 154     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 155         if ( $method =~ /^\(/ ) {
 156             my $orig = $MRO{$class}->{methods}->{$method}->{orig};
 157             ${"${class}::$method"} = $$orig if defined $$orig;
 158         }
 159         *{"${class}::$method"} = $MRO{$class}->{methods}->{$method}->{code};
 160     }
 161 }
 162
 163 sub _remove_method_dispatch_tables {
 164     return if $C3_IN_CORE;
 165     foreach my $class (keys %MRO) {
 166         _remove_method_dispatch_table($class);
 167     }
 168 }
 169
 170 sub _remove_method_dispatch_table {
 171     return if $C3_IN_CORE;
 172     my $class = shift;
 173     no strict 'refs';
 174     delete ${"${class}::"}{"()"} if $MRO{$class}->{has_overload_fallback};
 175     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 176         delete ${"${class}::"}{$method}
 177             if defined *{"${class}::${method}"}{CODE} &&
 178                (*{"${class}::${method}"}{CODE} eq $MRO{$class}->{methods}->{$method}->{code});
 179     }
 180 }
 181
 182 sub calculateMRO {
 183     my ($class, $merge_cache) = @_;
 184
 185     return @{mro::get_linear_isa($class)} if $C3_IN_CORE;
 186
 187     return Algorithm::C3::merge($class, sub {
 188         no strict 'refs';
 189         @{$_[0] . '::ISA'};
 190     }, $merge_cache);
 191 }
 192
 193 1;
 194
 195 __END__
 196
 197 =pod
 198
 199 =head1 NAME
 200
 201 Class::C3 - A pragma to use the C3 method resolution order algortihm
 202
 203 =head1 SYNOPSIS
 204
 205     package A;
 206     use Class::C3;
 207     sub hello { 'A::hello' }
 208
 209     package B;
 210     use base 'A';
 211     use Class::C3;
 212
 213     package C;
 214     use base 'A';
 215     use Class::C3;
 216
 217     sub hello { 'C::hello' }
 218
 219     package D;
 220     use base ('B', 'C');
 221     use Class::C3;
 222
 223     # Classic Diamond MI pattern
 224     #    <A>
 225     #   /   \
 226     # <B>   <C>
 227     #   \   /
 228     #    <D>
 229
 230     package main;
 231
 232     # initializez the C3 module
 233     # (formerly called in INIT)
 234     Class::C3::initialize();
 235
 236     print join ', ' => Class::C3::calculateMRO('Diamond_D') # prints D, B, C, A
 237
 238     print D->hello() # prints 'C::hello' instead of the standard p5 'A::hello'
 239
 240     D->can('hello')->();          # can() also works correctly
 241     UNIVERSAL::can('D', 'hello'); # as does UNIVERSAL::can()
 242
 243 =head1 SPECIAL NOTE FOR 0.15_01
 244
 245 To try this with the experimental perl core c3 patch,
 246 download a recent copy perl-current:
 247
 248 http://mirrors.develooper.com/perl/APC/perl-current-snap/perl-current@30943.tar.bz2
 249
 250 apply the enclosed c3.patch, and install this perl:
 251
 252 sh Configure -Dusedevel -Dprefix=/where/I/want/it -d -e && make && make test && make install
 253
 254 then try your C3-using software against this perl + Class::C3 0.15_01.
 255
 256 =head1 DESCRIPTION
 257
 258 This is pragma to change Perl 5's standard method resolution order from depth-first left-to-right
 259 (a.k.a - pre-order) to the more sophisticated C3 method resolution order.
 260
 261 =head2 What is C3?
 262
 263 C3 is the name of an algorithm which aims to provide a sane method resolution order under multiple
 264 inheritence. It was first introduced in the langauge Dylan (see links in the L<SEE ALSO> section),
 265 and then later adopted as the prefered MRO (Method Resolution Order) for the new-style classes in
 266 Python 2.3. Most recently it has been adopted as the 'canonical' MRO for Perl 6 classes, and the
 267 default MRO for Parrot objects as well.
 268
 269 =head2 How does C3 work.
 270
 271 C3 works by always preserving local precendence ordering. This essentially means that no class will
 272 appear before any of it's subclasses. Take the classic diamond inheritence pattern for instance:
 273
 274      <A>
 275     /   \
 276   <B>   <C>
 277     \   /
 278      <D>
 279
 280 The standard Perl 5 MRO would be (D, B, A, C). The result being that B<A> appears before B<C>, even
 281 though B<C> is the subclass of B<A>. The C3 MRO algorithm however, produces the following MRO
 282 (D, B, C, A), which does not have this same issue.
 283
 284 This example is fairly trival, for more complex examples and a deeper explaination, see the links in
 285 the L<SEE ALSO> section.
 286
 287 =head2 How does this module work?
 288
 289 This module uses a technique similar to Perl 5's method caching. When C<Class::C3::initialize> is
 290 called, this module calculates the MRO of all the classes which called C<use Class::C3>. It then
 291 gathers information from the symbol tables of each of those classes, and builds a set of method
 292 aliases for the correct dispatch ordering. Once all these C3-based method tables are created, it
 293 then adds the method aliases into the local classes symbol table.
 294
 295 The end result is actually classes with pre-cached method dispatch. However, this caching does not
 296 do well if you start changing your C<@ISA> or messing with class symbol tables, so you should consider
 297 your classes to be effectively closed. See the L<CAVEATS> section for more details.
 298
 299 =head1 OPTIONAL LOWERCASE PRAGMA
 300
 301 This release also includes an optional module B<c3> in the F<opt/> folder. I did not include this in
 302 the regular install since lowercase module names are considered I<"bad"> by some people. However I
 303 think that code looks much nicer like this:
 304
 305   package MyClass;
 306   use c3;
 307
 308 The the more clunky:
 309
 310   package MyClass;
 311   use Class::C3;
 312
 313 But hey, it's your choice, thats why it is optional.
 314
 315 =head1 FUNCTIONS
 316
 317 =over 4
 318
 319 =item B<calculateMRO ($class)>
 320
 321 Given a C<$class> this will return an array of class names in the proper C3 method resolution order.
 322
 323 =item B<initialize>
 324
 325 This B<must be called> to initalize the C3 method dispatch tables, this module B<will not work> if
 326 you do not do this. It is advised to do this as soon as possible B<after> loading any classes which
 327 use C3. Here is a quick code example:
 328
 329   package Foo;
 330   use Class::C3;
 331   # ... Foo methods here
 332
 333   package Bar;
 334   use Class::C3;
 335   use base 'Foo';
 336   # ... Bar methods here
 337
 338   package main;
 339
 340   Class::C3::initialize(); # now it is safe to use Foo and Bar
 341
 342 This function used to be called automatically for you in the INIT phase of the perl compiler, but
 343 that lead to warnings if this module was required at runtime. After discussion with my user base
 344 (the L<DBIx::Class> folks), we decided that calling this in INIT was more of an annoyance than a
 345 convience. I apologize to anyone this causes problems for (although i would very suprised if I had
 346 any other users other than the L<DBIx::Class> folks). The simplest solution of course is to define
 347 your own INIT method which calls this function.
 348
 349 NOTE:
 350
 351 If C<initialize> detects that C<initialize> has already been executed, it will L</uninitialize> and
 352 clear the MRO cache first.
 353
 354 =item B<uninitialize>
 355
 356 Calling this function results in the removal of all cached methods, and the restoration of the old Perl 5
 357 style dispatch order (depth-first, left-to-right).
 358
 359 =item B<reinitialize>
 360
 361 This is an alias for L</initialize> above.
 362
 363 =back
 364
 365 =head1 METHOD REDISPATCHING
 366
 367 It is always useful to be able to re-dispatch your method call to the "next most applicable method". This
 368 module provides a pseudo package along the lines of C<SUPER::> or C<NEXT::> which will re-dispatch the
 369 method along the C3 linearization. This is best show with an examples.
 370
 371   # a classic diamond MI pattern ...
 372      <A>
 373     /   \
 374   <B>   <C>
 375     \   /
 376      <D>
 377
 378   package A;
 379   use c3;
 380   sub foo { 'A::foo' }
 381
 382   package B;
 383   use base 'A';
 384   use c3;
 385   sub foo { 'B::foo => ' . (shift)->next::method() }
 386
 387   package B;
 388   use base 'A';
 389   use c3;
 390   sub foo { 'C::foo => ' . (shift)->next::method() }
 391
 392   package D;
 393   use base ('B', 'C');
 394   use c3;
 395   sub foo { 'D::foo => ' . (shift)->next::method() }
 396
 397   print D->foo; # prints out "D::foo => B::foo => C::foo => A::foo"
 398
 399 A few things to note. First, we do not require you to add on the method name to the C<next::method>
 400 call (this is unlike C<NEXT::> and C<SUPER::> which do require that). This helps to enforce the rule
 401 that you cannot dispatch to a method of a different name (this is how C<NEXT::> behaves as well).
 402
 403 The next thing to keep in mind is that you will need to pass all arguments to C<next::method> it can
 404 not automatically use the current C<@_>.
 405
 406 If C<next::method> cannot find a next method to re-dispatch the call to, it will throw an exception.
 407 You can use C<next::can> to see if C<next::method> will succeed before you call it like so:
 408
 409   $self->next::method(@_) if $self->next::can;
 410
 411 Additionally, you can use C<maybe::next::method> as a shortcut to only call the next method if it exists.
 412 The previous example could be simply written as:
 413
 414   $self->maybe::next::method(@_);
 415
 416 There are some caveats about using C<next::method>, see below for those.
 417
 418 =head1 CAVEATS
 419
 420 This module used to be labeled as I<experimental>, however it has now been pretty heavily tested by
 421 the good folks over at L<DBIx::Class> and I am confident this module is perfectly usable for
 422 whatever your needs might be.
 423
 424 But there are still caveats, so here goes ...
 425
 426 =over 4
 427
 428 =item Use of C<SUPER::>.
 429
 430 The idea of C<SUPER::> under multiple inheritence is ambigious, and generally not recomended anyway.
 431 However, it's use in conjuntion with this module is very much not recommended, and in fact very
 432 discouraged. The recommended approach is to instead use the supplied C<next::method> feature, see
 433 more details on it's usage above.
 434
 435 =item Changing C<@ISA>.
 436
 437 It is the author's opinion that changing C<@ISA> at runtime is pure insanity anyway. However, people
 438 do it, so I must caveat. Any changes to the C<@ISA> will not be reflected in the MRO calculated by this
 439 module, and therefor probably won't even show up. If you do this, you will need to call C<reinitialize>
 440 in order to recalulate B<all> method dispatch tables. See the C<reinitialize> documentation and an example
 441 in F<t/20_reinitialize.t> for more information.
 442
 443 =item Adding/deleting methods from class symbol tables.
 444
 445 This module calculates the MRO for each requested class by interogatting the symbol tables of said classes.
 446 So any symbol table manipulation which takes place after our INIT phase is run will not be reflected in
 447 the calculated MRO. Just as with changing the C<@ISA>, you will need to call C<reinitialize> for any
 448 changes you make to take effect.
 449
 450 =item Calling C<next::method> from methods defined outside the class
 451
 452 There is an edge case when using C<next::method> from within a subroutine which was created in a different
 453 module than the one it is called from. It sounds complicated, but it really isn't. Here is an example which
 454 will not work correctly:
 455
 456   *Foo::foo = sub { (shift)->next::method(@_) };
 457
 458 The problem exists because the anonymous subroutine being assigned to the glob C<*Foo::foo> will show up
 459 in the call stack as being called C<__ANON__> and not C<foo> as you might expect. Since C<next::method>
 460 uses C<caller> to find the name of the method it was called in, it will fail in this case.
 461
 462 But fear not, there is a simple solution. The module C<Sub::Name> will reach into the perl internals and
 463 assign a name to an anonymous subroutine for you. Simply do this:
 464
 465   use Sub::Name 'subname';
 466   *Foo::foo = subname 'Foo::foo' => sub { (shift)->next::method(@_) };
 467
 468 and things will Just Work. Of course this is not always possible to do, but to be honest, I just can't
 469 manage to find a workaround for it, so until someone gives me a working patch this will be a known
 470 limitation of this module.
 471
 472 =back
 473
 474 =head1 CODE COVERAGE
 475
 476 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
 477 module's test suite.
 478
 479  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 480  File                           stmt   bran   cond    sub    pod   time  total
 481  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 482  Class/C3.pm                    98.3   84.4   80.0   96.2  100.0   98.4   94.4
 483  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 484  Total                          98.3   84.4   80.0   96.2  100.0   98.4   94.4
 485  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 486
 487 =head1 SEE ALSO
 488
 489 =head2 The original Dylan paper
 490
 491 =over 4
 492
 493 =item L<http://www.webcom.com/haahr/dylan/linearization-oopsla96.html>
 494
 495 =back
 496
 497 =head2 The prototype Perl 6 Object Model uses C3
 498
 499 =over 4
 500
 501 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel/>
 502
 503 =back
 504
 505 =head2 Parrot now uses C3
 506
 507 =over 4
 508
 509 =item L<http://aspn.activestate.com/ASPN/Mail/Message/perl6-internals/2746631>
 510
 511 =item L<http://use.perl.org/~autrijus/journal/25768>
 512
 513 =back
 514
 515 =head2 Python 2.3 MRO related links
 516
 517 =over 4
 518
 519 =item L<http://www.python.org/2.3/mro.html>
 520
 521 =item L<http://www.python.org/2.2.2/descrintro.html#mro>
 522
 523 =back
 524
 525 =head2 C3 for TinyCLOS
 526
 527 =over 4
 528
 529 =item L<http://www.call-with-current-continuation.org/eggs/c3.html>
 530
 531 =back
 532
 533 =head1 ACKNOWLEGEMENTS
 534
 535 =over 4
 536
 537 =item Thanks to Matt S. Trout for using this module in his module L<DBIx::Class>
 538 and finding many bugs and providing fixes.
 539
 540 =item Thanks to Justin Guenther for making C<next::method> more robust by handling
 541 calls inside C<eval> and anon-subs.
 542
 543 =item Thanks to Robert Norris for adding support for C<next::can> and
 544 C<maybe::next::method>.
 545
 546 =back
 547
 548 =head1 AUTHOR
 549
 550 Stevan Little, E<lt>stevan@iinteractive.comE<gt>
 551
 552 Brandon L. Black, E<lt>blblack@gmail.comE<gt>
 553
 554 =head1 COPYRIGHT AND LICENSE
 555
 556 Copyright 2005, 2006 by Infinity Interactive, Inc.
 557
 558 L<http://www.iinteractive.com>
 559
 560 This library is free software; you can redistribute it and/or modify
 561 it under the same terms as Perl itself.
 562
 563 =cut