t/storage/replication.t

   1 use strict;
   2 use warnings;
   3 use lib qw(t/lib);
   4 use Test::More;
   5 use Test::Exception;
   6 use DBICTest;
   7 use List::Util 'first';
   8 use Scalar::Util 'reftype';
   9 use File::Spec;
  10 use IO::Handle;
  11
  12 BEGIN {
  13     eval "use DBIx::Class::Storage::DBI::Replicated; use Test::Moose";
  14     plan skip_all => "Deps not installed: $@" if $@;
  15 }
  16
  17 use_ok 'DBIx::Class::Storage::DBI::Replicated::Pool';
  18 use_ok 'DBIx::Class::Storage::DBI::Replicated::Balancer';
  19 use_ok 'DBIx::Class::Storage::DBI::Replicated::Replicant';
  20 use_ok 'DBIx::Class::Storage::DBI::Replicated';
  21
  22 use Moose();
  23 use MooseX::Types();
  24 diag "Using Moose version $Moose::VERSION and MooseX::Types version $MooseX::Types::VERSION";
  25
  26 =head1 HOW TO USE
  27
  28     This is a test of the replicated storage system.  This will work in one of
  29     two ways, either it was try to fake replication with a couple of SQLite DBs
  30     and creative use of copy, or if you define a couple of %ENV vars correctly
  31     will try to test those.  If you do that, it will assume the setup is properly
  32     replicating.  Your results may vary, but I have demonstrated this to work with
  33     mysql native replication.
  34
  35 =cut
  36
  37
  38 ## ----------------------------------------------------------------------------
  39 ## Build a class to hold all our required testing data and methods.
  40 ## ----------------------------------------------------------------------------
  41
  42 TESTSCHEMACLASSES: {
  43
  44     ## --------------------------------------------------------------------- ##
  45     ## Create an object to contain your replicated stuff.
  46     ## --------------------------------------------------------------------- ##
  47
  48     package DBIx::Class::DBI::Replicated::TestReplication;
  49
  50     use DBICTest;
  51     use base qw/Class::Accessor::Fast/;
  52
  53     __PACKAGE__->mk_accessors( qw/schema/ );
  54
  55     ## Initialize the object
  56
  57     sub new {
  58         my ($class, $schema_method) = (shift, shift);
  59         my $self = $class->SUPER::new(@_);
  60
  61         $self->schema( $self->init_schema($schema_method) );
  62         return $self;
  63     }
  64
  65     ## Get the Schema and set the replication storage type
  66
  67     sub init_schema {
  68         # current SQLT SQLite producer does not handle DROP TABLE IF EXISTS, trap warnings here
  69         local $SIG{__WARN__} = sub { warn @_ unless $_[0] =~ /no such table.+DROP TABLE/s };
  70
  71         my ($class, $schema_method) = @_;
  72
  73         my $method = "get_schema_$schema_method";
  74         my $schema = $class->$method;
  75
  76         return $schema;
  77     }
  78
  79     sub get_schema_by_storage_type {
  80       DBICTest->init_schema(
  81         sqlite_use_file => 1,
  82         storage_type=>{
  83           '::DBI::Replicated' => {
  84             balancer_type=>'::Random',
  85             balancer_args=>{
  86               auto_validate_every=>100,
  87           master_read_weight => 1
  88             },
  89           }
  90         },
  91         deploy_args=>{
  92           add_drop_table => 1,
  93         },
  94       );
  95     }
  96
  97     sub get_schema_by_connect_info {
  98       DBICTest->init_schema(
  99         sqlite_use_file => 1,
 100         storage_type=> '::DBI::Replicated',
 101         balancer_type=>'::Random',
 102         balancer_args=> {
 103           auto_validate_every=>100,
 104       master_read_weight => 1
 105         },
 106         deploy_args=>{
 107           add_drop_table => 1,
 108         },
 109       );
 110     }
 111
 112     sub generate_replicant_connect_info {}
 113     sub replicate {}
 114     sub cleanup {}
 115
 116     ## --------------------------------------------------------------------- ##
 117     ## Add a connect_info option to test option merging.
 118     ## --------------------------------------------------------------------- ##
 119     {
 120     package DBIx::Class::Storage::DBI::Replicated;
 121
 122     use Moose;
 123
 124     __PACKAGE__->meta->make_mutable;
 125
 126     around connect_info => sub {
 127       my ($next, $self, $info) = @_;
 128       $info->[3]{master_option} = 1;
 129       $self->$next($info);
 130     };
 131
 132     __PACKAGE__->meta->make_immutable;
 133
 134     no Moose;
 135     }
 136
 137     ## --------------------------------------------------------------------- ##
 138     ## Subclass for when you are using SQLite for testing, this provides a fake
 139     ## replication support.
 140     ## --------------------------------------------------------------------- ##
 141
 142     package DBIx::Class::DBI::Replicated::TestReplication::SQLite;
 143
 144     use DBICTest;
 145     use File::Copy;
 146     use base 'DBIx::Class::DBI::Replicated::TestReplication';
 147
 148     __PACKAGE__->mk_accessors(qw/master_path slave_paths/);
 149
 150     ## Set the master path from DBICTest
 151
 152     sub new {
 153         my $class = shift @_;
 154         my $self = $class->SUPER::new(@_);
 155
 156         $self->master_path( DBICTest->_sqlite_dbfilename );
 157         $self->slave_paths([
 158             File::Spec->catfile(qw/t var DBIxClass_slave1.db/),
 159             File::Spec->catfile(qw/t var DBIxClass_slave2.db/),
 160         ]);
 161
 162         return $self;
 163     }
 164
 165     ## Return an Array of ArrayRefs where each ArrayRef is suitable to use for
 166     ## $storage->connect_info to be used for connecting replicants.
 167
 168     sub generate_replicant_connect_info {
 169         my $self = shift @_;
 170         my @dsn = map {
 171             "dbi:SQLite:${_}";
 172         } @{$self->slave_paths};
 173
 174         my @connect_infos = map { [$_,'','',{AutoCommit=>1}] } @dsn;
 175
 176         ## Make sure nothing is left over from a failed test
 177         $self->cleanup;
 178
 179         ## try a hashref too
 180         my $c = $connect_infos[0];
 181         $connect_infos[0] = {
 182           dsn => $c->[0],
 183           user => $c->[1],
 184           password => $c->[2],
 185           %{ $c->[3] }
 186         };
 187
 188         @connect_infos
 189     }
 190
 191     ## Do a 'good enough' replication by copying the master dbfile over each of
 192     ## the slave dbfiles.  If the master is SQLite we do this, otherwise we
 193     ## just do a one second pause to let the slaves catch up.
 194
 195     sub replicate {
 196         my $self = shift @_;
 197         foreach my $slave (@{$self->slave_paths}) {
 198             copy($self->master_path, $slave);
 199         }
 200     }
 201
 202     ## Cleanup after ourselves.  Unlink all gthe slave paths.
 203
 204     sub cleanup {
 205         my $self = shift @_;
 206         foreach my $slave (@{$self->slave_paths}) {
 207             if(-e $slave) {
 208                 unlink $slave;
 209             }
 210         }
 211     }
 212
 213     ## --------------------------------------------------------------------- ##
 214     ## Subclass for when you are setting the databases via custom export vars
 215     ## This is for when you have a replicating database setup that you are
 216     ## going to test against.  You'll need to define the correct $ENV and have
 217     ## two slave databases to test against, as well as a replication system
 218     ## that will replicate in less than 1 second.
 219     ## --------------------------------------------------------------------- ##
 220
 221     package DBIx::Class::DBI::Replicated::TestReplication::Custom;
 222     use base 'DBIx::Class::DBI::Replicated::TestReplication';
 223
 224     ## Return an Array of ArrayRefs where each ArrayRef is suitable to use for
 225     ## $storage->connect_info to be used for connecting replicants.
 226
 227     sub generate_replicant_connect_info {
 228         return (
 229             [$ENV{"DBICTEST_SLAVE0_DSN"}, $ENV{"DBICTEST_SLAVE0_DBUSER"}, $ENV{"DBICTEST_SLAVE0_DBPASS"}, {AutoCommit => 1}],
 230             [$ENV{"DBICTEST_SLAVE1_DSN"}, $ENV{"DBICTEST_SLAVE1_DBUSER"}, $ENV{"DBICTEST_SLAVE1_DBPASS"}, {AutoCommit => 1}],
 231         );
 232     }
 233
 234     ## pause a bit to let the replication catch up
 235
 236     sub replicate {
 237         sleep 1;
 238     }
 239 }
 240
 241 ## ----------------------------------------------------------------------------
 242 ## Create an object and run some tests
 243 ## ----------------------------------------------------------------------------
 244
 245 ## Thi first bunch of tests are basic, just make sure all the bits are behaving
 246
 247 my $replicated_class = DBICTest->has_custom_dsn ?
 248     'DBIx::Class::DBI::Replicated::TestReplication::Custom' :
 249     'DBIx::Class::DBI::Replicated::TestReplication::SQLite';
 250
 251 my $replicated;
 252
 253 for my $method (qw/by_connect_info by_storage_type/) {
 254   undef $replicated;
 255   ok $replicated = $replicated_class->new($method)
 256       => "Created a replication object $method";
 257
 258   isa_ok $replicated->schema
 259       => 'DBIx::Class::Schema';
 260
 261   isa_ok $replicated->schema->storage
 262       => 'DBIx::Class::Storage::DBI::Replicated';
 263
 264   isa_ok $replicated->schema->storage->balancer
 265       => 'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
 266       => 'configured balancer_type';
 267 }
 268
 269 ok $replicated->schema->storage->meta
 270     => 'has a meta object';
 271
 272 isa_ok $replicated->schema->storage->master
 273     => 'DBIx::Class::Storage::DBI';
 274
 275 isa_ok $replicated->schema->storage->pool
 276     => 'DBIx::Class::Storage::DBI::Replicated::Pool';
 277
 278 does_ok $replicated->schema->storage->balancer
 279     => 'DBIx::Class::Storage::DBI::Replicated::Balancer';
 280
 281 ok my @replicant_connects = $replicated->generate_replicant_connect_info
 282     => 'got replication connect information';
 283
 284 ok my @replicated_storages = $replicated->schema->storage->connect_replicants(@replicant_connects)
 285     => 'Created some storages suitable for replicants';
 286
 287 our %debug;
 288 $replicated->schema->storage->debug(1);
 289 $replicated->schema->storage->debugcb(sub {
 290     my ($op, $info) = @_;
 291     ##warn "\n$op, $info\n";
 292     %debug = (
 293         op => $op,
 294         info => $info,
 295         dsn => ($info=~m/\[(.+)\]/)[0],
 296         storage_type => $info=~m/REPLICANT/ ? 'REPLICANT' : 'MASTER',
 297     );
 298 });
 299
 300 ok my @all_storages = $replicated->schema->storage->all_storages
 301     => '->all_storages';
 302
 303 is scalar @all_storages,
 304     3
 305     => 'correct number of ->all_storages';
 306
 307 is ((grep $_->isa('DBIx::Class::Storage::DBI'), @all_storages),
 308     3
 309     => '->all_storages are correct type');
 310
 311 my @all_storage_opts =
 312   grep { (reftype($_)||'') eq 'HASH' }
 313     map @{ $_->_connect_info }, @all_storages;
 314
 315 is ((grep $_->{master_option}, @all_storage_opts),
 316     3
 317     => 'connect_info was merged from master to replicants');
 318
 319 my @replicant_names = keys %{ $replicated->schema->storage->replicants };
 320
 321 ok @replicant_names, "found replicant names @replicant_names";
 322
 323 ## Silence warning about not supporting the is_replicating method if using the
 324 ## sqlite dbs.
 325 $replicated->schema->storage->debugobj->silence(1)
 326   if first { m{^t/} } @replicant_names;
 327
 328 isa_ok $replicated->schema->storage->balancer->current_replicant
 329     => 'DBIx::Class::Storage::DBI';
 330
 331 $replicated->schema->storage->debugobj->silence(0);
 332
 333 ok $replicated->schema->storage->pool->has_replicants
 334     => 'does have replicants';
 335
 336 is $replicated->schema->storage->pool->num_replicants => 2
 337     => 'has two replicants';
 338
 339 does_ok $replicated_storages[0]
 340     => 'DBIx::Class::Storage::DBI::Replicated::Replicant';
 341
 342 does_ok $replicated_storages[1]
 343     => 'DBIx::Class::Storage::DBI::Replicated::Replicant';
 344
 345 does_ok $replicated->schema->storage->replicants->{$replicant_names[0]}
 346     => 'DBIx::Class::Storage::DBI::Replicated::Replicant';
 347
 348 does_ok $replicated->schema->storage->replicants->{$replicant_names[1]}
 349     => 'DBIx::Class::Storage::DBI::Replicated::Replicant';
 350
 351 ## Add some info to the database
 352
 353 $replicated
 354     ->schema
 355     ->populate('Artist', [
 356         [ qw/artistid name/ ],
 357         [ 4, "Ozric Tentacles"],
 358     ]);
 359
 360     is $debug{storage_type}, 'MASTER',
 361         "got last query from a master: $debug{dsn}";
 362
 363     like $debug{info}, qr/INSERT/, 'Last was an insert';
 364
 365 ## Make sure all the slaves have the table definitions
 366
 367 $replicated->replicate;
 368 $replicated->schema->storage->replicants->{$replicant_names[0]}->active(1);
 369 $replicated->schema->storage->replicants->{$replicant_names[1]}->active(1);
 370
 371 ## Silence warning about not supporting the is_replicating method if using the
 372 ## sqlite dbs.
 373 $replicated->schema->storage->debugobj->silence(1)
 374   if first { m{^t/} } @replicant_names;
 375
 376 $replicated->schema->storage->pool->validate_replicants;
 377
 378 $replicated->schema->storage->debugobj->silence(0);
 379
 380 ## Make sure we can read the data.
 381
 382 ok my $artist1 = $replicated->schema->resultset('Artist')->find(4)
 383     => 'Created Result';
 384
 385 ## We removed testing here since master read weight is on, so we can't tell in
 386 ## advance what storage to expect.  We turn master read weight off a bit lower
 387 ## is $debug{storage_type}, 'REPLICANT'
 388 ##     => "got last query from a replicant: $debug{dsn}, $debug{info}";
 389
 390 isa_ok $artist1
 391     => 'DBICTest::Artist';
 392
 393 is $artist1->name, 'Ozric Tentacles'
 394     => 'Found expected name for first result';
 395
 396 ## Check that master_read_weight is honored
 397 {
 398     no warnings qw/once redefine/;
 399
 400     local
 401     *DBIx::Class::Storage::DBI::Replicated::Balancer::Random::_random_number =
 402     sub { 999 };
 403
 404     $replicated->schema->storage->balancer->increment_storage;
 405
 406     is $replicated->schema->storage->balancer->current_replicant,
 407        $replicated->schema->storage->master
 408        => 'master_read_weight is honored';
 409
 410     ## turn it off for the duration of the test
 411     $replicated->schema->storage->balancer->master_read_weight(0);
 412     $replicated->schema->storage->balancer->increment_storage;
 413 }
 414
 415 ## Add some new rows that only the master will have  This is because
 416 ## we overload any type of write operation so that is must hit the master
 417 ## database.
 418
 419 $replicated
 420     ->schema
 421     ->populate('Artist', [
 422         [ qw/artistid name/ ],
 423         [ 5, "Doom's Children"],
 424         [ 6, "Dead On Arrival"],
 425         [ 7, "Watergate"],
 426     ]);
 427
 428     is $debug{storage_type}, 'MASTER',
 429         "got last query from a master: $debug{dsn}";
 430
 431     like $debug{info}, qr/INSERT/, 'Last was an insert';
 432
 433 ## Make sure all the slaves have the table definitions
 434 $replicated->replicate;
 435
 436 ## Should find some data now
 437
 438 ok my $artist2 = $replicated->schema->resultset('Artist')->find(5)
 439     => 'Sync succeed';
 440
 441 is $debug{storage_type}, 'REPLICANT'
 442     => "got last query from a replicant: $debug{dsn}";
 443
 444 isa_ok $artist2
 445     => 'DBICTest::Artist';
 446
 447 is $artist2->name, "Doom's Children"
 448     => 'Found expected name for first result';
 449
 450 ## What happens when we disconnect all the replicants?
 451
 452 is $replicated->schema->storage->pool->connected_replicants => 2
 453     => "both replicants are connected";
 454
 455 $replicated->schema->storage->replicants->{$replicant_names[0]}->disconnect;
 456 $replicated->schema->storage->replicants->{$replicant_names[1]}->disconnect;
 457
 458 is $replicated->schema->storage->pool->connected_replicants => 0
 459     => "both replicants are now disconnected";
 460
 461 ## All these should pass, since the database should automatically reconnect
 462
 463 ok my $artist3 = $replicated->schema->resultset('Artist')->find(6)
 464     => 'Still finding stuff.';
 465
 466 is $debug{storage_type}, 'REPLICANT'
 467     => "got last query from a replicant: $debug{dsn}";
 468
 469 isa_ok $artist3
 470     => 'DBICTest::Artist';
 471
 472 is $artist3->name, "Dead On Arrival"
 473     => 'Found expected name for first result';
 474
 475 is $replicated->schema->storage->pool->connected_replicants => 1
 476     => "At Least One replicant reconnected to handle the job";
 477
 478 ## What happens when we try to select something that doesn't exist?
 479
 480 ok ! $replicated->schema->resultset('Artist')->find(666)
 481     => 'Correctly failed to find something.';
 482
 483 is $debug{storage_type}, 'REPLICANT'
 484     => "got last query from a replicant: $debug{dsn}";
 485
 486 ## test the reliable option
 487
 488 TESTRELIABLE: {
 489
 490     $replicated->schema->storage->set_reliable_storage;
 491
 492     ok $replicated->schema->resultset('Artist')->find(2)
 493         => 'Read from master 1';
 494
 495     is $debug{storage_type}, 'MASTER',
 496         "got last query from a master: $debug{dsn}";
 497
 498     ok $replicated->schema->resultset('Artist')->find(5)
 499         => 'Read from master 2';
 500
 501     is $debug{storage_type}, 'MASTER',
 502         "got last query from a master: $debug{dsn}";
 503
 504     $replicated->schema->storage->set_balanced_storage;
 505
 506     ok $replicated->schema->resultset('Artist')->find(3)
 507         => 'Read from replicant';
 508
 509     is $debug{storage_type}, 'REPLICANT',
 510         "got last query from a replicant: $debug{dsn}";
 511 }
 512
 513 ## Make sure when reliable goes out of scope, we are using replicants again
 514
 515 ok $replicated->schema->resultset('Artist')->find(1)
 516     => 'back to replicant 1.';
 517
 518     is $debug{storage_type}, 'REPLICANT',
 519         "got last query from a replicant: $debug{dsn}";
 520
 521 ok $replicated->schema->resultset('Artist')->find(2)
 522     => 'back to replicant 2.';
 523
 524     is $debug{storage_type}, 'REPLICANT',
 525         "got last query from a replicant: $debug{dsn}";
 526
 527 ## set all the replicants to inactive, and make sure the balancer falls back to
 528 ## the master.
 529
 530 $replicated->schema->storage->replicants->{$replicant_names[0]}->active(0);
 531 $replicated->schema->storage->replicants->{$replicant_names[1]}->active(0);
 532
 533 {
 534     ## catch the fallback to master warning
 535     open my $debugfh, '>', \my $fallback_warning;
 536     my $oldfh = $replicated->schema->storage->debugfh;
 537     $replicated->schema->storage->debugfh($debugfh);
 538
 539     ok $replicated->schema->resultset('Artist')->find(2)
 540         => 'Fallback to master';
 541
 542     is $debug{storage_type}, 'MASTER',
 543         "got last query from a master: $debug{dsn}";
 544
 545     like $fallback_warning, qr/falling back to master/
 546         => 'emits falling back to master warning';
 547
 548     $replicated->schema->storage->debugfh($oldfh);
 549 }
 550
 551 $replicated->schema->storage->replicants->{$replicant_names[0]}->active(1);
 552 $replicated->schema->storage->replicants->{$replicant_names[1]}->active(1);
 553
 554 ## Silence warning about not supporting the is_replicating method if using the
 555 ## sqlite dbs.
 556 $replicated->schema->storage->debugobj->silence(1)
 557   if first { m{^t/} } @replicant_names;
 558
 559 $replicated->schema->storage->pool->validate_replicants;
 560
 561 $replicated->schema->storage->debugobj->silence(0);
 562
 563 ok $replicated->schema->resultset('Artist')->find(2)
 564     => 'Returned to replicates';
 565
 566 is $debug{storage_type}, 'REPLICANT',
 567     "got last query from a replicant: $debug{dsn}";
 568
 569 ## Getting slave status tests
 570
 571 SKIP: {
 572     ## We skip this tests unless you have a custom replicants, since the default
 573     ## sqlite based replication tests don't support these functions.
 574
 575     skip 'Cannot Test Replicant Status on Non Replicating Database', 10
 576      unless DBICTest->has_custom_dsn && $ENV{"DBICTEST_SLAVE0_DSN"};
 577
 578     $replicated->replicate; ## Give the slaves a chance to catchup.
 579
 580     ok $replicated->schema->storage->replicants->{$replicant_names[0]}->is_replicating
 581         => 'Replicants are replicating';
 582
 583     is $replicated->schema->storage->replicants->{$replicant_names[0]}->lag_behind_master, 0
 584         => 'Replicant is zero seconds behind master';
 585
 586     ## Test the validate replicants
 587
 588     $replicated->schema->storage->pool->validate_replicants;
 589
 590     is $replicated->schema->storage->pool->active_replicants, 2
 591         => 'Still have 2 replicants after validation';
 592
 593     ## Force the replicants to fail the validate test by required their lag to
 594     ## be negative (ie ahead of the master!)
 595
 596     $replicated->schema->storage->pool->maximum_lag(-10);
 597     $replicated->schema->storage->pool->validate_replicants;
 598
 599     is $replicated->schema->storage->pool->active_replicants, 0
 600         => 'No way a replicant be be ahead of the master';
 601
 602     ## Let's be fair to the replicants again.  Let them lag up to 5
 603
 604     $replicated->schema->storage->pool->maximum_lag(5);
 605     $replicated->schema->storage->pool->validate_replicants;
 606
 607     is $replicated->schema->storage->pool->active_replicants, 2
 608         => 'Both replicants in good standing again';
 609
 610     ## Check auto validate
 611
 612     is $replicated->schema->storage->balancer->auto_validate_every, 100
 613         => "Got the expected value for auto validate";
 614
 615         ## This will make sure we auto validatge everytime
 616         $replicated->schema->storage->balancer->auto_validate_every(0);
 617
 618         ## set all the replicants to inactive, and make sure the balancer falls back to
 619         ## the master.
 620
 621         $replicated->schema->storage->replicants->{$replicant_names[0]}->active(0);
 622         $replicated->schema->storage->replicants->{$replicant_names[1]}->active(0);
 623
 624         ## Ok, now when we go to run a query, autovalidate SHOULD reconnect
 625
 626     is $replicated->schema->storage->pool->active_replicants => 0
 627         => "both replicants turned off";
 628
 629     ok $replicated->schema->resultset('Artist')->find(5)
 630         => 'replicant reactivated';
 631
 632     is $debug{storage_type}, 'REPLICANT',
 633         "got last query from a replicant: $debug{dsn}";
 634
 635     is $replicated->schema->storage->pool->active_replicants => 2
 636         => "both replicants reactivated";
 637 }
 638
 639 ## Test the reliably callback
 640
 641 ok my $reliably = sub {
 642
 643     ok $replicated->schema->resultset('Artist')->find(5)
 644         => 'replicant reactivated';
 645
 646     is $debug{storage_type}, 'MASTER',
 647         "got last query from a master: $debug{dsn}";
 648
 649 } => 'created coderef properly';
 650
 651 $replicated->schema->storage->execute_reliably($reliably);
 652
 653 ## Try something with an error
 654
 655 ok my $unreliably = sub {
 656
 657     ok $replicated->schema->resultset('ArtistXX')->find(5)
 658         => 'replicant reactivated';
 659
 660 } => 'created coderef properly';
 661
 662 throws_ok {$replicated->schema->storage->execute_reliably($unreliably)}
 663     qr/Can't find source for ArtistXX/
 664     => 'Bad coderef throws proper error';
 665
 666 ## Make sure replication came back
 667
 668 ok $replicated->schema->resultset('Artist')->find(3)
 669     => 'replicant reactivated';
 670
 671 is $debug{storage_type}, 'REPLICANT', "got last query from a replicant: $debug{dsn}";
 672
 673 ## make sure transactions are set to execute_reliably
 674
 675 ok my $transaction = sub {
 676
 677     my $id = shift @_;
 678
 679     $replicated
 680         ->schema
 681         ->populate('Artist', [
 682             [ qw/artistid name/ ],
 683             [ $id, "Children of the Grave"],
 684         ]);
 685
 686     ok my $result = $replicated->schema->resultset('Artist')->find($id)
 687         => "Found expected artist for $id";
 688
 689     is $debug{storage_type}, 'MASTER',
 690         "got last query from a master: $debug{dsn}";
 691
 692     ok my $more = $replicated->schema->resultset('Artist')->find(1)
 693         => 'Found expected artist again for 1';
 694
 695     is $debug{storage_type}, 'MASTER',
 696         "got last query from a master: $debug{dsn}";
 697
 698    return ($result, $more);
 699
 700 } => 'Created a coderef properly';
 701
 702 ## Test the transaction with multi return
 703 {
 704     ok my @return = $replicated->schema->txn_do($transaction, 666)
 705         => 'did transaction';
 706
 707         is $return[0]->id, 666
 708             => 'first returned value is correct';
 709
 710         is $debug{storage_type}, 'MASTER',
 711             "got last query from a master: $debug{dsn}";
 712
 713         is $return[1]->id, 1
 714             => 'second returned value is correct';
 715
 716         is $debug{storage_type}, 'MASTER',
 717              "got last query from a master: $debug{dsn}";
 718
 719 }
 720
 721 ## Test that asking for single return works
 722 {
 723     ok my @return = $replicated->schema->txn_do($transaction, 777)
 724         => 'did transaction';
 725
 726         is $return[0]->id, 777
 727             => 'first returned value is correct';
 728
 729         is $return[1]->id, 1
 730             => 'second returned value is correct';
 731 }
 732
 733 ## Test transaction returning a single value
 734
 735 {
 736     ok my $result = $replicated->schema->txn_do(sub {
 737         ok my $more = $replicated->schema->resultset('Artist')->find(1)
 738         => 'found inside a transaction';
 739         is $debug{storage_type}, 'MASTER', "got last query from a master: $debug{dsn}";
 740         return $more;
 741     }) => 'successfully processed transaction';
 742
 743     is $result->id, 1
 744        => 'Got expected single result from transaction';
 745 }
 746
 747 ## Make sure replication came back
 748
 749 ok $replicated->schema->resultset('Artist')->find(1)
 750     => 'replicant reactivated';
 751
 752 is $debug{storage_type}, 'REPLICANT', "got last query from a replicant: $debug{dsn}";
 753
 754 ## Test Discard changes
 755
 756 {
 757     ok my $artist = $replicated->schema->resultset('Artist')->find(2)
 758         => 'got an artist to test discard changes';
 759
 760     is $debug{storage_type}, 'REPLICANT', "got last query from a replicant: $debug{dsn}";
 761
 762     ok $artist->get_from_storage({force_pool=>'master'})
 763        => 'properly discard changes';
 764
 765     is $debug{storage_type}, 'MASTER', "got last query from a master: $debug{dsn}";
 766
 767     ok $artist->discard_changes({force_pool=>'master'})
 768        => 'properly called discard_changes against master (manual attrs)';
 769
 770     is $debug{storage_type}, 'MASTER', "got last query from a master: $debug{dsn}";
 771
 772     ok $artist->discard_changes()
 773        => 'properly called discard_changes against master (default attrs)';
 774
 775     is $debug{storage_type}, 'MASTER', "got last query from a master: $debug{dsn}";
 776
 777     ok $artist->discard_changes({force_pool=>$replicant_names[0]})
 778        => 'properly able to override the default attributes';
 779
 780     is $debug{storage_type}, 'REPLICANT', "got last query from a replicant: $debug{dsn}"
 781 }
 782
 783 ## Test some edge cases, like trying to do a transaction inside a transaction, etc
 784
 785 {
 786     ok my $result = $replicated->schema->txn_do(sub {
 787         return $replicated->schema->txn_do(sub {
 788             ok my $more = $replicated->schema->resultset('Artist')->find(1)
 789             => 'found inside a transaction inside a transaction';
 790             is $debug{storage_type}, 'MASTER', "got last query from a master: $debug{dsn}";
 791             return $more;
 792         });
 793     }) => 'successfully processed transaction';
 794
 795     is $result->id, 1
 796        => 'Got expected single result from transaction';
 797 }
 798
 799 {
 800     ok my $result = $replicated->schema->txn_do(sub {
 801         return $replicated->schema->storage->execute_reliably(sub {
 802             return $replicated->schema->txn_do(sub {
 803                 return $replicated->schema->storage->execute_reliably(sub {
 804                     ok my $more = $replicated->schema->resultset('Artist')->find(1)
 805                       => 'found inside crazy deep transactions and execute_reliably';
 806                     is $debug{storage_type}, 'MASTER', "got last query from a master: $debug{dsn}";
 807                     return $more;
 808                 });
 809             });
 810         });
 811     }) => 'successfully processed transaction';
 812
 813     is $result->id, 1
 814        => 'Got expected single result from transaction';
 815 }
 816
 817 ## Test the force_pool resultset attribute.
 818
 819 {
 820     ok my $artist_rs = $replicated->schema->resultset('Artist')
 821         => 'got artist resultset';
 822
 823     ## Turn on Forced Pool Storage
 824     ok my $reliable_artist_rs = $artist_rs->search(undef, {force_pool=>'master'})
 825         => 'Created a resultset using force_pool storage';
 826
 827     ok my $artist = $reliable_artist_rs->find(2)
 828         => 'got an artist result via force_pool storage';
 829
 830     is $debug{storage_type}, 'MASTER', "got last query from a master: $debug{dsn}";
 831 }
 832
 833 ## Test the force_pool resultset attribute part two.
 834
 835 {
 836     ok my $artist_rs = $replicated->schema->resultset('Artist')
 837         => 'got artist resultset';
 838
 839     ## Turn on Forced Pool Storage
 840     ok my $reliable_artist_rs = $artist_rs->search(undef, {force_pool=>$replicant_names[0]})
 841         => 'Created a resultset using force_pool storage';
 842
 843     ok my $artist = $reliable_artist_rs->find(2)
 844         => 'got an artist result via force_pool storage';
 845
 846     is $debug{storage_type}, 'REPLICANT', "got last query from a replicant: $debug{dsn}";
 847 }
 848 ## Delete the old database files
 849 $replicated->cleanup;
 850
 851 done_testing;
 852
 853 # vim: sw=4 sts=4 :