lib/Class/C3.pm

   1
   2 package Class::C3;
   3
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION = '0.15_01';
   8
   9 our $C3_IN_CORE;
  10
  11 BEGIN {
  12     eval "require mro"; # XXX in the future, this should be a version check
  13     if($@) {
  14         die $@ if $@ !~ /locate/;
  15 #        eval "require Class::C3::XS";
  16 #        if($@) {
  17 #            die $@ if $@ !~ /locate/;
  18             eval "require Algorithm::C3; require Class::C3::next";
  19             die $@ if $@;
  20 #        }
  21     }
  22     else {
  23         $C3_IN_CORE = 1;
  24     }
  25 }
  26
  27 # this is our global stash of both
  28 # MRO's and method dispatch tables
  29 # the structure basically looks like
  30 # this:
  31 #
  32 #   $MRO{$class} = {
  33 #      MRO => [ <class precendence list> ],
  34 #      methods => {
  35 #          orig => <original location of method>,
  36 #          code => \&<ref to original method>
  37 #      },
  38 #      has_overload_fallback => (1 | 0)
  39 #   }
  40 #
  41 our %MRO;
  42
  43 # use these for debugging ...
  44 sub _dump_MRO_table { %MRO }
  45 our $TURN_OFF_C3 = 0;
  46
  47 # state tracking for initialize()/uninitialize()
  48 our $_initialized = 0;
  49
  50 sub import {
  51     my $class = caller();
  52     # skip if the caller is main::
  53     # since that is clearly not relevant
  54     return if $class eq 'main';
  55
  56     return if $TURN_OFF_C3;
  57     mro::set_mro($class, 'c3') if $C3_IN_CORE;
  58
  59     # make a note to calculate $class
  60     # during INIT phase
  61     $MRO{$class} = undef unless exists $MRO{$class};
  62 }
  63
  64 ## initializers
  65
  66 sub initialize {
  67     %next::METHOD_CACHE = ();
  68     # why bother if we don't have anything ...
  69     return unless keys %MRO;
  70     if($C3_IN_CORE) {
  71         mro::set_mro($_, 'c3') for keys %MRO;
  72     }
  73     else {
  74         if($_initialized) {
  75             uninitialize();
  76             $MRO{$_} = undef foreach keys %MRO;
  77         }
  78         _calculate_method_dispatch_tables();
  79         _apply_method_dispatch_tables();
  80         $_initialized = 1;
  81     }
  82 }
  83
  84 sub uninitialize {
  85     # why bother if we don't have anything ...
  86     %next::METHOD_CACHE = ();
  87     return unless keys %MRO;
  88     if($C3_IN_CORE) {
  89         mro::set_mro($_, 'dfs') for keys %MRO;
  90     }
  91     else {
  92         _remove_method_dispatch_tables();
  93         $_initialized = 0;
  94     }
  95 }
  96
  97 sub reinitialize { goto &initialize }
  98
  99 ## functions for applying C3 to classes
 100
 101 sub _calculate_method_dispatch_tables {
 102     return if $C3_IN_CORE;
 103     my %merge_cache;
 104     foreach my $class (keys %MRO) {
 105         _calculate_method_dispatch_table($class, \%merge_cache);
 106     }
 107 }
 108
 109 sub _calculate_method_dispatch_table {
 110     return if $C3_IN_CORE;
 111     my ($class, $merge_cache) = @_;
 112     no strict 'refs';
 113     my @MRO = calculateMRO($class, $merge_cache);
 114     $MRO{$class} = { MRO => \@MRO };
 115     my $has_overload_fallback = 0;
 116     my %methods;
 117     # NOTE:
 118     # we do @MRO[1 .. $#MRO] here because it
 119     # makes no sense to interogate the class
 120     # which you are calculating for.
 121     foreach my $local (@MRO[1 .. $#MRO]) {
 122         # if overload has tagged this module to
 123         # have use "fallback", then we want to
 124         # grab that value
 125         $has_overload_fallback = ${"${local}::()"}
 126             if defined ${"${local}::()"};
 127         foreach my $method (grep { defined &{"${local}::$_"} } keys %{"${local}::"}) {
 128             # skip if already overriden in local class
 129             next unless !defined *{"${class}::$method"}{CODE};
 130             $methods{$method} = {
 131                 orig => "${local}::$method",
 132                 code => \&{"${local}::$method"}
 133             } unless exists $methods{$method};
 134         }
 135     }
 136     # now stash them in our %MRO table
 137     $MRO{$class}->{methods} = \%methods;
 138     $MRO{$class}->{has_overload_fallback} = $has_overload_fallback;
 139 }
 140
 141 sub _apply_method_dispatch_tables {
 142     return if $C3_IN_CORE;
 143     foreach my $class (keys %MRO) {
 144         _apply_method_dispatch_table($class);
 145     }
 146 }
 147
 148 sub _apply_method_dispatch_table {
 149     return if $C3_IN_CORE;
 150     my $class = shift;
 151     no strict 'refs';
 152     ${"${class}::()"} = $MRO{$class}->{has_overload_fallback}
 153         if $MRO{$class}->{has_overload_fallback};
 154     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 155         *{"${class}::$method"} = $MRO{$class}->{methods}->{$method}->{code};
 156     }
 157 }
 158
 159 sub _remove_method_dispatch_tables {
 160     return if $C3_IN_CORE;
 161     foreach my $class (keys %MRO) {
 162         _remove_method_dispatch_table($class);
 163     }
 164 }
 165
 166 sub _remove_method_dispatch_table {
 167     return if $C3_IN_CORE;
 168     my $class = shift;
 169     no strict 'refs';
 170     delete ${"${class}::"}{"()"} if $MRO{$class}->{has_overload_fallback};
 171     foreach my $method (keys %{$MRO{$class}->{methods}}) {
 172         delete ${"${class}::"}{$method}
 173             if defined *{"${class}::${method}"}{CODE} &&
 174                (*{"${class}::${method}"}{CODE} eq $MRO{$class}->{methods}->{$method}->{code});
 175     }
 176 }
 177
 178 sub calculateMRO {
 179     my ($class, $merge_cache) = @_;
 180
 181     return @{mro::get_linear_isa($class)} if $C3_IN_CORE;
 182
 183     return Algorithm::C3::merge($class, sub {
 184         no strict 'refs';
 185         @{$_[0] . '::ISA'};
 186     }, $merge_cache);
 187 }
 188
 189 1;
 190
 191 __END__
 192
 193 =pod
 194
 195 =head1 NAME
 196
 197 Class::C3 - A pragma to use the C3 method resolution order algortihm
 198
 199 =head1 SYNOPSIS
 200
 201     package A;
 202     use Class::C3;
 203     sub hello { 'A::hello' }
 204
 205     package B;
 206     use base 'A';
 207     use Class::C3;
 208
 209     package C;
 210     use base 'A';
 211     use Class::C3;
 212
 213     sub hello { 'C::hello' }
 214
 215     package D;
 216     use base ('B', 'C');
 217     use Class::C3;
 218
 219     # Classic Diamond MI pattern
 220     #    <A>
 221     #   /   \
 222     # <B>   <C>
 223     #   \   /
 224     #    <D>
 225
 226     package main;
 227
 228     # initializez the C3 module
 229     # (formerly called in INIT)
 230     Class::C3::initialize();
 231
 232     print join ', ' => Class::C3::calculateMRO('Diamond_D') # prints D, B, C, A
 233
 234     print D->hello() # prints 'C::hello' instead of the standard p5 'A::hello'
 235
 236     D->can('hello')->();          # can() also works correctly
 237     UNIVERSAL::can('D', 'hello'); # as does UNIVERSAL::can()
 238
 239 =head1 SPECIAL NOTE FOR 0.15_01
 240
 241 To try this with the experimental perl core c3 patch,
 242 download a recent copy perl-current:
 243
 244 http://mirrors.develooper.com/perl/APC/perl-current-snap/perl-current@30943.tar.bz2
 245
 246 apply the enclosed c3.patch, and install this perl:
 247
 248 sh Configure -Dusedevel -Dprefix=/where/I/want/it -d -e && make && make test && make install
 249
 250 then try your C3-using software against this perl + Class::C3 0.15_01.
 251
 252 =head1 DESCRIPTION
 253
 254 This is pragma to change Perl 5's standard method resolution order from depth-first left-to-right
 255 (a.k.a - pre-order) to the more sophisticated C3 method resolution order.
 256
 257 =head2 What is C3?
 258
 259 C3 is the name of an algorithm which aims to provide a sane method resolution order under multiple
 260 inheritence. It was first introduced in the langauge Dylan (see links in the L<SEE ALSO> section),
 261 and then later adopted as the prefered MRO (Method Resolution Order) for the new-style classes in
 262 Python 2.3. Most recently it has been adopted as the 'canonical' MRO for Perl 6 classes, and the
 263 default MRO for Parrot objects as well.
 264
 265 =head2 How does C3 work.
 266
 267 C3 works by always preserving local precendence ordering. This essentially means that no class will
 268 appear before any of it's subclasses. Take the classic diamond inheritence pattern for instance:
 269
 270      <A>
 271     /   \
 272   <B>   <C>
 273     \   /
 274      <D>
 275
 276 The standard Perl 5 MRO would be (D, B, A, C). The result being that B<A> appears before B<C>, even
 277 though B<C> is the subclass of B<A>. The C3 MRO algorithm however, produces the following MRO
 278 (D, B, C, A), which does not have this same issue.
 279
 280 This example is fairly trival, for more complex examples and a deeper explaination, see the links in
 281 the L<SEE ALSO> section.
 282
 283 =head2 How does this module work?
 284
 285 This module uses a technique similar to Perl 5's method caching. When C<Class::C3::initialize> is
 286 called, this module calculates the MRO of all the classes which called C<use Class::C3>. It then
 287 gathers information from the symbol tables of each of those classes, and builds a set of method
 288 aliases for the correct dispatch ordering. Once all these C3-based method tables are created, it
 289 then adds the method aliases into the local classes symbol table.
 290
 291 The end result is actually classes with pre-cached method dispatch. However, this caching does not
 292 do well if you start changing your C<@ISA> or messing with class symbol tables, so you should consider
 293 your classes to be effectively closed. See the L<CAVEATS> section for more details.
 294
 295 =head1 OPTIONAL LOWERCASE PRAGMA
 296
 297 This release also includes an optional module B<c3> in the F<opt/> folder. I did not include this in
 298 the regular install since lowercase module names are considered I<"bad"> by some people. However I
 299 think that code looks much nicer like this:
 300
 301   package MyClass;
 302   use c3;
 303
 304 The the more clunky:
 305
 306   package MyClass;
 307   use Class::C3;
 308
 309 But hey, it's your choice, thats why it is optional.
 310
 311 =head1 FUNCTIONS
 312
 313 =over 4
 314
 315 =item B<calculateMRO ($class)>
 316
 317 Given a C<$class> this will return an array of class names in the proper C3 method resolution order.
 318
 319 =item B<initialize>
 320
 321 This B<must be called> to initalize the C3 method dispatch tables, this module B<will not work> if
 322 you do not do this. It is advised to do this as soon as possible B<after> loading any classes which
 323 use C3. Here is a quick code example:
 324
 325   package Foo;
 326   use Class::C3;
 327   # ... Foo methods here
 328
 329   package Bar;
 330   use Class::C3;
 331   use base 'Foo';
 332   # ... Bar methods here
 333
 334   package main;
 335
 336   Class::C3::initialize(); # now it is safe to use Foo and Bar
 337
 338 This function used to be called automatically for you in the INIT phase of the perl compiler, but
 339 that lead to warnings if this module was required at runtime. After discussion with my user base
 340 (the L<DBIx::Class> folks), we decided that calling this in INIT was more of an annoyance than a
 341 convience. I apologize to anyone this causes problems for (although i would very suprised if I had
 342 any other users other than the L<DBIx::Class> folks). The simplest solution of course is to define
 343 your own INIT method which calls this function.
 344
 345 NOTE:
 346
 347 If C<initialize> detects that C<initialize> has already been executed, it will L</uninitialize> and
 348 clear the MRO cache first.
 349
 350 =item B<uninitialize>
 351
 352 Calling this function results in the removal of all cached methods, and the restoration of the old Perl 5
 353 style dispatch order (depth-first, left-to-right).
 354
 355 =item B<reinitialize>
 356
 357 This is an alias for L</initialize> above.
 358
 359 =back
 360
 361 =head1 METHOD REDISPATCHING
 362
 363 It is always useful to be able to re-dispatch your method call to the "next most applicable method". This
 364 module provides a pseudo package along the lines of C<SUPER::> or C<NEXT::> which will re-dispatch the
 365 method along the C3 linearization. This is best show with an examples.
 366
 367   # a classic diamond MI pattern ...
 368      <A>
 369     /   \
 370   <B>   <C>
 371     \   /
 372      <D>
 373
 374   package A;
 375   use c3;
 376   sub foo { 'A::foo' }
 377
 378   package B;
 379   use base 'A';
 380   use c3;
 381   sub foo { 'B::foo => ' . (shift)->next::method() }
 382
 383   package B;
 384   use base 'A';
 385   use c3;
 386   sub foo { 'C::foo => ' . (shift)->next::method() }
 387
 388   package D;
 389   use base ('B', 'C');
 390   use c3;
 391   sub foo { 'D::foo => ' . (shift)->next::method() }
 392
 393   print D->foo; # prints out "D::foo => B::foo => C::foo => A::foo"
 394
 395 A few things to note. First, we do not require you to add on the method name to the C<next::method>
 396 call (this is unlike C<NEXT::> and C<SUPER::> which do require that). This helps to enforce the rule
 397 that you cannot dispatch to a method of a different name (this is how C<NEXT::> behaves as well).
 398
 399 The next thing to keep in mind is that you will need to pass all arguments to C<next::method> it can
 400 not automatically use the current C<@_>.
 401
 402 If C<next::method> cannot find a next method to re-dispatch the call to, it will throw an exception.
 403 You can use C<next::can> to see if C<next::method> will succeed before you call it like so:
 404
 405   $self->next::method(@_) if $self->next::can;
 406
 407 Additionally, you can use C<maybe::next::method> as a shortcut to only call the next method if it exists.
 408 The previous example could be simply written as:
 409
 410   $self->maybe::next::method(@_);
 411
 412 There are some caveats about using C<next::method>, see below for those.
 413
 414 =head1 CAVEATS
 415
 416 This module used to be labeled as I<experimental>, however it has now been pretty heavily tested by
 417 the good folks over at L<DBIx::Class> and I am confident this module is perfectly usable for
 418 whatever your needs might be.
 419
 420 But there are still caveats, so here goes ...
 421
 422 =over 4
 423
 424 =item Use of C<SUPER::>.
 425
 426 The idea of C<SUPER::> under multiple inheritence is ambigious, and generally not recomended anyway.
 427 However, it's use in conjuntion with this module is very much not recommended, and in fact very
 428 discouraged. The recommended approach is to instead use the supplied C<next::method> feature, see
 429 more details on it's usage above.
 430
 431 =item Changing C<@ISA>.
 432
 433 It is the author's opinion that changing C<@ISA> at runtime is pure insanity anyway. However, people
 434 do it, so I must caveat. Any changes to the C<@ISA> will not be reflected in the MRO calculated by this
 435 module, and therefor probably won't even show up. If you do this, you will need to call C<reinitialize>
 436 in order to recalulate B<all> method dispatch tables. See the C<reinitialize> documentation and an example
 437 in F<t/20_reinitialize.t> for more information.
 438
 439 =item Adding/deleting methods from class symbol tables.
 440
 441 This module calculates the MRO for each requested class by interogatting the symbol tables of said classes.
 442 So any symbol table manipulation which takes place after our INIT phase is run will not be reflected in
 443 the calculated MRO. Just as with changing the C<@ISA>, you will need to call C<reinitialize> for any
 444 changes you make to take effect.
 445
 446 =item Calling C<next::method> from methods defined outside the class
 447
 448 There is an edge case when using C<next::method> from within a subroutine which was created in a different
 449 module than the one it is called from. It sounds complicated, but it really isn't. Here is an example which
 450 will not work correctly:
 451
 452   *Foo::foo = sub { (shift)->next::method(@_) };
 453
 454 The problem exists because the anonymous subroutine being assigned to the glob C<*Foo::foo> will show up
 455 in the call stack as being called C<__ANON__> and not C<foo> as you might expect. Since C<next::method>
 456 uses C<caller> to find the name of the method it was called in, it will fail in this case.
 457
 458 But fear not, there is a simple solution. The module C<Sub::Name> will reach into the perl internals and
 459 assign a name to an anonymous subroutine for you. Simply do this:
 460
 461   use Sub::Name 'subname';
 462   *Foo::foo = subname 'Foo::foo' => sub { (shift)->next::method(@_) };
 463
 464 and things will Just Work. Of course this is not always possible to do, but to be honest, I just can't
 465 manage to find a workaround for it, so until someone gives me a working patch this will be a known
 466 limitation of this module.
 467
 468 =back
 469
 470 =head1 CODE COVERAGE
 471
 472 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
 473 module's test suite.
 474
 475  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 476  File                           stmt   bran   cond    sub    pod   time  total
 477  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 478  Class/C3.pm                    98.3   84.4   80.0   96.2  100.0   98.4   94.4
 479  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 480  Total                          98.3   84.4   80.0   96.2  100.0   98.4   94.4
 481  ---------------------------- ------ ------ ------ ------ ------ ------ ------
 482
 483 =head1 SEE ALSO
 484
 485 =head2 The original Dylan paper
 486
 487 =over 4
 488
 489 =item L<http://www.webcom.com/haahr/dylan/linearization-oopsla96.html>
 490
 491 =back
 492
 493 =head2 The prototype Perl 6 Object Model uses C3
 494
 495 =over 4
 496
 497 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel/>
 498
 499 =back
 500
 501 =head2 Parrot now uses C3
 502
 503 =over 4
 504
 505 =item L<http://aspn.activestate.com/ASPN/Mail/Message/perl6-internals/2746631>
 506
 507 =item L<http://use.perl.org/~autrijus/journal/25768>
 508
 509 =back
 510
 511 =head2 Python 2.3 MRO related links
 512
 513 =over 4
 514
 515 =item L<http://www.python.org/2.3/mro.html>
 516
 517 =item L<http://www.python.org/2.2.2/descrintro.html#mro>
 518
 519 =back
 520
 521 =head2 C3 for TinyCLOS
 522
 523 =over 4
 524
 525 =item L<http://www.call-with-current-continuation.org/eggs/c3.html>
 526
 527 =back
 528
 529 =head1 ACKNOWLEGEMENTS
 530
 531 =over 4
 532
 533 =item Thanks to Matt S. Trout for using this module in his module L<DBIx::Class>
 534 and finding many bugs and providing fixes.
 535
 536 =item Thanks to Justin Guenther for making C<next::method> more robust by handling
 537 calls inside C<eval> and anon-subs.
 538
 539 =item Thanks to Robert Norris for adding support for C<next::can> and
 540 C<maybe::next::method>.
 541
 542 =back
 543
 544 =head1 AUTHOR
 545
 546 Stevan Little, E<lt>stevan@iinteractive.comE<gt>
 547
 548 Brandon L. Black, E<lt>blblack@gmail.comE<gt>
 549
 550 =head1 COPYRIGHT AND LICENSE
 551
 552 Copyright 2005, 2006 by Infinity Interactive, Inc.
 553
 554 L<http://www.iinteractive.com>
 555
 556 This library is free software; you can redistribute it and/or modify
 557 it under the same terms as Perl itself.
 558
 559 =cut