xt/extra/dbicadmin.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_admin_script';
   2
   3 use strict;
   4 use warnings;
   5
   6 BEGIN {
   7   # just in case the user env has stuff in it
   8   delete $ENV{JSON_ANY_ORDER};
   9   delete $ENV{DBICTEST_VERSION_WARNS_INDISCRIMINATELY};
  10 }
  11
  12 use Test::More;
  13 use Config;
  14 use File::Spec;
  15 use lib qw(t/lib);
  16 use DBICTest;
  17
  18 $ENV{PATH} = '';
  19 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  20
  21 my @json_backends = qw(DWIW PP JSON CPANEL XS);
  22
  23 # test the script is setting @INC properly
  24 test_exec (qw|-It/lib/testinclude --schema=DBICTestAdminInc --connect=[] --insert|);
  25 cmp_ok ( $? >> 8, '==', 70, 'Correct exit code from connecting a custom INC schema' );
  26
  27 # test that config works properly
  28 {
  29   no warnings 'qw';
  30   test_exec(qw|-It/lib/testinclude --schema=DBICTestConfig --create --connect=["klaatu","barada","nikto"]|);
  31   cmp_ok( $? >> 8, '==', 71, 'Correct schema loaded via config' ) || exit;
  32 }
  33
  34 # test that config-file works properly
  35 test_exec(qw|-It/lib/testinclude --schema=DBICTestConfig --config=t/lib/admincfgtest.json --config-stanza=Model::Gort --deploy|);
  36 cmp_ok ($? >> 8, '==', 71, 'Correct schema loaded via testconfig');
  37
  38 for my $js (@json_backends) {
  39
  40     SKIP: {
  41         eval {JSON::Any->import ($js); 1 }
  42           or skip ("JSON backend $js is not available, skip testing", 1);
  43
  44         local $ENV{JSON_ANY_ORDER} = $js;
  45         eval { test_dbicadmin () };
  46         diag $@ if $@;
  47     }
  48 }
  49
  50 done_testing();
  51
  52 sub test_dbicadmin {
  53     my $schema = DBICTest->init_schema( sqlite_use_file => 1 );  # reinit a fresh db for every run
  54
  55     my $employees = $schema->resultset('Employee');
  56
  57     test_exec( default_args(), qw|--op=insert --set={"name":"Matt"}| );
  58     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: insert count" );
  59
  60     my $employee = $employees->find(1);
  61     ok( ($employee->name() eq 'Matt'), "$ENV{JSON_ANY_ORDER}: insert valid" );
  62
  63     test_exec( default_args(), qw|--op=update --set={"name":"Trout"}| );
  64     $employee = $employees->find(1);
  65     ok( ($employee->name() eq 'Trout'), "$ENV{JSON_ANY_ORDER}: update" );
  66
  67     test_exec( default_args(), qw|--op=insert --set={"name":"Aran"}| );
  68
  69     SKIP: {
  70         skip ("MSWin32 doesn't support -|", 1) if $^O eq 'MSWin32';
  71
  72         my ($perl) = $^X =~ /(.*)/;
  73
  74         open(my $fh, "-|",  ( $perl, '-MDBICTest::RunMode', 'script/dbicadmin', default_args(), qw|--op=select --attrs={"order_by":"name"}| ) ) or die $!;
  75         my $data = do { local $/; <$fh> };
  76         close($fh);
  77         if (!ok( ($data=~/Aran.*Trout/s), "$ENV{JSON_ANY_ORDER}: select with attrs" )) {
  78           diag ("data from select is $data")
  79         };
  80     }
  81
  82     test_exec( default_args(), qw|--op=delete --where={"name":"Trout"}| );
  83     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: delete" );
  84 }
  85
  86 sub default_args {
  87   my $dsn = JSON::Any->encode([
  88     'dbi:SQLite:dbname=' . DBICTest->_sqlite_dbfilename,
  89     '',
  90     '',
  91     { AutoCommit => 1 },
  92   ]);
  93
  94   return (
  95     qw|--quiet --schema=DBICTest::Schema --class=Employee|,
  96     qq|--connect=$dsn|,
  97     qw|--force -I testincludenoniterference|,
  98   );
  99 }
 100
 101 sub test_exec {
 102   my ($perl) = $^X =~ /(.*)/;
 103
 104   my @args = ($perl, '-MDBICTest::RunMode', File::Spec->catfile(qw(script dbicadmin)), @_);
 105
 106   if ($^O eq 'MSWin32') {
 107     require Win32::ShellQuote; # included in test optdeps
 108     @args = Win32::ShellQuote::quote_system_list(@args);
 109   }
 110
 111   system @args;
 112 }