xt/extra/internals/sqla_condition_parsers.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Test::Warn;
   7 use Test::Exception;
   8
   9
  10 use DBICTest ':DiffSQL';
  11 use DBIx::Class::_Util qw( UNRESOLVABLE_CONDITION dump_value );
  12 use DBIx::Class::SQLMaker::Util qw( normalize_sqla_condition extract_equality_conditions );
  13
  14 BEGIN {
  15   if ( eval { require Test::Differences } ) {
  16     no warnings 'redefine';
  17     *is_deeply = \&Test::Differences::eq_or_diff;
  18   }
  19 }
  20
  21 my $sm = DBICTest->init_schema( no_deploy => 1)->storage->sql_maker;
  22
  23 {
  24   package # hideee
  25     DBICTest::SillyInt;
  26
  27   use overload
  28     fallback => 1,
  29     '0+' => sub { ${$_[0]} },
  30   ;
  31 }
  32 my $num = bless( \do { my $foo = 69 }, 'DBICTest::SillyInt' );
  33
  34 is($num, 69, 'test overloaded object is "sane"');
  35 is("$num", 69, 'test overloaded object is "sane"');
  36
  37 my @tests = (
  38   {
  39     where => { artistid => 1, charfield => undef },
  40     normalized => { artistid => 1, charfield => undef },
  41     sql => 'WHERE artistid = ? AND charfield IS NULL',
  42     equality_extract => { artistid => 1 },
  43     equality_considering_nulls_extract => { artistid => 1, charfield => undef },
  44   },
  45   {
  46     where => { -and => [ artistid => 1, charfield => undef, { rank => 13 } ] },
  47     normalized => { artistid => 1, charfield => undef, rank => 13 },
  48     sql => 'WHERE artistid = ?  AND charfield IS NULL AND rank = ?',
  49     equality_extract => { artistid => 1, rank => 13 },
  50     equality_considering_nulls_extract => { artistid => 1, charfield => undef, rank => 13 },
  51   },
  52   {
  53     where => { -and => [ { artistid => 1, charfield => undef}, { rank => 13 } ] },
  54     normalized => { artistid => 1, charfield => undef, rank => 13 },
  55     sql => 'WHERE artistid = ?  AND charfield IS NULL AND rank = ?',
  56     equality_extract => { artistid => 1, rank => 13 },
  57     equality_considering_nulls_extract => { artistid => 1, charfield => undef, rank => 13 },
  58   },
  59   {
  60     where => { -and => [ -or => { name => 'Caterwauler McCrae' }, 'rank' ] },
  61     normalized => { name => 'Caterwauler McCrae', rank => undef },
  62     sql => 'WHERE name = ? AND rank IS NULL',
  63     equality_extract => { name => 'Caterwauler McCrae' },
  64     equality_considering_nulls_extract => { name => 'Caterwauler McCrae', rank => undef },
  65   },
  66   {
  67     where => { -and => [ [ [ artist => {'=' => \'foo' } ] ], { name => \[ '= ?', 'bar' ] } ] },
  68     normalized => { artist => {'=' => \'foo' }, name => \[ '= ?', 'bar' ] },
  69     sql => 'WHERE artist = foo AND name = ?',
  70     equality_extract => { artist => \'foo' },
  71   },
  72   {
  73     where => { -and => [ -or => { name => 'Caterwauler McCrae', artistid => 2 } ] },
  74     normalized => { -or => [ artistid => 2, name => 'Caterwauler McCrae' ] },
  75     sql => 'WHERE artistid = ? OR name = ?',
  76     equality_extract => {},
  77   },
  78   {
  79     where => { -or => { name => 'Caterwauler McCrae', artistid => 2 } },
  80     normalized => { -or => [ artistid => 2, name => 'Caterwauler McCrae' ] },
  81     sql => 'WHERE artistid = ? OR name = ?',
  82     equality_extract => {},
  83   },
  84   {
  85     where => { -and => [ \'foo=bar',  [ { artistid => { '=', $num } } ], { name => 'Caterwauler McCrae'} ] },
  86     normalized => { -and => [ \'foo=bar' ], name => 'Caterwauler McCrae', artistid => $num },
  87     sql => 'WHERE foo=bar AND artistid = ? AND name = ?',
  88     equality_extract => { name => 'Caterwauler McCrae', artistid => $num },
  89   },
  90   {
  91     where => { -and => [ \'foo=bar',  [ { artistid => { '=', $num } } ], { name => 'Caterwauler McCrae'}, \'buzz=bozz' ] },
  92     normalized => { -and => [ \'foo=bar', \'buzz=bozz' ], name => 'Caterwauler McCrae', artistid => $num },
  93     sql =>            'WHERE foo=bar AND artistid = ? AND name = ? AND buzz=bozz',
  94     normalized_sql => 'WHERE foo=bar AND buzz=bozz AND artistid = ? AND name = ?',
  95     equality_extract => { name => 'Caterwauler McCrae', artistid => $num },
  96   },
  97   {
  98     where => { artistid => [ $num ], rank => [ 13, 2, 3 ], charfield => [ undef ] },
  99     normalized => { artistid => $num, charfield => undef, rank => [13, 2, 3] },
 100     sql => 'WHERE artistid = ? AND charfield IS NULL AND ( rank = ? OR rank = ? OR rank = ? )',
 101     equality_extract => { artistid => $num },
 102     equality_considering_nulls_extract => { artistid => $num, charfield => undef },
 103   },
 104   {
 105     where => { artistid => { '=' => 1 }, rank => { '>' => 12 }, charfield => { '=' => undef } },
 106     normalized => { artistid => 1, charfield => undef, rank => { '>' => 12 } },
 107     sql => 'WHERE artistid = ? AND charfield IS NULL AND rank > ?',
 108     equality_extract => { artistid => 1 },
 109     equality_considering_nulls_extract => { artistid => 1, charfield => undef },
 110   },
 111   {
 112     where => { artistid => { '=' => [ 1 ], }, charfield => { '=' => [ -AND => \'1', \['?',2] ] }, rank => { '=' => [ -OR => $num, $num ] } },
 113     normalized => { artistid => 1, charfield => [-and => { '=' => \['?',2] }, { '=' => \'1' } ], rank => { '=' => [$num, $num] } },
 114     sql =>            'WHERE artistid = ? AND charfield = 1 AND charfield = ? AND ( rank = ? OR rank = ? )',
 115     normalized_sql => 'WHERE artistid = ? AND charfield = ? AND charfield = 1 AND ( rank = ? OR rank = ? )',
 116     equality_extract => { artistid => 1, charfield => UNRESOLVABLE_CONDITION },
 117   },
 118   {
 119     where => { -and => [ artistid => 1, artistid => 2 ], name => [ -and => { '!=', 1 }, 2 ], charfield => [ -or => { '=', 2 } ], rank => [-and => undef, { '=', undef }, { '!=', 2 } ] },
 120     normalized => { artistid => [ -and => 1, 2 ], name => [ -and => { '!=', 1 }, 2 ], charfield => 2, rank => [ -and => { '!=', 2 }, undef ] },
 121     sql =>            'WHERE artistid = ? AND artistid = ? AND charfield = ? AND name != ? AND name = ? AND rank IS NULL AND rank IS NULL AND rank != ?',
 122     normalized_sql => 'WHERE artistid = ? AND artistid = ? AND charfield = ? AND name != ? AND name = ? AND rank != ? AND rank IS NULL',
 123     equality_extract => {
 124       artistid => UNRESOLVABLE_CONDITION,
 125       name => 2,
 126       charfield => 2,
 127     },
 128     equality_considering_nulls_extract => {
 129       artistid => UNRESOLVABLE_CONDITION,
 130       name => 2,
 131       charfield => 2,
 132       rank => undef,
 133     },
 134   },
 135   (map { {
 136     where => $_,
 137     sql =>            'WHERE (rank = 13 OR charfield IS NULL OR artistid = ?) AND (artistid = ? OR charfield IS NULL OR rank != 42)',
 138     normalized_sql => 'WHERE (artistid = ? OR charfield IS NULL OR rank = 13) AND (artistid = ? OR charfield IS NULL OR rank != 42)',
 139     normalized => { -and => [
 140       { -or => [ artistid => 1, charfield => undef, rank => { '=' => \13 } ] },
 141       { -or => [ artistid => 1, charfield => undef, rank => { '!=' => \42 } ] },
 142     ] },
 143     equality_extract => {},
 144     equality_considering_nulls_extract => {},
 145   } } (
 146
 147     { -and => [
 148       -or => [ rank => { '=' => \13 }, charfield => { '=' => undef }, artistid => 1 ],
 149       -or => { artistid => { '=' => 1 }, charfield => undef, rank => { '!=' => \42 } },
 150     ] },
 151
 152     {
 153       -OR => [ rank => { '=' => \13 }, charfield => { '=' => undef }, artistid => 1 ],
 154       -or => { artistid => { '=' => 1 }, charfield => undef, rank => { '!=' => \42 } },
 155     },
 156
 157   ) ),
 158   {
 159     where => { -or => [
 160       -and => [ foo => { '!=', { -value => undef } }, bar => { -in => [ 69, 42 ] } ],
 161       foo => { '=', { -value => undef } },
 162       baz => { '!=' => { -ident => 'bozz' } },
 163       baz => { -ident => 'buzz' },
 164     ] },
 165     sql =>            'WHERE ( foo IS NOT NULL AND bar IN ( ?, ? ) ) OR foo IS NULL OR baz != bozz OR baz = buzz',
 166     normalized_sql => 'WHERE baz != bozz OR baz = buzz OR foo IS NULL OR ( bar IN ( ?, ? ) AND foo IS NOT NULL )',
 167     normalized => { -or => [
 168       baz => { '!=' => { -ident => 'bozz' } },
 169       baz => { '=' => { -ident => 'buzz' } },
 170       foo => undef,
 171       { bar => { -in => [ 69, 42 ] }, foo => { '!=', undef } }
 172     ] },
 173     equality_extract => {},
 174   },
 175   {
 176     where => { -or => [ rank => { '=' => \13 }, charfield => { '=' => undef }, artistid => { '=' => 1 }, genreid => { '=' => \['?', 2] } ] },
 177     sql =>            'WHERE rank = 13 OR charfield IS NULL OR artistid = ? OR genreid = ?',
 178     normalized_sql => 'WHERE artistid = ? OR charfield IS NULL OR genreid = ? OR rank = 13',
 179     normalized => { -or => [ artistid => 1, charfield => undef, genreid => { '=' => \['?', 2] }, rank => { '=' => \13 } ] },
 180     equality_extract => {},
 181     equality_considering_nulls_extract => {},
 182   },
 183   {
 184     where => { -and => [
 185       -or => [ rank => { '=' => \13 }, charfield => { '=' => undef }, artistid => 1 ],
 186       -or => { artistid => { '=' => 1 }, charfield => undef, rank => { '=' => \13 } },
 187     ] },
 188     normalized => { -and => [
 189       { -or => [ artistid => 1, charfield => undef, rank => { '=' => \13 } ] },
 190       { -or => [ artistid => 1, charfield => undef, rank => { '=' => \13 } ] },
 191     ] },
 192     sql =>            'WHERE (rank = 13 OR charfield IS NULL OR artistid = ?) AND (artistid = ? OR charfield IS NULL OR rank = 13)',
 193     normalized_sql => 'WHERE (artistid = ? OR charfield IS NULL OR rank = 13) AND (artistid = ? OR charfield IS NULL OR rank = 13)',
 194     equality_extract => {},
 195     equality_considering_nulls_extract => {},
 196   },
 197   {
 198     where => { -and => [
 199       -or => [ rank => { '=' => \13 }, charfield => { '=' => undef }, artistid => 1 ],
 200       -or => { artistid => { '=' => 1 }, charfield => undef, rank => { '!=' => \42 } },
 201       -and => [ foo => { '=' => \1 }, bar => 2 ],
 202       -and => [ foo => 3, bar => { '=' => \4 } ],
 203       -exists => \'(SELECT 1)',
 204       -exists => \'(SELECT 2)',
 205       -not => { foo => 69 },
 206       -not => { foo => 42 },
 207     ]},
 208     sql => 'WHERE
 209           ( rank = 13 OR charfield IS NULL OR artistid = ? )
 210       AND ( artistid = ? OR charfield IS NULL OR rank != 42 )
 211       AND foo = 1
 212       AND bar = ?
 213       AND foo = ?
 214       AND bar = 4
 215       AND (EXISTS (SELECT 1))
 216       AND (EXISTS (SELECT 2))
 217       AND NOT foo = ?
 218       AND NOT foo = ?
 219     ',
 220     normalized_sql => 'WHERE
 221           ( artistid = ? OR charfield IS NULL OR rank = 13 )
 222       AND ( artistid = ? OR charfield IS NULL OR rank != 42 )
 223       AND (EXISTS (SELECT 1))
 224       AND (EXISTS (SELECT 2))
 225       AND NOT foo = ?
 226       AND NOT foo = ?
 227       AND bar = 4
 228       AND bar = ?
 229       AND foo = 1
 230       AND foo = ?
 231     ',
 232     normalized => {
 233       -and => [
 234         { -or => [ artistid => 1, charfield => undef, rank => { '=' => \13 } ] },
 235         { -or => [ artistid => 1, charfield => undef, rank => { '!=' => \42 } ] },
 236         { -exists => \'(SELECT 1)' },
 237         { -exists => \'(SELECT 2)' },
 238         { -not => { foo => 69 } },
 239         { -not => { foo => 42 } },
 240       ],
 241       foo => [ -and => { '=' => \1 }, 3 ],
 242       bar => [ -and => { '=' => \4 }, 2 ],
 243     },
 244     equality_extract => {
 245       foo => UNRESOLVABLE_CONDITION,
 246       bar => UNRESOLVABLE_CONDITION,
 247     },
 248     equality_considering_nulls_extract => {
 249       foo => UNRESOLVABLE_CONDITION,
 250       bar => UNRESOLVABLE_CONDITION,
 251     },
 252   },
 253   {
 254     where => { -and => [
 255       [ '_macro.to' => { -like => '%correct%' }, '_wc_macros.to' => { -like => '%correct%' } ],
 256       { -and => [ { 'group.is_active' => 1 }, { 'me.is_active' => 1 } ] }
 257     ] },
 258     normalized => {
 259       'group.is_active' => 1,
 260       'me.is_active' => 1,
 261       -or => [
 262         '_macro.to' => { -like => '%correct%' },
 263         '_wc_macros.to' => { -like => '%correct%' },
 264       ],
 265     },
 266     sql => 'WHERE ( _macro.to LIKE ? OR _wc_macros.to LIKE ? ) AND group.is_active = ? AND me.is_active = ?',
 267     equality_extract => { 'group.is_active' => 1, 'me.is_active' => 1 },
 268   },
 269
 270   {
 271     where => { -and => [
 272       artistid => { -value => [1] },
 273       charfield => { -ident => 'foo' },
 274       name => { '=' => { -value => undef } },
 275       rank => { '=' => { -ident => 'bar' } },
 276       arrayfield => { '>' => { -value => [3,1] } },
 277     ] },
 278     normalized => {
 279       artistid => { -value => [1] },
 280       name => undef,
 281       charfield => { '=', { -ident => 'foo' } },
 282       rank => { '=' => { -ident => 'bar' } },
 283       arrayfield => { '>' => { -value => [3,1] } },
 284     },
 285     sql            => 'WHERE artistid = ? AND charfield = foo AND name IS NULL AND rank = bar AND arrayfield > ?',
 286     normalized_sql => 'WHERE arrayfield > ? AND artistid = ? AND charfield = foo AND name IS NULL AND rank = bar',
 287     equality_extract => {
 288       artistid => [1],
 289       charfield => { -ident => 'foo' },
 290       rank => { -ident => 'bar' },
 291     },
 292     equality_considering_nulls_extract => {
 293       artistid => [1],
 294       name => undef,
 295       charfield => { -ident => 'foo' },
 296       rank => { -ident => 'bar' },
 297     },
 298   },
 299
 300   {
 301     where => { artistid => [] },
 302     normalized => { artistid => [] },
 303     equality_extract => {},
 304   },
 305   (map {
 306     {
 307       where => { -and => $_ },
 308       normalized => undef,
 309       equality_extract => {},
 310       sql => '',
 311     },
 312     {
 313       where => { -or => $_ },
 314       normalized => undef,
 315       equality_extract => {},
 316       sql => '',
 317     },
 318     {
 319       where => { -or => [ foo => 1, $_ ] },
 320       normalized => { foo => 1 },
 321       equality_extract => { foo => 1 },
 322       sql => 'WHERE foo = ?',
 323     },
 324     {
 325       where => { -or => [ $_, foo => 1 ] },
 326       normalized => { foo => 1 },
 327       equality_extract => { foo => 1 },
 328       sql => 'WHERE foo = ?',
 329     },
 330     {
 331       where => { -and => [ fuu => 2, $_, foo => 1 ] },
 332       sql =>            'WHERE fuu = ? AND foo = ?',
 333       normalized_sql => 'WHERE foo = ? AND fuu = ?',
 334       normalized => { foo => 1, fuu => 2 },
 335       equality_extract => { foo => 1, fuu => 2 },
 336     },
 337   } (
 338     # bare
 339     [], {},
 340     # singles
 341     [ {} ], [ [] ],
 342     # doubles
 343     [ [], [] ], [ {}, {} ], [ [], {} ], [ {}, [] ],
 344     # tripples
 345     [ {}, [], {} ], [ [], {}, [] ]
 346   )),
 347
 348   # FIXME legacy compat crap, possibly worth undef/dieing in SQLMaker
 349   { where => { artistid => {} }, sql => '', normalized => undef, equality_extract => {}, equality_considering_nulls_extract => {} },
 350
 351   # batshit insanity, just to be thorough
 352   {
 353     where => { -and => [ [ 'artistid' ], [ -and => [ artistid => { '!=', 69 }, artistid => undef, artistid => { '=' => 200 } ]], artistid => [], { -or => [] }, { -and => [] }, [ 'charfield' ], { name => [] }, 'rank' ] },
 354     normalized => { artistid => [ -and => [], { '!=', 69 }, undef, 200  ], charfield => undef, name => [], rank => undef },
 355     sql =>            'WHERE artistid IS NULL AND artistid != ? AND artistid IS NULL AND artistid = ? AND 0=1 AND charfield IS NULL AND 0=1 AND rank IS NULL',
 356     normalized_sql => 'WHERE 0=1 AND artistid != ? AND artistid IS NULL AND artistid = ? AND charfield IS NULL AND 0=1 AND rank IS NULL',
 357     equality_extract => { artistid => UNRESOLVABLE_CONDITION },
 358     equality_considering_nulls_extract => { artistid => UNRESOLVABLE_CONDITION, charfield => undef, rank => undef },
 359   },
 360
 361   # original test from RT#93244
 362   {
 363     where => {
 364       -and => [
 365         \[
 366           "LOWER(me.title) LIKE ?",
 367           '%spoon%',
 368         ],
 369         [ { 'me.title' => 'Spoonful of bees' } ],
 370     ]},
 371     normalized => {
 372       -and => [ \[
 373         "LOWER(me.title) LIKE ?",
 374         '%spoon%',
 375       ]],
 376       'me.title' => 'Spoonful of bees',
 377     },
 378     sql => 'WHERE LOWER(me.title) LIKE ? AND me.title = ?',
 379     equality_extract => { 'me.title' => 'Spoonful of bees' },
 380   },
 381
 382   # crazy literals
 383   {
 384     where => {
 385       -or => [
 386         \'foo = bar',
 387       ],
 388     },
 389     sql => 'WHERE foo = bar',
 390     normalized => {
 391       -and => [
 392         \'foo = bar',
 393       ],
 394     },
 395     equality_extract => {},
 396   },
 397   {
 398     where => {
 399       -or => [
 400         \'foo = bar',
 401         \'baz = ber',
 402       ],
 403     },
 404     sql =>            'WHERE foo = bar OR baz = ber',
 405     normalized_sql => 'WHERE baz = ber OR foo = bar',
 406     normalized => {
 407       -or => [
 408         \'baz = ber',
 409         \'foo = bar',
 410       ],
 411     },
 412     equality_extract => {},
 413   },
 414   {
 415     where => {
 416       -and => [
 417         \'foo = bar',
 418         \'baz = ber',
 419       ],
 420     },
 421     sql => 'WHERE foo = bar AND baz = ber',
 422     normalized => {
 423       -and => [
 424         \'foo = bar',
 425         \'baz = ber',
 426       ],
 427     },
 428     equality_extract => {},
 429   },
 430   {
 431     where => {
 432       -and => [
 433         \'foo = bar',
 434         \'baz = ber',
 435         x => { -ident => 'y' },
 436       ],
 437     },
 438     sql => 'WHERE foo = bar AND baz = ber AND x = y',
 439     normalized => {
 440       -and => [
 441         \'foo = bar',
 442         \'baz = ber',
 443       ],
 444       x => { '=' => { -ident => 'y' } }
 445     },
 446     equality_extract => { x => { -ident => 'y' } },
 447   },
 448 );
 449
 450 # these die as of SQLA 1.80 - make sure we do not transform them
 451 # into something usable instead
 452 for my $lhs (undef, '', { -ident => 'foo' }, { -value => 'foo' } ) {
 453   no warnings 'uninitialized';
 454
 455   for my $w (
 456     ( map { { -or => $_ }, (ref $lhs ? () : { @$_ } ) }
 457       [ $lhs => "foo" ],
 458       [ $lhs => { "=" => "bozz" } ],
 459       [ $lhs => { "=" => \"bozz" } ],
 460       [ $lhs => { -max => \"bizz" } ],
 461     ),
 462
 463     (ref $lhs) ? () : (
 464       { -or => [ -and => { $lhs => "baz" }, bizz => "buzz" ] },
 465       { -or => [ foo => "bar", { $lhs => "baz" }, bizz => "buzz" ] },
 466       { foo => "bar", -or => { $lhs => "baz" } },
 467       { foo => "bar", -or => { $lhs => \"baz" }, bizz => "buzz" },
 468     ),
 469
 470     { foo => "bar", -and => [ $lhs => \"baz" ], bizz => "buzz" },
 471     { foo => "bar", -or => [ $lhs => \"baz" ], bizz => "buzz" },
 472
 473     { -or => [ foo => "bar", [ $lhs => \"baz" ], bizz => "buzz" ] },
 474     { -or => [ foo => "bar", $lhs => \"baz", bizz => "buzz" ] },
 475     { -or => [ foo => "bar", $lhs => \["baz"], bizz => "buzz" ] },
 476     { -or => [ $lhs => \"baz" ] },
 477     { -or => [ $lhs => \["baz"] ] },
 478
 479   ) {
 480     push @tests, {
 481       where => $w,
 482       throw => qr/
 483         \QSupplying an empty left hand side argument is not supported in \E(?:array|hash)-pairs
 484           |
 485         \QIllegal use of top-level '-\E(?:value|ident)'
 486       /x,
 487     }
 488   }
 489 }
 490
 491 # these are deprecated as of SQLA 1.79 - make sure we do not transform
 492 # them without losing the warning
 493 for my $lhs (undef, '') {
 494   for my $rhs ( \"baz", \[ "baz" ] ) {
 495     no warnings 'uninitialized';
 496
 497     my $expected_warning = qr/\QHash-pairs consisting of an empty string with a literal are deprecated/;
 498
 499     push @tests, {
 500       where => { $lhs => $rhs },
 501       normalized => { -and => [ $rhs ] },
 502       equality_extract => {},
 503       sql => 'WHERE baz',
 504       warn => $expected_warning,
 505     };
 506
 507     for my $w (
 508       { foo => "bar", -and => { $lhs => $rhs }, bizz => "buzz" },
 509       { foo => "bar", $lhs => $rhs, bizz => "buzz" },
 510     ) {
 511       push @tests, {
 512         where => $w,
 513         normalized => {
 514           -and => [ $rhs ],
 515           bizz => "buzz",
 516           foo => "bar",
 517         },
 518         equality_extract => {
 519           foo => "bar",
 520           bizz => "buzz",
 521         },
 522         sql => 'WHERE baz AND bizz = ? AND foo = ?',
 523         warn => $expected_warning,
 524       };
 525     }
 526   }
 527 }
 528
 529 # lots of extra silly tests with a false column
 530 for my $eq (
 531   \"= baz",
 532   \[ "= baz" ],
 533   { '=' => { -ident => 'baz' } },
 534   { '=' => \'baz' },
 535 ) {
 536   for my $where (
 537     { foo => "bar", -and => [ 0 => $eq ], bizz => "buzz" },
 538     { foo => "bar", -or => [ 0 => $eq ], bizz => "buzz" },
 539     { foo => "bar", -and => { 0 => $eq }, bizz => "buzz" },
 540     { foo => "bar", -or => { 0 => $eq }, bizz => "buzz" },
 541     { foo => "bar", 0 => $eq, bizz => "buzz" },
 542   ) {
 543     push @tests, {
 544       where => $where,
 545       normalized => {
 546         0 => $eq,
 547         foo => 'bar',
 548         bizz => 'buzz',
 549       },
 550       equality_extract => {
 551         foo => 'bar',
 552         bizz => 'buzz',
 553         ( ref $eq eq 'HASH' ? ( 0 => $eq->{'='} ) : () ),
 554       },
 555       sql => 'WHERE 0 = baz AND bizz = ? AND foo = ?',
 556     };
 557
 558     push @tests, {
 559       where => { -or => $where },
 560       normalized => { -or => [
 561         "0" => $eq,
 562         bizz => 'buzz',
 563         foo => 'bar',
 564       ]},
 565       equality_extract => {},
 566       sql => 'WHERE 0 = baz OR bizz = ? OR foo = ?',
 567     }
 568
 569   }
 570
 571   for my $where (
 572     [ foo => "bar", -and => [ 0 => $eq ], bizz => "buzz" ],
 573     [ foo => "bar", -or => [ 0 => $eq ], bizz => "buzz" ],
 574     [ foo => "bar", -and => { 0 => $eq }, bizz => "buzz" ],
 575     [ foo => "bar", -or => { 0 => $eq }, bizz => "buzz" ],
 576     [ foo => "bar", 0 => $eq, bizz => "buzz" ],
 577   ) {
 578     push @tests, {
 579       where => { -or => $where },
 580       normalized => { -or => [
 581         "0" => $eq,
 582         bizz => 'buzz',
 583         foo => 'bar',
 584       ]},
 585       equality_extract => {},
 586       sql =>            'WHERE foo = ? OR 0 = baz OR bizz = ?',
 587       normalized_sql => 'WHERE 0 = baz OR bizz = ? OR foo = ?',
 588     }
 589   }
 590
 591   for my $where (
 592     [ {foo => "bar"}, -and => { 0 => "baz" }, bizz => "buzz" ],
 593     [ -or => [ foo => "bar", -or => { 0 => "baz" }, bizz => "buzz" ] ],
 594   ) {
 595     push @tests, {
 596       where => { -or => $where },
 597       normalized => { -or => [
 598         "0" => 'baz',
 599         bizz => 'buzz',
 600         foo => 'bar',
 601       ]},
 602       equality_extract => {},
 603       sql =>            'WHERE foo = ? OR 0 = ? OR bizz = ?',
 604       normalized_sql => 'WHERE 0 = ? OR bizz = ? OR foo = ?',
 605     };
 606   }
 607
 608 };
 609
 610 for my $t (@tests) {
 611   for my $w (
 612     $t->{where},
 613     $t->{where},  # do it twice, make sure we didn't destory the condition
 614     [ -and => $t->{where} ],
 615     [ -AND => $t->{where} ],
 616     { -OR => [ -AND => $t->{where} ] },
 617     ( ( keys %{$t->{where}} == 1 and length( (keys %{$t->{where}})[0] ) )
 618       ? [ %{$t->{where}} ]
 619       : ()
 620     ),
 621     ( (keys %{$t->{where}} == 1 and $t->{where}{-or})
 622       ? ( ref $t->{where}{-or} eq 'HASH'
 623         ? [ map { $_ => $t->{where}{-or}{$_} } sort keys %{$t->{where}{-or}} ]
 624         : $t->{where}{-or}
 625       )
 626       : ()
 627     ),
 628   ) {
 629     die unless Test::Builder->new->is_passing;
 630
 631     my $name = do { local $Data::Dumper::Indent = 0; dump_value $w };
 632
 633     my ($normalized_cond, $normalized_cond_as_sql);
 634
 635     if ($t->{throw}) {
 636       throws_ok {
 637         $sm->where( normalize_sqla_condition($w) );
 638       } $t->{throw}, "Exception on attempted collapse/render of $name"
 639         and
 640       next;
 641     }
 642
 643     warnings_exist {
 644       $normalized_cond = normalize_sqla_condition($w);
 645       ($normalized_cond_as_sql) = $sm->where($normalized_cond);
 646     } $t->{warn} || [], "Expected warning when collapsing/rendering $name";
 647
 648     is_deeply(
 649       $normalized_cond,
 650       $t->{normalized},
 651       "Expected collapsed condition produced on $name",
 652     );
 653
 654     my ($original_sql) = do {
 655       local $SIG{__WARN__} = sub {};
 656       $sm->where($w);
 657     };
 658
 659     is_same_sql ( $original_sql, $t->{sql}, "Expected original SQL from $name" )
 660       if exists $t->{sql};
 661
 662     is_same_sql(
 663       $normalized_cond_as_sql,
 664       ( $t->{normalized_sql} || $t->{sql} || $original_sql ),
 665       "Normalization did not alter *the semantics* of the final SQL based on $name",
 666     );
 667
 668     is_deeply(
 669       extract_equality_conditions($normalized_cond),
 670       $t->{equality_extract},
 671       "Expected equality_conditions produced on $name",
 672     );
 673
 674     is_deeply(
 675       extract_equality_conditions($normalized_cond, 'consider_nulls'),
 676       ( $t->{equality_considering_nulls_extract} || $t->{equality_extract} ),
 677       "Expected equality_conditions including NULLs produced on $name",
 678     );
 679
 680     is_deeply(
 681       $normalized_cond,
 682       $t->{normalized},
 683       "Collapsed condition result unaltered by equality conditions extractor",
 684     );
 685   }
 686 }
 687
 688 # test separately
 689 is_deeply(
 690   normalize_sqla_condition( UNRESOLVABLE_CONDITION ),
 691   { -and => [ UNRESOLVABLE_CONDITION ] },
 692 );
 693
 694 done_testing;