xt/extra/lean_startup.t

   1 # Use a require override instead of @INC munging (less common)
   2 # Do the override as early as possible so that CORE::require doesn't get compiled away
   3
   4 BEGIN {
   5   if ( $ENV{RELEASE_TESTING} ) {
   6     require warnings and warnings->import;
   7     require strict and strict->import;
   8   }
   9 }
  10
  11 my ($initial_inc_contents, $expected_dbic_deps, $require_sites, %stack);
  12 BEGIN {
  13   unshift @INC, 't/lib';
  14   require DBICTest::Util::OverrideRequire;
  15
  16   DBICTest::Util::OverrideRequire::override_global_require( sub {
  17     my $res = $_[0]->();
  18
  19     return $res if $stack{neutralize_override};
  20
  21     my $req = $_[1];
  22     $req =~ s/\.pm$//;
  23     $req =~ s/\//::/g;
  24
  25     my $up = 0;
  26     my @caller;
  27     do { @caller = CORE::caller($up++) } while (
  28       @caller and (
  29         # exclude our test suite, known "module require-rs" and eval frames
  30         $caller[1] =~ / (?: \A | [\/\\] ) x?t [\/\\] /x
  31           or
  32         $caller[0] =~ /^ (?: base | parent | Class::C3::Componentised | Module::Inspector | Module::Runtime ) $/x
  33           or
  34         $caller[3] eq '(eval)',
  35       )
  36     );
  37
  38     push @{$require_sites->{$req}}, "$caller[1] line $caller[2]"
  39       if @caller;
  40
  41     return $res if $req =~ /^DBIx::Class|^DBICTest::/;
  42
  43     # FIXME - work around RT#114641
  44     #
  45     # Because *OF COURSE* when (questionable) unicode tests fail on < 5.8
  46     # the answer is to make the entire module 5.8 only, instead of skipping
  47     # the tests in question
  48     # rjbs-- # thinly veiled passive aggressive bullshit
  49     #
  50     # The actual skip is needed because the use happens before 'package' had
  51     # a chance to switch the namespace, so the shim thinks DBIC::Schema tried
  52     # to require this
  53     return $res if $req eq '5.008';
  54
  55     # exclude everything where the current namespace does not match the called function
  56     # (this works around very weird XS-induced require callstack corruption)
  57     if (
  58       !$initial_inc_contents->{$req}
  59         and
  60       !$expected_dbic_deps->{$req}
  61         and
  62       @caller
  63         and
  64       $caller[0] =~ /^DBIx::Class/
  65         and
  66       (CORE::caller($up))[3] =~ /\Q$caller[0]/
  67     ) {
  68       local $stack{neutralize_override} = 1;
  69
  70       do 1 while CORE::caller(++$up);
  71
  72       require('Test/More.pm');
  73       local $Test::Builder::Level = $up + 1;
  74       Test::More::fail ("Unexpected require of '$req' by $caller[0] ($caller[1] line $caller[2])");
  75
  76       require('DBICTest/Util.pm');
  77       Test::More::diag( 'Require invoked' .  DBICTest::Util::stacktrace() );
  78     }
  79
  80     return $res;
  81   });
  82 }
  83
  84 use strict;
  85 use warnings;
  86 use Test::More;
  87
  88 BEGIN {
  89   plan skip_all => 'A defined PERL5OPT may inject extra deps crashing this test'
  90     if $ENV{PERL5OPT};
  91
  92   plan skip_all => 'Presence of sitecustomize.pl may inject extra deps crashing this test'
  93     if grep { $_ =~ m| \/ sitecustomize\.pl $ |x } keys %INC;
  94
  95   plan skip_all => 'Dependency load patterns are radically different before perl 5.10'
  96     if "$]" < 5.010;
  97
  98   # these envvars *will* bring in more stuff than the baseline
  99   delete @ENV{qw(
 100     DBIC_TRACE
 101     DBICTEST_SQLT_DEPLOY
 102     DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER
 103     DBICTEST_VIA_REPLICATED
 104     DBICTEST_DEBUG_CONCURRENCY_LOCKS
 105   )};
 106
 107   $ENV{DBICTEST_ANFANG_DEFANG} = 1;
 108
 109   # make sure extras do not load even when this is set
 110   $ENV{PERL_STRICTURES_EXTRA} = 1;
 111
 112   # add what we loaded so far
 113   for (keys %INC) {
 114     my $mod = $_;
 115     $mod =~ s/\.pm$//;
 116     $mod =~ s!\/!::!g;
 117     $initial_inc_contents->{$mod} = 1;
 118   }
 119 }
 120
 121
 122 #######
 123 ### This is where the test starts
 124 #######
 125
 126 # checking base schema load, no storage no connection
 127 {
 128   register_lazy_loadable_requires(qw(
 129     B
 130     constant
 131     overload
 132
 133     base
 134     Devel::GlobalDestruction
 135     mro
 136
 137     Carp
 138     namespace::clean
 139     Try::Tiny
 140     Sub::Name
 141     Sub::Defer
 142     Sub::Quote
 143
 144     Scalar::Util
 145     List::Util
 146     Storable
 147
 148     Class::Accessor::Grouped
 149     Class::C3::Componentised
 150   ));
 151
 152   require DBIx::Class::Schema;
 153   assert_no_missing_expected_requires();
 154 }
 155
 156 # check schema/storage instantiation with no connect
 157 {
 158   register_lazy_loadable_requires(qw(
 159     Moo
 160     Moo::Object
 161     Method::Generate::Accessor
 162     Method::Generate::Constructor
 163     Context::Preserve
 164     SQL::Abstract
 165   ));
 166
 167   my $s = DBIx::Class::Schema->connect('dbi:SQLite::memory:');
 168   ok (! $s->storage->connected, 'no connection');
 169   assert_no_missing_expected_requires();
 170 }
 171
 172 # do something (deploy, insert)
 173 {
 174   register_lazy_loadable_requires(qw(
 175     DBI
 176     Hash::Merge
 177   ));
 178
 179   {
 180     eval <<'EOP' or die $@;
 181
 182   package DBICTest::Result::Artist;
 183
 184   use warnings;
 185   use strict;
 186
 187   use base 'DBIx::Class::Core';
 188
 189   __PACKAGE__->table("artist");
 190
 191   __PACKAGE__->add_columns(
 192     artistid => {
 193       data_type => 'integer',
 194       is_auto_increment => 1,
 195     },
 196     name => {
 197       data_type => 'varchar',
 198       size      => 100,
 199       is_nullable => 1,
 200     },
 201     rank => {
 202       data_type => 'integer',
 203       default_value => 13,
 204     },
 205     charfield => {
 206       data_type => 'char',
 207       size => 10,
 208       is_nullable => 1,
 209     },
 210   );
 211
 212   __PACKAGE__->set_primary_key('artistid');
 213   __PACKAGE__->add_unique_constraint(['name']);
 214   __PACKAGE__->add_unique_constraint(u_nullable => [qw/charfield rank/]);
 215
 216   1;
 217
 218 EOP
 219   }
 220
 221   my $s = DBIx::Class::Schema->connect('dbi:SQLite::memory:');
 222
 223   $s->register_class( Artist => 'DBICTest::Result::Artist' );
 224
 225   $s->storage->dbh_do(sub {
 226     $_[1]->do('CREATE TABLE artist (
 227       "artistid" INTEGER PRIMARY KEY NOT NULL,
 228       "name" varchar(100),
 229       "rank" integer NOT NULL DEFAULT 13,
 230       "charfield" char(10)
 231     )');
 232   });
 233
 234   my $art = $s->resultset('Artist')->create({ name => \[ '?' => 'foo'], rank => 42 });
 235   $art->discard_changes;
 236   $art->update({ rank => 69, name => 'foo' });
 237   assert_no_missing_expected_requires();
 238 }
 239
 240
 241 # and do full DBICTest based populate() as well, just in case - shouldn't add new stuff
 242 {
 243   # DBICTest needs File::Spec, but older versions of Storable load it alread
 244   # Instead of adding a contrived conditional, just preempt the testing entirely
 245   require File::Spec;
 246
 247   require DBICTest;
 248   DBICTest->import;
 249
 250   my $s = DBICTest->init_schema;
 251   is ($s->resultset('Artist')->find(1)->name, 'Caterwauler McCrae', 'Expected find() result');
 252 }
 253
 254 done_testing;
 255 # one final quiet guard to run at all times
 256 END { assert_no_missing_expected_requires('quiet') };
 257
 258 sub register_lazy_loadable_requires {
 259   local $Test::Builder::Level = $Test::Builder::Level + 1;
 260
 261   for my $mod (@_) {
 262     (my $modfn = "$mod.pm") =~ s!::!\/!g;
 263     fail(join "\n",
 264       "Module $mod already loaded by require site(s):",
 265       (map { "\t$_" } @{$require_sites->{$mod}}),
 266       '',
 267     ) if $INC{$modfn} and !$initial_inc_contents->{$mod};
 268
 269     $expected_dbic_deps->{$mod}++
 270   }
 271 }
 272
 273 # check if anything we were expecting didn't actually load
 274 sub assert_no_missing_expected_requires {
 275   my $quiet = shift;
 276
 277   for my $mod (keys %$expected_dbic_deps) {
 278     (my $modfn = "$mod.pm") =~ s/::/\//g;
 279     fail sprintf (
 280       "Expected DBIC core dependency '%s' never loaded - %s needs adjustment",
 281       $mod,
 282       __FILE__
 283     ) unless $INC{$modfn};
 284   }
 285
 286   pass(sprintf 'All modules expected at %s line %s loaded by DBIC: %s',
 287     __FILE__,
 288     (caller(0))[2],
 289     join (', ', sort keys %$expected_dbic_deps ),
 290   ) unless $quiet;
 291 }