xt/extra/lean_startup.t

   1 # Use a require override instead of @INC munging (less common)
   2 # Do the override as early as possible so that CORE::require doesn't get compiled away
   3
   4 my ($initial_inc_contents, $expected_dbic_deps, $require_sites);
   5 BEGIN {
   6   # these envvars *will* bring in more stuff than the baseline
   7   delete @ENV{qw(DBICTEST_SQLT_DEPLOY DBIC_TRACE)};
   8
   9   # make sure extras do not load even when this is set
  10   $ENV{PERL_STRICTURES_EXTRA} = 1;
  11
  12   unshift @INC, 't/lib';
  13   require DBICTest::Util::OverrideRequire;
  14
  15   DBICTest::Util::OverrideRequire::override_global_require( sub {
  16     my $res = $_[0]->();
  17
  18     my $req = $_[1];
  19     $req =~ s/\.pm$//;
  20     $req =~ s/\//::/g;
  21
  22     my $up = 0;
  23     my @caller;
  24     do { @caller = caller($up++) } while (
  25       @caller and (
  26         # exclude our test suite, known "module require-rs" and eval frames
  27         $caller[1] =~ /^ t [\/\\] /x
  28           or
  29         $caller[0] =~ /^ (?: base | parent | Class::C3::Componentised | Module::Inspector | Module::Runtime ) $/x
  30           or
  31         $caller[3] eq '(eval)',
  32       )
  33     );
  34
  35     push @{$require_sites->{$req}}, "$caller[1] line $caller[2]"
  36       if @caller;
  37
  38     return $res if $req =~ /^DBIx::Class|^DBICTest::/;
  39
  40     # exclude everything where the current namespace does not match the called function
  41     # (this works around very weird XS-induced require callstack corruption)
  42     if (
  43       !$initial_inc_contents->{$req}
  44         and
  45       !$expected_dbic_deps->{$req}
  46         and
  47       @caller
  48         and
  49       $caller[0] =~ /^DBIx::Class/
  50         and
  51       (caller($up))[3] =~ /\Q$caller[0]/
  52     ) {
  53       CORE::require('Test/More.pm');
  54       Test::More::fail ("Unexpected require of '$req' by $caller[0] ($caller[1] line $caller[2])");
  55
  56       if ( $ENV{TEST_VERBOSE} or ! DBICTest::RunMode->is_plain ) {
  57         CORE::require('DBICTest/Util.pm');
  58         Test::More::diag( 'Require invoked' .  DBICTest::Util::stacktrace() );
  59       }
  60     }
  61
  62     return $res;
  63   });
  64 }
  65
  66 use strict;
  67 use warnings;
  68 use Test::More;
  69
  70 BEGIN {
  71   plan skip_all => 'A defined PERL5OPT may inject extra deps crashing this test'
  72     if $ENV{PERL5OPT};
  73
  74   plan skip_all => 'Dependency load patterns are radically different before perl 5.10'
  75     if "$]" < 5.010;
  76
  77   # add what we loaded so far
  78   for (keys %INC) {
  79     my $mod = $_;
  80     $mod =~ s/\.pm$//;
  81     $mod =~ s!\/!::!g;
  82     $initial_inc_contents->{$mod} = 1;
  83   }
  84 }
  85
  86 BEGIN {
  87   delete $ENV{$_} for qw(
  88     DBICTEST_VIA_REPLICATED
  89     DBICTEST_DEBUG_CONCURRENCY_LOCKS
  90   );
  91 }
  92
  93 #######
  94 ### This is where the test starts
  95 #######
  96
  97 # checking base schema load, no storage no connection
  98 {
  99   register_lazy_loadable_requires(qw(
 100     B
 101     constant
 102     overload
 103
 104     base
 105     Devel::GlobalDestruction
 106     mro
 107
 108     Carp
 109     namespace::clean
 110     Try::Tiny
 111     Sub::Name
 112     Sub::Defer
 113     Sub::Quote
 114
 115     Scalar::Util
 116     List::Util
 117     Storable
 118
 119     Class::Accessor::Grouped
 120     Class::C3::Componentised
 121     SQL::Abstract
 122   ));
 123
 124   require DBICTest::Schema;
 125   assert_no_missing_expected_requires();
 126 }
 127
 128 # check schema/storage instantiation with no connect
 129 {
 130   register_lazy_loadable_requires(qw(
 131     Moo
 132     Moo::Object
 133     Method::Generate::Accessor
 134     Method::Generate::Constructor
 135     Context::Preserve
 136   ));
 137
 138   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 139   ok (! $s->storage->connected, 'no connection');
 140   assert_no_missing_expected_requires();
 141 }
 142
 143 # do something (deploy, insert)
 144 {
 145   register_lazy_loadable_requires(qw(
 146     DBI
 147     Hash::Merge
 148   ));
 149
 150   my $s = DBICTest::Schema->connect('dbi:SQLite::memory:');
 151   $s->storage->dbh_do(sub {
 152     $_[1]->do('CREATE TABLE artist (
 153       "artistid" INTEGER PRIMARY KEY NOT NULL,
 154       "name" varchar(100),
 155       "rank" integer NOT NULL DEFAULT 13,
 156       "charfield" char(10)
 157     )');
 158   });
 159
 160   my $art = $s->resultset('Artist')->create({ name => \[ '?' => 'foo'], rank => 42 });
 161   $art->discard_changes;
 162   $art->update({ rank => 69, name => 'foo' });
 163   assert_no_missing_expected_requires();
 164 }
 165
 166 # and do full populate() as well, just in case - shouldn't add new stuff
 167 {
 168   local $ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER};
 169   {
 170     # in general we do not want DBICTest to load before sqla, but it is
 171     # ok to cheat here
 172     local $INC{'SQL/Abstract.pm'};
 173     require DBICTest;
 174   }
 175   my $s = DBICTest->init_schema;
 176   is ($s->resultset('Artist')->find(1)->name, 'Caterwauler McCrae');
 177   assert_no_missing_expected_requires();
 178 }
 179
 180 done_testing;
 181
 182 sub register_lazy_loadable_requires {
 183   local $Test::Builder::Level = $Test::Builder::Level + 1;
 184
 185   for my $mod (@_) {
 186     (my $modfn = "$mod.pm") =~ s!::!\/!g;
 187     fail(join "\n",
 188       "Module $mod already loaded by require site(s):",
 189       (map { "\t$_" } @{$require_sites->{$mod}}),
 190       '',
 191     ) if $INC{$modfn} and !$initial_inc_contents->{$mod};
 192
 193     $expected_dbic_deps->{$mod}++
 194   }
 195 }
 196
 197 # check if anything we were expecting didn't actually load
 198 sub assert_no_missing_expected_requires {
 199   my $nl;
 200   for my $mod (keys %$expected_dbic_deps) {
 201     (my $modfn = "$mod.pm") =~ s/::/\//g;
 202     unless ($INC{$modfn}) {
 203       my $err = sprintf "Expected DBIC core dependency '%s' never loaded - %s needs adjustment", $mod, __FILE__;
 204       if (DBICTest::RunMode->is_smoker or DBICTest::RunMode->is_author) {
 205         fail ($err)
 206       }
 207       else {
 208         diag "\n" unless $nl->{$mod}++;
 209         diag $err;
 210       }
 211     }
 212   }
 213   pass(sprintf 'All modules expected at %s line %s loaded by DBIC: %s',
 214     __FILE__,
 215     (caller(0))[2],
 216     join (', ', sort keys %$expected_dbic_deps ),
 217   ) unless $nl;
 218 }