t/storage/txn_scope_guard.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Warn;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 # Test txn_scope_guard
  11 {
  12   my $schema = DBICTest->init_schema();
  13
  14   is($schema->storage->transaction_depth, 0, "Correct transaction depth");
  15   my $artist_rs = $schema->resultset('Artist');
  16
  17   my $fn = __FILE__;
  18   throws_ok {
  19    my $guard = $schema->txn_scope_guard;
  20
  21     $artist_rs->create({
  22       name => 'Death Cab for Cutie',
  23       made_up_column => 1,
  24     });
  25
  26    $guard->commit;
  27   } qr/No such column made_up_column .*? at .*?$fn line \d+/s, "Error propogated okay";
  28
  29   ok(!$artist_rs->find({name => 'Death Cab for Cutie'}), "Artist not created");
  30
  31   my $inner_exception = '';  # set in inner() below
  32   throws_ok (sub {
  33     outer($schema, 1);
  34   }, qr/$inner_exception/, "Nested exceptions propogated");
  35
  36   ok(!$artist_rs->find({name => 'Death Cab for Cutie'}), "Artist not created");
  37
  38   lives_ok (sub {
  39
  40     # this weird assignment is to stop perl <= 5.8.9 leaking $schema on nested sub{}s
  41     my $s = $schema;
  42
  43     warnings_exist ( sub {
  44       # The 0 arg says don't die, just let the scope guard go out of scope
  45       # forcing a txn_rollback to happen
  46       outer($s, 0);
  47     }, qr/A DBIx::Class::Storage::TxnScopeGuard went out of scope without explicit commit or error. Rolling back./, 'Out of scope warning detected');
  48
  49     ok(!$artist_rs->find({name => 'Death Cab for Cutie'}), "Artist not created");
  50
  51   }, 'rollback successful withot exception');
  52
  53   sub outer {
  54     my ($schema, $fatal) = @_;
  55
  56     my $guard = $schema->txn_scope_guard;
  57     $schema->resultset('Artist')->create({
  58       name => 'Death Cab for Cutie',
  59     });
  60     inner($schema, $fatal);
  61   }
  62
  63   sub inner {
  64     my ($schema, $fatal) = @_;
  65
  66     my $inner_guard = $schema->txn_scope_guard;
  67     is($schema->storage->transaction_depth, 2, "Correct transaction depth");
  68
  69     my $artist = $schema->resultset('Artist')->find({ name => 'Death Cab for Cutie' });
  70
  71     eval {
  72       $artist->cds->create({
  73         title => 'Plans',
  74         year => 2005,
  75         $fatal ? ( foo => 'bar' ) : ()
  76       });
  77     };
  78     if ($@) {
  79       # Record what got thrown so we can test it propgates out properly.
  80       $inner_exception = $@;
  81       die $@;
  82     }
  83
  84     # inner guard should commit without consequences
  85     $inner_guard->commit;
  86   }
  87 }
  88
  89 # make sure the guard does not eat exceptions
  90 {
  91   my $schema = DBICTest->init_schema;
  92
  93   no strict 'refs';
  94   no warnings 'redefine';
  95   local *{DBIx::Class::Storage::DBI::txn_rollback} = sub { die 'die die my darling' };
  96
  97   throws_ok (sub {
  98     my $guard = $schema->txn_scope_guard;
  99     $schema->resultset ('Artist')->create ({ name => 'bohhoo'});
 100
 101     # this should freak out the guard rollback
 102     # but it won't work because DBD::SQLite is buggy
 103     # instead just install a toxic rollback above
 104     #$schema->storage->_dbh( $schema->storage->_dbh->clone );
 105
 106     die 'Deliberate exception';
 107   }, qr/Deliberate exception.+Rollback failed/s);
 108
 109   # just to mask off warning since we could not disconnect above
 110   $schema->storage->_dbh->disconnect;
 111 }
 112
 113 # make sure it warns *big* on failed rollbacks
 114 {
 115   my $schema = DBICTest->init_schema();
 116
 117   no strict 'refs';
 118   no warnings 'redefine';
 119   local *{DBIx::Class::Storage::DBI::txn_rollback} = sub { die 'die die my darling' };
 120
 121 #The warn from within a DESTROY callback freaks out Test::Warn, do it old-school
 122 =begin
 123   warnings_exist (
 124     sub {
 125       my $guard = $schema->txn_scope_guard;
 126       $schema->resultset ('Artist')->create ({ name => 'bohhoo'});
 127
 128       # this should freak out the guard rollback
 129       # but it won't work because DBD::SQLite is buggy
 130       # instead just install a toxic rollback above
 131       #$schema->storage->_dbh( $schema->storage->_dbh->clone );
 132     },
 133     [
 134       qr/A DBIx::Class::Storage::TxnScopeGuard went out of scope without explicit commit or error. Rolling back./,
 135       qr/\*+ ROLLBACK FAILED\!\!\! \*+/,
 136     ],
 137     'proper warnings generated on out-of-scope+rollback failure'
 138   );
 139 =cut
 140
 141 # delete this once the above works properly (same test)
 142   my @want = (
 143     qr/A DBIx::Class::Storage::TxnScopeGuard went out of scope without explicit commit or error. Rolling back./,
 144     qr/\*+ ROLLBACK FAILED\!\!\! \*+/,
 145   );
 146
 147   my @w;
 148   local $SIG{__WARN__} = sub {
 149     if (grep {$_[0] =~ $_} (@want)) {
 150       push @w, $_[0];
 151     }
 152     else {
 153       warn $_[0];
 154     }
 155   };
 156   {
 157       my $guard = $schema->txn_scope_guard;
 158       $schema->resultset ('Artist')->create ({ name => 'bohhoo'});
 159   }
 160
 161   is (@w, 2, 'Both expected warnings found');
 162
 163   # just to mask off warning since we could not disconnect above
 164   $schema->storage->_dbh->disconnect;
 165 }
 166
 167 done_testing;