xt/extra/internals/namespaces_cleaned.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 BEGIN {
   4   if ( "$]" < 5.010) {
   5
   6     # Pre-5.10 perls pollute %INC on unsuccesfull module
   7     # require, making it appear as if the module is already
   8     # loaded on subsequent require()s
   9     # Can't seem to find the exact RT/perldelta entry
  10     #
  11     # The reason we can't just use a sane, clean loader, is because
  12     # if a Module require()s another module the %INC will still
  13     # get filled with crap and we are back to square one. A global
  14     # fix is really the only way for this test, as we try to load
  15     # each available module separately, and have no control (nor
  16     # knowledge) over their common dependencies.
  17     #
  18     # we want to do this here, in the very beginning, before even
  19     # warnings/strict are loaded
  20
  21
  22     require DBICTest::Util::OverrideRequire;
  23
  24     DBICTest::Util::OverrideRequire::override_global_require( sub {
  25       my $res = eval { $_[0]->() };
  26       if ($@ ne '') {
  27         delete $INC{$_[1]};
  28         die $@;
  29       }
  30       return $res;
  31     } );
  32   }
  33 }
  34
  35 use strict;
  36 use warnings;
  37
  38 # FIXME This is a crock of shit, needs to go away
  39 # currently here to work around https://rt.cpan.org/Ticket/Display.html?id=74151
  40 # kill with fire when PS::XS / RT#74151 is *finally* fixed
  41 BEGIN {
  42   my $PS_provider;
  43
  44   if ( "$]" < 5.010 ) {
  45     require Package::Stash::PP;
  46     $PS_provider = 'Package::Stash::PP';
  47   }
  48   else {
  49     require Package::Stash;
  50     $PS_provider = 'Package::Stash';
  51   }
  52   eval <<"EOS" or die $@;
  53
  54 sub stash_for (\$) {
  55   $PS_provider->new(\$_[0]);
  56 }
  57 1;
  58 EOS
  59 }
  60
  61 use Test::More;
  62
  63 use DBICTest;
  64 use File::Find;
  65 use File::Spec;
  66 use B qw/svref_2object/;
  67
  68 # makes sure we can load at least something
  69 use DBIx::Class;
  70 use DBIx::Class::Carp;
  71
  72 my @modules = grep {
  73   my ($mod) = $_ =~ /(.+)/;
  74
  75   # not all modules are loadable at all times
  76   do {
  77     # trap deprecation warnings and whatnot
  78     local $SIG{__WARN__} = sub {};
  79     eval "require $mod";
  80   } ? $mod : do {
  81     SKIP: { skip "Failed require of $mod: " . ($@ =~ /^(.+?)$/m)[0], 1 };
  82     (); # empty RV for @modules
  83   };
  84
  85 } find_modules();
  86
  87 # have an exception table for old and/or weird code we are not sure
  88 # we *want* to clean in the first place
  89 my $skip_idx = { map { $_ => 1 } (
  90   'SQL::Translator::Producer::DBIx::Class::File', # too crufty to touch
  91
  92   # not sure how to handle type libraries
  93   'DBIx::Class::Storage::DBI::Replicated::Types',
  94   'DBIx::Class::Admin::Types',
  95
  96   # G::L::D is unclean, but we never inherit from it
  97   'DBIx::Class::Admin::Descriptive',
  98   'DBIx::Class::Admin::Usage',
  99
 100   # this subclass is expected to inherit whatever crap comes
 101   # from the parent
 102   'DBIx::Class::ResultSet::Pager',
 103
 104   # utility classes, not part of the inheritance chain
 105   'DBIx::Class::Optional::Dependencies',
 106   'DBIx::Class::ResultSource::RowParser::Util',
 107   'DBIx::Class::_Util',
 108 ) };
 109
 110 my $has_moose = eval { require Moose::Util };
 111
 112 my $seen; #inheritance means we will see the same method multiple times
 113
 114 for my $mod (@modules) {
 115   SKIP: {
 116     skip "$mod exempt from namespace checks",1 if $skip_idx->{$mod};
 117
 118     my %all_method_like = (map
 119       { %{stash_for($_)->get_all_symbols('CODE')} }
 120       (reverse @{mro::get_linear_isa($mod)})
 121     );
 122
 123     my %parents = map { $_ => 1 } @{mro::get_linear_isa($mod)};
 124
 125     my %roles;
 126     if ($has_moose and my $mc = Moose::Util::find_meta($mod)) {
 127       if ($mc->can('calculate_all_roles_with_inheritance')) {
 128         $roles{$_->name} = 1 for ($mc->calculate_all_roles_with_inheritance);
 129       }
 130     }
 131
 132     for my $name (keys %all_method_like) {
 133
 134       # overload is a funky thing - it is not cleaned, and its imports are named funny
 135       next if $name =~ /^\(/;
 136
 137       my $gv = svref_2object($all_method_like{$name})->GV;
 138       my $origin = $gv->STASH->NAME;
 139
 140       is ($gv->NAME, $name, "Properly named $name method at $origin" . ($origin eq $mod
 141         ? ''
 142         : " (inherited by $mod)"
 143       ));
 144
 145       next if $seen->{"${origin}:${name}"}++;
 146
 147       if ($origin eq $mod) {
 148         pass ("$name is a native $mod method");
 149       }
 150       elsif ($roles{$origin}) {
 151         pass ("${mod}::${name} came from consumption of role $origin");
 152       }
 153       elsif ($parents{$origin}) {
 154         pass ("${mod}::${name} came from proper parent-class $origin");
 155       }
 156       else {
 157         my $via;
 158         for (reverse @{mro::get_linear_isa($mod)} ) {
 159           if ( ($_->can($name)||'') eq $all_method_like{$name} ) {
 160             $via = $_;
 161             last;
 162           }
 163         }
 164
 165         # exception time
 166         if (
 167           ( $name eq 'import' and $via = 'Exporter' )
 168             or
 169           # jesus christ nobody had any idea how to design an interface back then
 170           ( $name =~ /_trigger/ and $via = 'Class::Trigger' )
 171         ) {
 172           pass("${mod}::${name} is a valid uncleaned import from ${name}");
 173         }
 174         else {
 175           fail ("${mod}::${name} appears to have entered inheritance chain by import into "
 176               . ($via || 'UNKNOWN')
 177           );
 178         }
 179       }
 180     }
 181
 182     # some common import names (these should never ever be methods)
 183     for my $f (qw/carp carp_once carp_unique croak confess cluck try catch finally/) {
 184       if ($mod->can($f)) {
 185         my $via;
 186         for (reverse @{mro::get_linear_isa($mod)} ) {
 187           if ( ($_->can($f)||'') eq $all_method_like{$f} ) {
 188             $via = $_;
 189             last;
 190           }
 191         }
 192         fail ("Import $f leaked into method list of ${mod}, appears to have entered inheritance chain at "
 193             . ($via || 'UNKNOWN')
 194         );
 195       }
 196       else {
 197         pass ("Import $f not leaked into method list of $mod");
 198       }
 199     }
 200   }
 201 }
 202
 203 sub find_modules {
 204   my @modules;
 205
 206   find( {
 207     wanted => sub {
 208       -f $_ or return;
 209       $_ =~ m|lib/DBIx/Class/_TempExtlib| and return;
 210       s/\.pm$// or return;
 211       s/^ (?: lib | blib . (?:lib|arch) ) . //x;
 212       push @modules, join ('::', File::Spec->splitdir($_));
 213     },
 214     no_chdir => 1,
 215   }, (
 216     # find them in both lib and blib, duplicates are fine, since
 217     # @INC is preadjusted for us by the harness
 218     'lib',
 219     ( -e 'blib' ? 'blib' : () ),
 220   ));
 221
 222   return sort @modules;
 223 }
 224
 225 done_testing;