xt/extra/lean_startup.t

   1 # Use a require override instead of @INC munging (less common)
   2 # Do the override as early as possible so that CORE::require doesn't get compiled away
   3
   4 my ($initial_inc_contents, $expected_dbic_deps, $require_sites);
   5 BEGIN {
   6   # these envvars *will* bring in more stuff than the baseline
   7   delete @ENV{qw(DBICTEST_SQLT_DEPLOY DBIC_TRACE)};
   8
   9   # make sure extras do not load even when this is set
  10   $ENV{PERL_STRICTURES_EXTRA} = 1;
  11
  12   unshift @INC, 't/lib';
  13   require DBICTest::Util::OverrideRequire;
  14
  15   DBICTest::Util::OverrideRequire::override_global_require( sub {
  16     my $res = $_[0]->();
  17
  18     my $req = $_[1];
  19     $req =~ s/\.pm$//;
  20     $req =~ s/\//::/g;
  21
  22     my $up = 0;
  23     my @caller;
  24     do { @caller = caller($up++) } while (
  25       @caller and (
  26         # exclude our test suite, known "module require-rs" and eval frames
  27         $caller[1] =~ /^ t [\/\\] /x
  28           or
  29         $caller[0] =~ /^ (?: base | parent | Class::C3::Componentised | Module::Inspector | Module::Runtime ) $/x
  30           or
  31         $caller[3] eq '(eval)',
  32       )
  33     );
  34
  35     push @{$require_sites->{$req}}, "$caller[1] line $caller[2]"
  36       if @caller;
  37
  38     return $res if $req =~ /^DBIx::Class|^DBICTest::/;
  39
  40     # exclude everything where the current namespace does not match the called function
  41     # (this works around very weird XS-induced require callstack corruption)
  42     if (
  43       !$initial_inc_contents->{$req}
  44         and
  45       !$expected_dbic_deps->{$req}
  46         and
  47       @caller
  48         and
  49       $caller[0] =~ /^DBIx::Class/
  50         and
  51       (caller($up))[3] =~ /\Q$caller[0]/
  52     ) {
  53       CORE::require('Test/More.pm');
  54       Test::More::fail ("Unexpected require of '$req' by $caller[0] ($caller[1] line $caller[2])");
  55
  56       if ( $ENV{TEST_VERBOSE} or ! DBICTest::RunMode->is_plain ) {
  57         CORE::require('DBICTest/Util.pm');
  58         Test::More::diag( 'Require invoked' .  DBICTest::Util::stacktrace() );
  59       }
  60     }
  61
  62     return $res;
  63   });
  64 }
  65
  66 use strict;
  67 use warnings;
  68 use Test::More;
  69
  70 BEGIN {
  71   plan skip_all => 'A defined PERL5OPT may inject extra deps crashing this test'
  72     if $ENV{PERL5OPT};
  73
  74   plan skip_all => 'Dependency load patterns are radically different before perl 5.10'
  75     if "$]" < 5.010;
  76
  77   # add what we loaded so far
  78   for (keys %INC) {
  79     my $mod = $_;
  80     $mod =~ s/\.pm$//;
  81     $mod =~ s!\/!::!g;
  82     $initial_inc_contents->{$mod} = 1;
  83   }
  84 }
  85
  86 BEGIN { $ENV{DBICTEST_VIA_REPLICATED} = 0 }
  87
  88 #######
  89 ### This is where the test starts
  90 #######
  91
  92 # checking base schema load, no storage no connection
  93 {
  94   register_lazy_loadable_requires(qw(
  95     B
  96     constant
  97     overload
  98
  99     base
 100     Devel::GlobalDestruction
 101     mro
 102
 103     Carp
 104     namespace::clean
 105     Try::Tiny
 106     Sub::Name
 107     Sub::Defer
 108     Sub::Quote
 109
 110     Scalar::Util
 111     List::Util
 112     Storable
 113
 114     Class::Accessor::Grouped
 115     Class::C3::Componentised
 116     SQL::Abstract
 117   ));
 118
 119   require DBICTest::Schema;
 120   assert_no_missing_expected_requires();
 121 }
 122
 123 # check schema/storage instantiation with no connect
 124 {
 125   register_lazy_loadable_requires(qw(
 126     Moo
 127     Moo::Object
 128     Method::Generate::Accessor
 129     Method::Generate::Constructor
 130     Context::Preserve
 131   ));
 132
 133   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 134   ok (! $s->storage->connected, 'no connection');
 135   assert_no_missing_expected_requires();
 136 }
 137
 138 # do something (deploy, insert)
 139 {
 140   register_lazy_loadable_requires(qw(
 141     DBI
 142     Hash::Merge
 143   ));
 144
 145   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 146   $s->storage->dbh_do(sub {
 147     $_[1]->do('CREATE TABLE artist (
 148       "artistid" INTEGER PRIMARY KEY NOT NULL,
 149       "name" varchar(100),
 150       "rank" integer NOT NULL DEFAULT 13,
 151       "charfield" char(10)
 152     )');
 153   });
 154
 155   my $art = $s->resultset('Artist')->create({ name => \[ '?' => 'foo'], rank => 42 });
 156   $art->discard_changes;
 157   $art->update({ rank => 69, name => 'foo' });
 158   assert_no_missing_expected_requires();
 159 }
 160
 161 # and do full populate() as well, just in case - shouldn't add new stuff
 162 {
 163   local $ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER};
 164   {
 165     # in general we do not want DBICTest to load before sqla, but it is
 166     # ok to cheat here
 167     local $INC{'SQL/Abstract.pm'};
 168     require DBICTest;
 169   }
 170   my $s = DBICTest->init_schema;
 171   is ($s->resultset('Artist')->find(1)->name, 'Caterwauler McCrae');
 172   assert_no_missing_expected_requires();
 173 }
 174
 175 done_testing;
 176
 177 sub register_lazy_loadable_requires {
 178   local $Test::Builder::Level = $Test::Builder::Level + 1;
 179
 180   for my $mod (@_) {
 181     (my $modfn = "$mod.pm") =~ s!::!\/!g;
 182     fail(join "\n",
 183       "Module $mod already loaded by require site(s):",
 184       (map { "\t$_" } @{$require_sites->{$mod}}),
 185       '',
 186     ) if $INC{$modfn} and !$initial_inc_contents->{$mod};
 187
 188     $expected_dbic_deps->{$mod}++
 189   }
 190 }
 191
 192 # check if anything we were expecting didn't actually load
 193 sub assert_no_missing_expected_requires {
 194   my $nl;
 195   for my $mod (keys %$expected_dbic_deps) {
 196     (my $modfn = "$mod.pm") =~ s/::/\//g;
 197     unless ($INC{$modfn}) {
 198       my $err = sprintf "Expected DBIC core dependency '%s' never loaded - %s needs adjustment", $mod, __FILE__;
 199       if (DBICTest::RunMode->is_smoker or DBICTest::RunMode->is_author) {
 200         fail ($err)
 201       }
 202       else {
 203         diag "\n" unless $nl->{$mod}++;
 204         diag $err;
 205       }
 206     }
 207   }
 208   pass(sprintf 'All modules expected at %s line %s loaded by DBIC: %s',
 209     __FILE__,
 210     (caller(0))[2],
 211     join (', ', sort keys %$expected_dbic_deps ),
 212   ) unless $nl;
 213 }