xt/optional_deps.t

   1 my ($inc_before, $inc_after);
   2 BEGIN {
   3   $inc_before = [ keys %INC ];
   4   require DBIx::Class::Optional::Dependencies;
   5   $inc_after = [ keys %INC ];
   6 }
   7
   8 use strict;
   9 use warnings;
  10 no warnings qw/once/;
  11
  12 use Test::More;
  13 use Test::Exception;
  14
  15 # load before we break require()
  16 use Scalar::Util();
  17 use MRO::Compat();
  18 use Carp 'confess';
  19 use List::Util 'shuffle';
  20
  21 ok ( (! grep { $_ =~ m|DBIx/Class| } @$inc_before ), 'Nothing DBIC related was loaded before inc-test')
  22   unless $ENV{PERL5OPT}; # a defined PERL5OPT may inject extra deps crashing this test
  23
  24 is_deeply (
  25   [ sort @$inc_after],
  26   [ sort (@$inc_before, qw( DBIx/Class/Optional/Dependencies.pm if.pm )) ],
  27   'Nothing loaded other than DBIx::Class::OptDeps',
  28 ) unless $ENV{RELEASE_TESTING};
  29
  30
  31 # check the project-local groups for sanity
  32 lives_ok {
  33   DBIx::Class::Optional::Dependencies->req_group_list
  34 } "The entire optdep list is well formed";
  35
  36 is_deeply (
  37   [ keys %{ DBIx::Class::Optional::Dependencies->req_list_for ('deploy') } ],
  38   [ 'SQL::Translator' ],
  39   'Correct deploy() dependency list',
  40 );
  41
  42 # scope to break require()
  43 {
  44
  45 # make module loading impossible, regardless of actual libpath contents
  46   local @INC = (sub { confess('Optional Dep Test') } );
  47
  48 # basic test using the deploy target
  49   for ('deploy', ['deploy']) {
  50
  51     # explicitly blow up cache
  52     %DBIx::Class::Optional::Dependencies::req_unavailability_cache = ();
  53
  54     ok (
  55       ! DBIx::Class::Optional::Dependencies->req_ok_for ($_),
  56       'deploy() deps missing',
  57     );
  58
  59     like (
  60       DBIx::Class::Optional::Dependencies->modreq_missing_for ($_),
  61       qr/
  62         \A
  63         " SQL::Translator \~ \>\= [\d\.]+ "
  64         \z
  65       /x,
  66       'expected modreq missing string contents',
  67     );
  68
  69     like (
  70       DBIx::Class::Optional::Dependencies->req_missing_for ($_),
  71       qr/
  72         \A
  73         " SQL::Translator \~ \>\= [\d\.]+ "
  74         \Q (see DBIx::Class::Optional::Dependencies documentation for details)\E
  75         \z
  76       /x,
  77       'expected missing string contents',
  78     );
  79
  80     like (
  81       DBIx::Class::Optional::Dependencies->modreq_errorlist_for ($_)->{'SQL::Translator'},
  82       qr/Optional Dep Test/,
  83       'custom exception found in errorlist',
  84     );
  85
  86     #make it so module appears loaded
  87     local $INC{'SQL/Translator.pm'} = 1;
  88     local $SQL::Translator::VERSION = 999;
  89
  90     ok (
  91       ! DBIx::Class::Optional::Dependencies->req_ok_for ($_),
  92       'deploy() deps missing cached properly from previous run',
  93     );
  94
  95     # blow cache again
  96     %DBIx::Class::Optional::Dependencies::req_unavailability_cache = ();
  97
  98     ok (
  99       DBIx::Class::Optional::Dependencies->req_ok_for ($_),
 100       'deploy() deps present',
 101     );
 102
 103     is (
 104       DBIx::Class::Optional::Dependencies->req_missing_for ($_),
 105       '',
 106       'expected null missing string',
 107     );
 108
 109     is_deeply (
 110       # use the deprecated method name
 111       DBIx::Class::Optional::Dependencies->req_errorlist_for ($_),
 112       undef,
 113       'expected empty errorlist',
 114     );
 115   }
 116
 117 # test single-db text
 118   local $ENV{DBICTEST_MYSQL_DSN};
 119   is_deeply(
 120     DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_mysql'),
 121     undef,
 122     'unknown optional dependencies list for testing MySQL without ENV var',
 123   );
 124   is_deeply(
 125     DBIx::Class::Optional::Dependencies->modreq_list_for('test_rdbms_mysql'),
 126     { 'DBD::mysql' => 0 },
 127     'correct optional module dependencies list for testing MySQL without ENV var',
 128   );
 129
 130   local $ENV{DBICTEST_MYSQL_DSN};
 131   local $ENV{DBICTEST_PG_DSN};
 132
 133   is_deeply(
 134     DBIx::Class::Optional::Dependencies->modreq_list_for('test_rdbms_pg'),
 135     { 'DBD::Pg' => '2.009002' },
 136     'optional dependencies list for testing Postgres without envvar',
 137   );
 138
 139   is_deeply(
 140     DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_pg'),
 141     undef,
 142     'optional dependencies list for testing Postgres without envvar',
 143   );
 144
 145   is_deeply(
 146     DBIx::Class::Optional::Dependencies->req_list_for('rdbms_pg'),
 147     { 'DBD::Pg' => '0', },
 148     'optional dependencies list for using Postgres matches',
 149   );
 150
 151   is_deeply(
 152     DBIx::Class::Optional::Dependencies->req_missing_for('rdbms_pg'),
 153     'DBD::Pg (see DBIx::Class::Optional::Dependencies documentation for details)',
 154     'optional dependencies missing list for using Postgres matches',
 155   );
 156
 157 # test combination of different requirements on same module (pg's are relatively stable)
 158   is_deeply (
 159     DBIx::Class::Optional::Dependencies->req_list_for([shuffle qw( rdbms_pg test_rdbms_pg )]),
 160     { 'DBD::Pg' => '0' },
 161     'optional module dependencies list for testing Postgres matches without envvar',
 162   );
 163
 164   is(
 165     DBIx::Class::Optional::Dependencies->req_missing_for([qw( rdbms_pg test_rdbms_pg )]),
 166     '"DBD::Pg~>=2.009002" as well as the following group(s) of environment variables: DBICTEST_PG_DSN/..._USER/..._PASS',
 167     'optional dependencies for testing Postgres without envvar'
 168   );
 169
 170   is(
 171     DBIx::Class::Optional::Dependencies->req_missing_for([shuffle qw( test_rdbms_mysql test_rdbms_pg )]),
 172     'DBD::mysql "DBD::Pg~>=2.009002" as well as the following group(s) of environment variables: DBICTEST_MYSQL_DSN/..._USER/..._PASS and DBICTEST_PG_DSN/..._USER/..._PASS',
 173     'optional dependencies for testing Postgres+MySQL without envvars'
 174   );
 175
 176   $ENV{DBICTEST_PG_DSN} = 'boo';
 177   is_deeply (
 178     DBIx::Class::Optional::Dependencies->modreq_list_for([shuffle qw( rdbms_pg test_rdbms_pg )]),
 179     { 'DBD::Pg' => '2.009002' },
 180     'optional module dependencies list for testing Postgres matches with envvar',
 181   );
 182
 183   is(
 184     DBIx::Class::Optional::Dependencies->req_missing_for([shuffle qw( rdbms_pg test_rdbms_pg )]),
 185     '"DBD::Pg~>=2.009002"',
 186     'optional dependencies error text for testing Postgres matches with evvar',
 187   );
 188
 189 # test multi-level include with a variable and mandatory part converging on same included dep
 190   local $ENV{DBICTEST_MSACCESS_ODBC_DSN};
 191   local $ENV{DBICTEST_MSSQL_ODBC_DSN} = 'foo';
 192   my $msaccess_mssql = [ shuffle qw( test_rdbms_msaccess_odbc test_rdbms_mssql_odbc ) ];
 193   is_deeply(
 194     DBIx::Class::Optional::Dependencies->req_missing_for($msaccess_mssql),
 195     'Data::GUID DBD::ODBC as well as the following group(s) of environment variables: DBICTEST_MSACCESS_ODBC_DSN/..._USER/..._PASS',
 196     'Correct req_missing_for on multi-level converging include',
 197   );
 198
 199   is_deeply(
 200     DBIx::Class::Optional::Dependencies->modreq_missing_for($msaccess_mssql),
 201     'Data::GUID DBD::ODBC',
 202     'Correct modreq_missing_for on multi-level converging include',
 203   );
 204
 205   is_deeply(
 206     DBIx::Class::Optional::Dependencies->req_list_for($msaccess_mssql),
 207     {
 208       'DBD::ODBC' => 0,
 209     },
 210     'Correct req_list_for on multi-level converging include',
 211   );
 212
 213   is_deeply(
 214     DBIx::Class::Optional::Dependencies->modreq_list_for($msaccess_mssql),
 215     {
 216       'DBD::ODBC' => 0,
 217       'Data::GUID' => 0,
 218     },
 219     'Correct modreq_list_for on multi-level converging include',
 220   );
 221
 222 }
 223
 224 # test multiple times to find autovivification bugs
 225 for my $meth (qw(req_list_for modreq_list_for)) {
 226   throws_ok {
 227     DBIx::Class::Optional::Dependencies->$meth();
 228   } qr/\Qreq_list_for() expects a requirement group name/,
 229   "$meth without groupname throws exception";
 230
 231   throws_ok {
 232     DBIx::Class::Optional::Dependencies->$meth('');
 233   } qr/\Q$meth() expects a requirement group name/,
 234   "$meth with empty groupname throws exception";
 235
 236   throws_ok {
 237     DBIx::Class::Optional::Dependencies->$meth('invalid_groupname');
 238   } qr/Requirement group 'invalid_groupname' is not defined/,
 239   "$meth with invalid groupname throws exception";
 240 }
 241
 242 done_testing;