xt/extra/lean_startup.t

   1 BEGIN { $ENV{DBICTEST_ANFANG_DEFANG} = 1 }
   2
   3 # Use a require override instead of @INC munging (less common)
   4 # Do the override as early as possible so that CORE::require doesn't get compiled away
   5
   6 my ($initial_inc_contents, $expected_dbic_deps, $require_sites);
   7 BEGIN {
   8   # these envvars *will* bring in more stuff than the baseline
   9   delete @ENV{qw(DBICTEST_SQLT_DEPLOY DBIC_TRACE)};
  10
  11   # make sure extras do not load even when this is set
  12   $ENV{PERL_STRICTURES_EXTRA} = 1;
  13
  14   unshift @INC, 't/lib';
  15   require DBICTest::Util::OverrideRequire;
  16
  17   DBICTest::Util::OverrideRequire::override_global_require( sub {
  18     my $res = $_[0]->();
  19
  20     my $req = $_[1];
  21     $req =~ s/\.pm$//;
  22     $req =~ s/\//::/g;
  23
  24     my $up = 0;
  25     my @caller;
  26     do { @caller = caller($up++) } while (
  27       @caller and (
  28         # exclude our test suite, known "module require-rs" and eval frames
  29         $caller[1] =~ /^ t [\/\\] /x
  30           or
  31         $caller[0] =~ /^ (?: base | parent | Class::C3::Componentised | Module::Inspector | Module::Runtime ) $/x
  32           or
  33         $caller[3] eq '(eval)',
  34       )
  35     );
  36
  37     push @{$require_sites->{$req}}, "$caller[1] line $caller[2]"
  38       if @caller;
  39
  40     return $res if $req =~ /^DBIx::Class|^DBICTest::/;
  41
  42     # exclude everything where the current namespace does not match the called function
  43     # (this works around very weird XS-induced require callstack corruption)
  44     if (
  45       !$initial_inc_contents->{$req}
  46         and
  47       !$expected_dbic_deps->{$req}
  48         and
  49       @caller
  50         and
  51       $caller[0] =~ /^DBIx::Class/
  52         and
  53       (caller($up))[3] =~ /\Q$caller[0]/
  54     ) {
  55       CORE::require('Test/More.pm');
  56       Test::More::fail ("Unexpected require of '$req' by $caller[0] ($caller[1] line $caller[2])");
  57
  58       CORE::require('DBICTest/Util.pm');
  59       Test::More::diag( 'Require invoked' .  DBICTest::Util::stacktrace() );
  60     }
  61
  62     return $res;
  63   });
  64 }
  65
  66 use strict;
  67 use warnings;
  68 use Test::More;
  69
  70 BEGIN {
  71   plan skip_all => 'A defined PERL5OPT may inject extra deps crashing this test'
  72     if $ENV{PERL5OPT};
  73
  74   plan skip_all => 'Dependency load patterns are radically different before perl 5.10'
  75     if "$]" < 5.010;
  76
  77   # add what we loaded so far
  78   for (keys %INC) {
  79     my $mod = $_;
  80     $mod =~ s/\.pm$//;
  81     $mod =~ s!\/!::!g;
  82     $initial_inc_contents->{$mod} = 1;
  83   }
  84 }
  85
  86 BEGIN {
  87   delete $ENV{$_} for qw(
  88     DBICTEST_VIA_REPLICATED
  89     DBICTEST_DEBUG_CONCURRENCY_LOCKS
  90   );
  91 }
  92
  93 #######
  94 ### This is where the test starts
  95 #######
  96
  97 # checking base schema load, no storage no connection
  98 {
  99   register_lazy_loadable_requires(qw(
 100     B
 101     constant
 102     overload
 103
 104     base
 105     Devel::GlobalDestruction
 106     mro
 107
 108     Carp
 109     namespace::clean
 110     Try::Tiny
 111     Sub::Name
 112     Sub::Defer
 113     Sub::Quote
 114
 115     File::Spec
 116     Scalar::Util
 117     List::Util
 118     Storable
 119
 120     Class::Accessor::Grouped
 121     Class::C3::Componentised
 122     SQL::Abstract
 123   ));
 124
 125   require DBICTest::Schema;
 126   assert_no_missing_expected_requires();
 127 }
 128
 129 # check schema/storage instantiation with no connect
 130 {
 131   register_lazy_loadable_requires(qw(
 132     Moo
 133     Moo::Object
 134     Method::Generate::Accessor
 135     Method::Generate::Constructor
 136     Context::Preserve
 137   ));
 138
 139   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 140   ok (! $s->storage->connected, 'no connection');
 141   assert_no_missing_expected_requires();
 142 }
 143
 144 # do something (deploy, insert)
 145 {
 146   register_lazy_loadable_requires(qw(
 147     DBI
 148     Hash::Merge
 149   ));
 150
 151   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 152   $s->storage->dbh_do(sub {
 153     $_[1]->do('CREATE TABLE artist (
 154       "artistid" INTEGER PRIMARY KEY NOT NULL,
 155       "name" varchar(100),
 156       "rank" integer NOT NULL DEFAULT 13,
 157       "charfield" char(10)
 158     )');
 159   });
 160
 161   my $art = $s->resultset('Artist')->create({ name => \[ '?' => 'foo'], rank => 42 });
 162   $art->discard_changes;
 163   $art->update({ rank => 69, name => 'foo' });
 164   assert_no_missing_expected_requires();
 165 }
 166
 167 # and do full populate() as well, just in case - shouldn't add new stuff
 168 {
 169   local $ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER};
 170   {
 171     # in general we do not want DBICTest to load before sqla, but it is
 172     # ok to cheat here
 173     local $INC{'SQL/Abstract.pm'};
 174     require DBICTest;
 175   }
 176   my $s = DBICTest->init_schema;
 177   is ($s->resultset('Artist')->find(1)->name, 'Caterwauler McCrae');
 178   assert_no_missing_expected_requires();
 179 }
 180
 181 done_testing;
 182
 183 sub register_lazy_loadable_requires {
 184   local $Test::Builder::Level = $Test::Builder::Level + 1;
 185
 186   for my $mod (@_) {
 187     (my $modfn = "$mod.pm") =~ s!::!\/!g;
 188     fail(join "\n",
 189       "Module $mod already loaded by require site(s):",
 190       (map { "\t$_" } @{$require_sites->{$mod}}),
 191       '',
 192     ) if $INC{$modfn} and !$initial_inc_contents->{$mod};
 193
 194     $expected_dbic_deps->{$mod}++
 195   }
 196 }
 197
 198 # check if anything we were expecting didn't actually load
 199 sub assert_no_missing_expected_requires {
 200   my $nl;
 201   for my $mod (keys %$expected_dbic_deps) {
 202     (my $modfn = "$mod.pm") =~ s/::/\//g;
 203     fail sprintf (
 204       "Expected DBIC core dependency '%s' never loaded - %s needs adjustment",
 205       $mod,
 206       __FILE__
 207     ) unless $INC{$modfn};
 208   }
 209   pass(sprintf 'All modules expected at %s line %s loaded by DBIC: %s',
 210     __FILE__,
 211     (caller(0))[2],
 212     join (', ', sort keys %$expected_dbic_deps ),
 213   ) unless $nl;
 214 }