xt/extra/internals/namespaces_cleaned.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 BEGIN {
   4   if ( "$]" < 5.010) {
   5
   6     # Pre-5.10 perls pollute %INC on unsuccesfull module
   7     # require, making it appear as if the module is already
   8     # loaded on subsequent require()s
   9     # Can't seem to find the exact RT/perldelta entry
  10     #
  11     # The reason we can't just use a sane, clean loader, is because
  12     # if a Module require()s another module the %INC will still
  13     # get filled with crap and we are back to square one. A global
  14     # fix is really the only way for this test, as we try to load
  15     # each available module separately, and have no control (nor
  16     # knowledge) over their common dependencies.
  17     #
  18     # we want to do this here, in the very beginning, before even
  19     # warnings/strict are loaded
  20
  21
  22     require DBICTest::Util::OverrideRequire;
  23
  24     DBICTest::Util::OverrideRequire::override_global_require( sub {
  25       my $res = eval { $_[0]->() };
  26       if ($@ ne '') {
  27         delete $INC{$_[1]};
  28         die $@;
  29       }
  30       return $res;
  31     } );
  32   }
  33 }
  34
  35 use strict;
  36 use warnings;
  37
  38 # FIXME This is a crock of shit, needs to go away
  39 # currently here to work around https://rt.cpan.org/Ticket/Display.html?id=74151
  40 # kill with fire when PS::XS / RT#74151 is *finally* fixed
  41 BEGIN {
  42   my $PS_provider;
  43
  44   if ( "$]" < 5.010 ) {
  45     require Package::Stash::PP;
  46     $PS_provider = 'Package::Stash::PP';
  47   }
  48   else {
  49     require Package::Stash;
  50     $PS_provider = 'Package::Stash';
  51   }
  52   eval <<"EOS" or die $@;
  53
  54 sub stash_for (\$) {
  55   $PS_provider->new(\$_[0]);
  56 }
  57 1;
  58 EOS
  59 }
  60
  61 use Test::More;
  62
  63 use DBICTest;
  64 use File::Find;
  65 use File::Spec;
  66 use B qw/svref_2object/;
  67
  68 # makes sure we can load at least something
  69 use DBIx::Class;
  70 use DBIx::Class::Carp;
  71
  72 my @modules = grep {
  73   my ($mod) = $_ =~ /(.+)/;
  74
  75   # not all modules are loadable at all times
  76   do {
  77     # trap deprecation warnings and whatnot
  78     local $SIG{__WARN__} = sub {};
  79     eval "require $mod";
  80   } ? $mod : do {
  81     SKIP: { skip "Failed require of $mod: " . ($@ =~ /^(.+?)$/m)[0], 1 };
  82     (); # empty RV for @modules
  83   };
  84
  85 } find_modules();
  86
  87 # have an exception table for old and/or weird code we are not sure
  88 # we *want* to clean in the first place
  89 my $skip_idx = { map { $_ => 1 } (
  90   'SQL::Translator::Producer::DBIx::Class::File', # too crufty to touch
  91
  92   # not sure how to handle type libraries
  93   'DBIx::Class::Storage::DBI::Replicated::Types',
  94   'DBIx::Class::Admin::Types',
  95
  96   # G::L::D is unclean, but we never inherit from it
  97   'DBIx::Class::Admin::Descriptive',
  98   'DBIx::Class::Admin::Usage',
  99
 100   # this subclass is expected to inherit whatever crap comes
 101   # from the parent
 102   'DBIx::Class::ResultSet::Pager',
 103
 104   # utility classes, not part of the inheritance chain
 105   'DBIx::Class::Optional::Dependencies',
 106   'DBIx::Class::ResultSource::RowParser::Util',
 107   'DBIx::Class::_Util',
 108 ) };
 109
 110 my $has_moose = eval { require Moose::Util };
 111
 112 Sub::Defer::undefer_all();
 113
 114 my $seen; #inheritance means we will see the same method multiple times
 115
 116 for my $mod (@modules) {
 117   SKIP: {
 118     skip "$mod exempt from namespace checks",1 if $skip_idx->{$mod};
 119
 120     my %all_method_like = (map
 121       { %{stash_for($_)->get_all_symbols('CODE')} }
 122       (reverse @{mro::get_linear_isa($mod)})
 123     );
 124
 125     my %parents = map { $_ => 1 } @{mro::get_linear_isa($mod)};
 126
 127     my %roles;
 128     if ($has_moose and my $mc = Moose::Util::find_meta($mod)) {
 129       if ($mc->can('calculate_all_roles_with_inheritance')) {
 130         $roles{$_->name} = 1 for ($mc->calculate_all_roles_with_inheritance);
 131       }
 132     }
 133
 134     for my $name (keys %all_method_like) {
 135
 136       # overload is a funky thing - it is not cleaned, and its imports are named funny
 137       next if $name =~ /^\(/;
 138
 139       my $gv = svref_2object($all_method_like{$name})->GV;
 140       my $origin = $gv->STASH->NAME;
 141
 142       is ($gv->NAME, $name, "Properly named $name method at $origin" . ($origin eq $mod
 143         ? ''
 144         : " (inherited by $mod)"
 145       ));
 146
 147       next if $seen->{"${origin}:${name}"}++;
 148
 149       if ($origin eq $mod) {
 150         pass ("$name is a native $mod method");
 151       }
 152       elsif ($roles{$origin}) {
 153         pass ("${mod}::${name} came from consumption of role $origin");
 154       }
 155       elsif ($parents{$origin}) {
 156         pass ("${mod}::${name} came from proper parent-class $origin");
 157       }
 158       else {
 159         my $via;
 160         for (reverse @{mro::get_linear_isa($mod)} ) {
 161           if ( ($_->can($name)||'') eq $all_method_like{$name} ) {
 162             $via = $_;
 163             last;
 164           }
 165         }
 166
 167         # exception time
 168         if (
 169           ( $name eq 'import' and $via = 'Exporter' )
 170             or
 171           # jesus christ nobody had any idea how to design an interface back then
 172           ( $name =~ /_trigger/ and $via = 'Class::Trigger' )
 173         ) {
 174           pass("${mod}::${name} is a valid uncleaned import from ${name}");
 175         }
 176         else {
 177           fail ("${mod}::${name} appears to have entered inheritance chain by import into "
 178               . ($via || 'UNKNOWN')
 179           );
 180         }
 181       }
 182     }
 183
 184     # some common import names (these should never ever be methods)
 185     for my $f (qw/carp carp_once carp_unique croak confess cluck try catch finally/) {
 186       if ($mod->can($f)) {
 187         my $via;
 188         for (reverse @{mro::get_linear_isa($mod)} ) {
 189           if ( ($_->can($f)||'') eq $all_method_like{$f} ) {
 190             $via = $_;
 191             last;
 192           }
 193         }
 194         fail ("Import $f leaked into method list of ${mod}, appears to have entered inheritance chain at "
 195             . ($via || 'UNKNOWN')
 196         );
 197       }
 198       else {
 199         pass ("Import $f not leaked into method list of $mod");
 200       }
 201     }
 202   }
 203 }
 204
 205 sub find_modules {
 206   my @modules;
 207
 208   find( {
 209     wanted => sub {
 210       -f $_ or return;
 211       s/\.pm$// or return;
 212       s/^ (?: lib | blib . (?:lib|arch) ) . //x;
 213       push @modules, join ('::', File::Spec->splitdir($_));
 214     },
 215     no_chdir => 1,
 216   }, (
 217     # find them in both lib and blib, duplicates are fine, since
 218     # @INC is preadjusted for us by the harness
 219     'lib',
 220     ( -e 'blib' ? 'blib' : () ),
 221   ));
 222
 223   return sort @modules;
 224 }
 225
 226 done_testing;