xt/dist/postdistdir/whitespace.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_whitespace';
   3
   4 use warnings;
   5 use strict;
   6
   7 use Test::More;
   8 use File::Glob 'bsd_glob';
   9
  10 use DBICTest ':GlobalLock';
  11
  12 # FIXME - temporary workaround for RT#82032, RT#82033
  13 # also add all scripts (no extension) and some extra extensions
  14 # we want to check
  15 {
  16   no warnings 'redefine';
  17   my $is_pm = sub {
  18     $_[0] !~ /\./ || $_[0] =~ /\.(?:pm|pod|skip|bash|sql|json|proto)$/i || $_[0] =~ /::/;
  19   };
  20
  21   *Test::EOL::_is_perl_module = $is_pm;
  22   *Test::NoTabs::_is_perl_module = $is_pm;
  23 }
  24
  25 my @pl_targets = qw/t xt lib script examples maint/;
  26 Test::EOL::all_perl_files_ok({ trailing_whitespace => 1 }, @pl_targets);
  27 Test::NoTabs::all_perl_files_ok(@pl_targets);
  28
  29 # check some non-"perl files" in the root separately
  30 my @root_files = grep { -f $_ } bsd_glob('*');
  31
  32 # use .gitignore as a partial guide of what to skip
  33 if (open(my $gi, '<', '.gitignore')) {
  34   my $skipnames;
  35   while (my $ln = <$gi>) {
  36     next if $ln =~ /^\s*$/;
  37     chomp $ln;
  38     $skipnames->{$_}++ for bsd_glob($ln);
  39   }
  40
  41   # these we want to check no matter what the above says
  42   delete @{$skipnames}{qw(
  43     Changes
  44     LICENSE
  45     AUTHORS
  46     README
  47     MANIFEST
  48     META.yml
  49     META.json
  50   )};
  51
  52   @root_files = grep { ! $skipnames->{$_} } @root_files;
  53 }
  54
  55 for my $fn (@root_files) {
  56   Test::EOL::eol_unix_ok($fn, { trailing_whitespace => 1 });
  57   Test::NoTabs::notabs_ok($fn) unless $fn eq 'MANIFEST';  # it is always tab infested
  58 }
  59
  60 # FIXME - Test::NoTabs and Test::EOL declare 'no_plan' which conflicts with done_testing
  61 # https://github.com/schwern/test-more/issues/14
  62 #done_testing;