xt/dist/postdistdir/whitespace.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_whitespace';
   3
   4 use warnings;
   5 use strict;
   6
   7 use Test::More;
   8 use File::Glob 'bsd_glob';
   9
  10 use DBICTest ':GlobalLock';
  11
  12 # FIXME - temporary workaround for RT#82032, RT#82033
  13 # also add all scripts (no extension) and some extra extensions
  14 # we want to check
  15 {
  16   no warnings 'redefine';
  17   my $is_pm = sub {
  18     $_[0] !~ /\./ || $_[0] =~ /\.(?:pm|pod|skip|bash|sql|json|proto)$/i || $_[0] =~ /::/;
  19   };
  20
  21   *Test::EOL::_is_perl_module = $is_pm;
  22   *Test::NoTabs::_is_perl_module = $is_pm;
  23 }
  24
  25 my @pl_targets = qw/t xt lib script examples maint/;
  26 Test::EOL::all_perl_files_ok({ trailing_whitespace => 1 }, @pl_targets);
  27 Test::NoTabs::all_perl_files_ok(@pl_targets);
  28
  29 # check some non-"perl files" in the root separately
  30 # start with what we want to check no matter what .gitignore says
  31 my @root_files = grep { -f $_ } qw(
  32   Changes
  33   LICENSE
  34   AUTHORS
  35   README
  36   MANIFEST
  37   META.yml
  38   META.json
  39 );
  40
  41 # if .gitignore is available - go for * and use .gitignore as a guide
  42 # of what to skip
  43 if (open(my $gi, '<', '.gitignore')) {
  44   my $skipnames;
  45   while (my $ln = <$gi>) {
  46     next if $ln =~ /^\s*$/;
  47     chomp $ln;
  48     $skipnames->{$_}++ for bsd_glob($ln);
  49   }
  50
  51   delete @{$skipnames}{@root_files};
  52
  53   @root_files = grep {
  54     ! $skipnames->{$_}
  55       and
  56     -f $_
  57   } bsd_glob('*');
  58 }
  59
  60 for my $fn (@root_files) {
  61   Test::EOL::eol_unix_ok($fn, { trailing_whitespace => 1 });
  62   Test::NoTabs::notabs_ok($fn) unless $fn eq 'MANIFEST';  # it is always tab infested
  63 }
  64
  65 # FIXME - Test::NoTabs and Test::EOL declare 'no_plan' which conflicts with done_testing
  66 # https://github.com/schwern/test-more/issues/14
  67 #done_testing;