lib/Class/C3.pm

   1
   2 package Class::C3;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed';
   8 use Algorithm::C3;
   9
  10 our $VERSION = '0.11';
  11
  12 # this is our global stash of both
  13 # MRO's and method dispatch tables
  14 # the structure basically looks like
  15 # this:
  16 #
  17 #   $MRO{$class} = {
  18 #      MRO => [ <class precendence list> ],
  19 #      methods => {
  20 #          orig => <original location of method>,
  21 #          code => \&<ref to original method>
  22 #      },
  23 #      has_overload_fallback => (1 | 0)
  24 #   }
  25 #
  26 our %MRO;
  27
  28 # use these for debugging ...
  29 sub _dump_MRO_table { %MRO }
  30 our $TURN_OFF_C3 = 0;
  31
  32 sub import {
  33     my $class = caller();
  34     # skip if the caller is main::
  35     # since that is clearly not relevant
  36     return if $class eq 'main';
  37     return if $TURN_OFF_C3;
  38     # make a note to calculate $class
  39     # during INIT phase
  40     $MRO{$class} = undef unless exists $MRO{$class};
  41 }
  42
  43 ## initializers
  44
  45 sub initialize {
  46     # why bother if we don't have anything ...
  47     return unless keys %MRO;
  48     _calculate_method_dispatch_tables();
  49     _apply_method_dispatch_tables();
  50     %next::METHOD_CACHE = ();
  51 }
  52
  53 sub uninitialize {
  54     # why bother if we don't have anything ...
  55     return unless keys %MRO;
  56     _remove_method_dispatch_tables();
  57     %next::METHOD_CACHE = ();
  58 }
  59
  60 sub reinitialize {
  61     uninitialize();
  62     # clean up the %MRO before we re-initialize
  63     $MRO{$_} = undef foreach keys %MRO;
  64     initialize();
  65 }
  66
  67 ## functions for applying C3 to classes
  68
  69 sub _calculate_method_dispatch_tables {
  70     foreach my $class (keys %MRO) {
  71         _calculate_method_dispatch_table($class);
  72     }
  73 }
  74
  75 sub _calculate_method_dispatch_table {
  76     my $class = shift;
  77     no strict 'refs';
  78     my @MRO = calculateMRO($class);
  79     $MRO{$class} = { MRO => \@MRO };
  80     my $has_overload_fallback = 0;
  81     my %methods;
  82     # NOTE:
  83     # we do @MRO[1 .. $#MRO] here because it
  84     # makes no sense to interogate the class
  85     # which you are calculating for.
  86     foreach my $local (@MRO[1 .. $#MRO]) {
  87         # if overload has tagged this module to
  88         # have use "fallback", then we want to
  89         # grab that value
  90         $has_overload_fallback = ${"${local}::()"}
  91             if defined ${"${local}::()"};
  92         foreach my $method (grep { defined &{"${local}::$_"} } keys %{"${local}::"}) {
  93             # skip if already overriden in local class
  94             next unless !defined *{"${class}::$method"}{CODE};
  95             $methods{$method} = {
  96                 orig => "${local}::$method",
  97                 code => \&{"${local}::$method"}
  98             } unless exists $methods{$method};
  99         }
 100     }
 101     # now stash them in our %MRO table
 102     $MRO{$class}->{methods} = \%methods;
 103     $MRO{$class}->{has_overload_fallback} = $has_overload_fallback;
 104 }
 105
 106 sub _apply_method_dispatch_tables {
 107     foreach my $class (keys %MRO) {
 108         _apply_method_dispatch_table($class);
 109     }
 110 }
 111
 112 sub _apply_method_dispatch_table {
 113     my $class = shift;
 114     no strict 'refs';
 115     ${"${class}::()"} = $MRO{$class}->{has_overload_fallback}
 116         if $MRO{$class}->{has_overload_fallback};
 117     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 118         *{"${class}::$method"} = $MRO{$class}->{methods}->{$method}->{code};
 119     }
 120 }
 121
 122 sub _remove_method_dispatch_tables {
 123     foreach my $class (keys %MRO) {
 124         _remove_method_dispatch_table($class);
 125     }
 126 }
 127
 128 sub _remove_method_dispatch_table {
 129     my $class = shift;
 130     no strict 'refs';
 131     delete ${"${class}::"}{"()"} if $MRO{$class}->{has_overload_fallback};
 132     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 133         delete ${"${class}::"}{$method}
 134             if defined *{"${class}::${method}"}{CODE} &&
 135                (*{"${class}::${method}"}{CODE} eq $MRO{$class}->{methods}->{$method}->{code});
 136     }
 137 }
 138
 139 ## functions for calculating C3 MRO
 140
 141 sub calculateMRO {
 142     my ($class) = @_;
 143     return Algorithm::C3::merge($class, sub {
 144         no strict 'refs';
 145         @{$_[0] . '::ISA'};
 146     });
 147 }
 148
 149 package  # hide me from PAUSE
 150     next;
 151
 152 use strict;
 153 use warnings;
 154
 155 use Scalar::Util 'blessed';
 156
 157 our $VERSION = '0.05';
 158
 159 our %METHOD_CACHE;
 160
 161 sub method {
 162     my $level = 1;
 163     my ($method_caller, $label, @label);
 164     while ($method_caller = (caller($level++))[3]) {
 165       @label = (split '::', $method_caller);
 166       $label = pop @label;
 167       last unless
 168         $label eq '(eval)' ||
 169         $label eq '__ANON__';
 170     }
 171     my $caller   = join '::' => @label;
 172     my $self     = $_[0];
 173     my $class    = blessed($self) || $self;
 174
 175     goto &{ $METHOD_CACHE{"$class|$caller|$label"} ||= do {
 176
 177       my @MRO = Class::C3::calculateMRO($class);
 178
 179       my $current;
 180       while ($current = shift @MRO) {
 181           last if $caller eq $current;
 182       }
 183
 184       no strict 'refs';
 185       my $found;
 186       foreach my $class (@MRO) {
 187           next if (defined $Class::C3::MRO{$class} &&
 188                    defined $Class::C3::MRO{$class}{methods}{$label});
 189           last if (defined ($found = *{$class . '::' . $label}{CODE}));
 190       }
 191
 192       die "No next::method '$label' found for $self" unless $found;
 193
 194       $found;
 195     } };
 196 }
 197
 198 1;
 199
 200 __END__
 201
 202 =pod
 203
 204 =head1 NAME
 205
 206 Class::C3 - A pragma to use the C3 method resolution order algortihm
 207
 208 =head1 SYNOPSIS
 209
 210     package A;
 211     use Class::C3;
 212     sub hello { 'A::hello' }
 213
 214     package B;
 215     use base 'A';
 216     use Class::C3;
 217
 218     package C;
 219     use base 'A';
 220     use Class::C3;
 221
 222     sub hello { 'C::hello' }
 223
 224     package D;
 225     use base ('B', 'C');
 226     use Class::C3;
 227
 228     # Classic Diamond MI pattern
 229     #    <A>
 230     #   /   \
 231     # <B>   <C>
 232     #   \   /
 233     #    <D>
 234
 235     package main;
 236
 237     # initializez the C3 module
 238     # (formerly called in INIT)
 239     Class::C3::initialize();
 240
 241     print join ', ' => Class::C3::calculateMRO('Diamond_D') # prints D, B, C, A
 242
 243     print D->hello() # prints 'C::hello' instead of the standard p5 'A::hello'
 244
 245     D->can('hello')->();          # can() also works correctly
 246     UNIVERSAL::can('D', 'hello'); # as does UNIVERSAL::can()
 247
 248 =head1 DESCRIPTION
 249
 250 This is pragma to change Perl 5's standard method resolution order from depth-first left-to-right
 251 (a.k.a - pre-order) to the more sophisticated C3 method resolution order.
 252
 253 =head2 What is C3?
 254
 255 C3 is the name of an algorithm which aims to provide a sane method resolution order under multiple
 256 inheritence. It was first introduced in the langauge Dylan (see links in the L<SEE ALSO> section),
 257 and then later adopted as the prefered MRO (Method Resolution Order) for the new-style classes in
 258 Python 2.3. Most recently it has been adopted as the 'canonical' MRO for Perl 6 classes, and the
 259 default MRO for Parrot objects as well.
 260
 261 =head2 How does C3 work.
 262
 263 C3 works by always preserving local precendence ordering. This essentially means that no class will
 264 appear before any of it's subclasses. Take the classic diamond inheritence pattern for instance:
 265
 266      <A>
 267     /   \
 268   <B>   <C>
 269     \   /
 270      <D>
 271
 272 The standard Perl 5 MRO would be (D, B, A, C). The result being that B<A> appears before B<C>, even
 273 though B<C> is the subclass of B<A>. The C3 MRO algorithm however, produces the following MRO
 274 (D, B, C, A), which does not have this same issue.
 275
 276 This example is fairly trival, for more complex examples and a deeper explaination, see the links in
 277 the L<SEE ALSO> section.
 278
 279 =head2 How does this module work?
 280
 281 This module uses a technique similar to Perl 5's method caching. When C<Class::C3::initialize> is
 282 called, this module calculates the MRO of all the classes which called C<use Class::C3>. It then
 283 gathers information from the symbol tables of each of those classes, and builds a set of method
 284 aliases for the correct dispatch ordering. Once all these C3-based method tables are created, it
 285 then adds the method aliases into the local classes symbol table.
 286
 287 The end result is actually classes with pre-cached method dispatch. However, this caching does not
 288 do well if you start changing your C<@ISA> or messing with class symbol tables, so you should consider
 289 your classes to be effectively closed. See the L<CAVEATS> section for more details.
 290
 291 =head1 OPTIONAL LOWERCASE PRAGMA
 292
 293 This release also includes an optional module B<c3> in the F<opt/> folder. I did not include this in
 294 the regular install since lowercase module names are considered I<"bad"> by some people. However I
 295 think that code looks much nicer like this:
 296
 297   package MyClass;
 298   use c3;
 299
 300 The the more clunky:
 301
 302   package MyClass;
 303   use Class::C3;
 304
 305 But hey, it's your choice, thats why it is optional.
 306
 307 =head1 FUNCTIONS
 308
 309 =over 4
 310
 311 =item B<calculateMRO ($class)>
 312
 313 Given a C<$class> this will return an array of class names in the proper C3 method resolution order.
 314
 315 =item B<initialize>
 316
 317 This B<must be called> to initalize the C3 method dispatch tables, this module B<will not work> if
 318 you do not do this. It is advised to do this as soon as possible B<after> any classes which use C3.
 319
 320 This function used to be called automatically for you in the INIT phase of the perl compiler, but
 321 that lead to warnings if this module was required at runtime. After discussion with my user base
 322 (the L<DBIx::Class> folks), we decided that calling this in INIT was more of an annoyance than a
 323 convience. I apologize to anyone this causes problems for (although i would very suprised if I had
 324 any other users other than the L<DBIx::Class> folks). The simplest solution of course is to define
 325 your own INIT method which calls this function.
 326
 327 NOTE:
 328 This can B<not> be used to re-load the dispatch tables for all classes. Use C<reinitialize> for that.
 329
 330 =item B<uninitialize>
 331
 332 Calling this function results in the removal of all cached methods, and the restoration of the old Perl 5
 333 style dispatch order (depth-first, left-to-right).
 334
 335 =item B<reinitialize>
 336
 337 This effectively calls C<uninitialize> followed by C<initialize> the result of which is a reloading of
 338 B<all> the calculated C3 dispatch tables.
 339
 340 It should be noted that if you have a large class library, this could potentially be a rather costly
 341 operation.
 342
 343 =back
 344
 345 =head1 METHOD REDISPATCHING
 346
 347 It is always useful to be able to re-dispatch your method call to the "next most applicable method". This
 348 module provides a pseudo package along the lines of C<SUPER::> or C<NEXT::> which will re-dispatch the
 349 method along the C3 linearization. This is best show with an examples.
 350
 351   # a classic diamond MI pattern ...
 352      <A>
 353     /   \
 354   <B>   <C>
 355     \   /
 356      <D>
 357
 358   package A;
 359   use c3;
 360   sub foo { 'A::foo' }
 361
 362   package B;
 363   use base 'A';
 364   use c3;
 365   sub foo { 'B::foo => ' . (shift)->next::method() }
 366
 367   package B;
 368   use base 'A';
 369   use c3;
 370   sub foo { 'C::foo => ' . (shift)->next::method() }
 371
 372   package D;
 373   use base ('B', 'C');
 374   use c3;
 375   sub foo { 'D::foo => ' . (shift)->next::method() }
 376
 377   print D->foo; # prints out "D::foo => B::foo => C::foo => A::foo"
 378
 379 A few things to note. First, we do not require you to add on the method name to the C<next::method>
 380 call (this is unlike C<NEXT::> and C<SUPER::> which do require that). This helps to enforce the rule
 381 that you cannot dispatch to a method of a different name (this is how C<NEXT::> behaves as well).
 382
 383 The next thing to keep in mind is that you will need to pass all arguments to C<next::method> it can
 384 not automatically use the current C<@_>.
 385
 386 There are some caveats about using C<next::method>, see below for those.
 387
 388 =head1 CAVEATS
 389
 390 This module used to be labeled as I<experimental>, however it has now been pretty heavily tested by
 391 the good folks over at L<DBIx::Class> and I am confident this module is perfectly usable for
 392 whatever your needs might be.
 393
 394 But there are still caveats, so here goes ...
 395
 396 =over 4
 397
 398 =item Use of C<SUPER::>.
 399
 400 The idea of C<SUPER::> under multiple inheritence is ambigious, and generally not recomended anyway.
 401 However, it's use in conjuntion with this module is very much not recommended, and in fact very
 402 discouraged. The recommended approach is to instead use the supplied C<next::method> feature, see
 403 more details on it's usage above.
 404
 405 =item Changing C<@ISA>.
 406
 407 It is the author's opinion that changing C<@ISA> at runtime is pure insanity anyway. However, people
 408 do it, so I must caveat. Any changes to the C<@ISA> will not be reflected in the MRO calculated by this
 409 module, and therefor probably won't even show up. If you do this, you will need to call C<reinitialize>
 410 in order to recalulate B<all> method dispatch tables. See the C<reinitialize> documentation and an example
 411 in F<t/20_reinitialize.t> for more information.
 412
 413 =item Adding/deleting methods from class symbol tables.
 414
 415 This module calculates the MRO for each requested class by interogatting the symbol tables of said classes.
 416 So any symbol table manipulation which takes place after our INIT phase is run will not be reflected in
 417 the calculated MRO. Just as with changing the C<@ISA>, you will need to call C<reinitialize> for any
 418 changes you make to take effect.
 419
 420 =item Calling C<next::method> from methods defined outside the class
 421
 422 There is an edge case when using C<next::method> from within a subroutine which was created in a different
 423 module than the one it is called from. It sounds complicated, but it really isn't. Here is an example which
 424 will not work correctly:
 425
 426   *Foo::foo = sub { (shift)->next::method(@_) };
 427
 428 The problem exists because the anonymous subroutine being assigned to the glob C<*Foo::foo> will show up
 429 in the call stack as being called C<__ANON__> and not C<foo> as you might expect. Since C<next::method>
 430 uses C<caller> to find the name of the method it was called in, it will fail in this case.
 431
 432 But fear not, there is a simple solution. The module C<Sub::Name> will reach into the perl internals and
 433 assign a name to an anonymous subroutine for you. Simply do this:
 434
 435   use Sub::Name 'subname';
 436   *Foo::foo = subname 'Foo::foo' => sub { (shift)->next::method(@_) };
 437
 438 and things will Just Work. Of course this is not always possible to do, but to be honest, I just can't
 439 manage to find a workaround for it, so until someone gives me a working patch this will be a known
 440 limitation of this module.
 441
 442 =back
 443
 444 =head1 CODE COVERAGE
 445
 446 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
 447 module's test suite.
 448
 449  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 450  File                           stmt   bran   cond    sub    pod   time  total
 451  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 452  Class/C3.pm                    98.6   90.9   73.3   96.0  100.0   96.8   95.3
 453  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 454  Total                          98.6   90.9   73.3   96.0  100.0   96.8   95.3
 455  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 456
 457 =head1 SEE ALSO
 458
 459 =head2 The original Dylan paper
 460
 461 =over 4
 462
 463 =item L<http://www.webcom.com/haahr/dylan/linearization-oopsla96.html>
 464
 465 =back
 466
 467 =head2 The prototype Perl 6 Object Model uses C3
 468
 469 =over 4
 470
 471 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel/>
 472
 473 =back
 474
 475 =head2 Parrot now uses C3
 476
 477 =over 4
 478
 479 =item L<http://aspn.activestate.com/ASPN/Mail/Message/perl6-internals/2746631>
 480
 481 =item L<http://use.perl.org/~autrijus/journal/25768>
 482
 483 =back
 484
 485 =head2 Python 2.3 MRO related links
 486
 487 =over 4
 488
 489 =item L<http://www.python.org/2.3/mro.html>
 490
 491 =item L<http://www.python.org/2.2.2/descrintro.html#mro>
 492
 493 =back
 494
 495 =head2 C3 for TinyCLOS
 496
 497 =over 4
 498
 499 =item L<http://www.call-with-current-continuation.org/eggs/c3.html>
 500
 501 =back
 502
 503 =head1 ACKNOWLEGEMENTS
 504
 505 =over 4
 506
 507 =item Thanks to Matt S. Trout for using this module in his module L<DBIx::Class>
 508 and finding many bugs and providing fixes.
 509
 510 =item Thanks to Justin Guenther for making C<next::method> more robust by handling
 511 calls inside C<eval> and anon-subs.
 512
 513 =back
 514
 515 =head1 AUTHOR
 516
 517 Stevan Little, E<lt>stevan@iinteractive.comE<gt>
 518
 519 =head1 COPYRIGHT AND LICENSE
 520
 521 Copyright 2005, 2006 by Infinity Interactive, Inc.
 522
 523 L<http://www.iinteractive.com>
 524
 525 This library is free software; you can redistribute it and/or modify
 526 it under the same terms as Perl itself.
 527
 528 =cut