t/sqlmaker/dbihacks_internals.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Test::Warn;
   5
   6 use lib qw(t/lib);
   7 use DBICTest ':DiffSQL';
   8 use DBIx::Class::_Util 'UNRESOLVABLE_CONDITION';
   9
  10 use Data::Dumper;
  11
  12 my $schema = DBICTest->init_schema( no_deploy => 1);
  13 my $sm = $schema->storage->sql_maker;
  14
  15 {
  16   package # hideee
  17     DBICTest::SillyInt;
  18
  19   use overload
  20     fallback => 1,
  21     '0+' => sub { ${$_[0]} },
  22   ;
  23 }
  24 my $num = bless( \do { my $foo = 69 }, 'DBICTest::SillyInt' );
  25
  26 is($num, 69, 'test overloaded object is "sane"');
  27 is("$num", 69, 'test overloaded object is "sane"');
  28
  29 for my $t (
  30   {
  31     where => { artistid => 1, charfield => undef },
  32     cc_result => { artistid => 1, charfield => undef },
  33     sql => 'WHERE artistid = ? AND charfield IS NULL',
  34     efcc_result => { artistid => 1 },
  35     efcc_n_result => { artistid => 1, charfield => undef },
  36   },
  37   {
  38     where => { -and => [ artistid => 1, charfield => undef, { rank => 13 } ] },
  39     cc_result => { artistid => 1, charfield => undef, rank => 13 },
  40     sql => 'WHERE artistid = ?  AND charfield IS NULL AND rank = ?',
  41     efcc_result => { artistid => 1, rank => 13 },
  42     efcc_n_result => { artistid => 1, charfield => undef, rank => 13 },
  43   },
  44   {
  45     where => { -and => [ { artistid => 1, charfield => undef}, { rank => 13 } ] },
  46     cc_result => { artistid => 1, charfield => undef, rank => 13 },
  47     sql => 'WHERE artistid = ?  AND charfield IS NULL AND rank = ?',
  48     efcc_result => { artistid => 1, rank => 13 },
  49     efcc_n_result => { artistid => 1, charfield => undef, rank => 13 },
  50   },
  51   {
  52     where => { -and => [ -or => { name => 'Caterwauler McCrae' }, 'rank' ] },
  53     cc_result => { name => 'Caterwauler McCrae', rank => undef },
  54     sql => 'WHERE name = ? AND rank IS NULL',
  55     efcc_result => { name => 'Caterwauler McCrae' },
  56     efcc_n_result => { name => 'Caterwauler McCrae', rank => undef },
  57   },
  58   {
  59     where => { -and => [ [ [ artist => {'=' => \'foo' } ] ], { name => \[ '= ?', 'bar' ] } ] },
  60     cc_result => { artist => {'=' => \'foo' }, name => \[ '= ?', 'bar' ] },
  61     sql => 'WHERE artist = foo AND name = ?',
  62     efcc_result => { artist => \'foo' },
  63   },
  64   {
  65     where => { -and => [ -or => { name => 'Caterwauler McCrae', artistid => 2 } ] },
  66     cc_result => { -or => [ artistid => 2, name => 'Caterwauler McCrae' ] },
  67     sql => 'WHERE artistid = ? OR name = ?',
  68     efcc_result => {},
  69   },
  70   {
  71     where => { -or => { name => 'Caterwauler McCrae', artistid => 2 } },
  72     cc_result => { -or => [ artistid => 2, name => 'Caterwauler McCrae' ] },
  73     sql => 'WHERE artistid = ? OR name = ?',
  74     efcc_result => {},
  75   },
  76   {
  77     where => { -and => [ \'foo=bar',  [ { artistid => { '=', $num } } ], { name => 'Caterwauler McCrae'} ] },
  78     cc_result => { '' => \'foo=bar', name => 'Caterwauler McCrae', artistid => $num },
  79     sql => 'WHERE foo=bar AND artistid = ? AND name = ?',
  80     efcc_result => { name => 'Caterwauler McCrae', artistid => $num },
  81   },
  82   {
  83     where => { artistid => [ $num ], rank => [ 13, 2, 3 ], charfield => [ undef ] },
  84     cc_result => { artistid => $num, charfield => undef, rank => [13, 2, 3] },
  85     sql => 'WHERE artistid = ? AND charfield IS NULL AND ( rank = ? OR rank = ? OR rank = ? )',
  86     efcc_result => { artistid => $num },
  87     efcc_n_result => { artistid => $num, charfield => undef },
  88   },
  89   {
  90     where => { artistid => { '=' => 1 }, rank => { '>' => 12 }, charfield => { '=' => undef } },
  91     cc_result => { artistid => 1, charfield => undef, rank => { '>' => 12 } },
  92     sql => 'WHERE artistid = ? AND charfield IS NULL AND rank > ?',
  93     efcc_result => { artistid => 1 },
  94     efcc_n_result => { artistid => 1, charfield => undef },
  95   },
  96   {
  97     where => { artistid => { '=' => [ 1 ], }, charfield => { '=' => [-and => \'1', \['?',2] ] }, rank => { '=' => [ $num, $num ] } },
  98     cc_result => { artistid => 1, charfield => [-and => { '=' => \'1' }, { '=' => \['?',2] } ], rank => { '=' => [$num, $num] } },
  99     sql => 'WHERE artistid = ? AND charfield = 1 AND charfield = ? AND ( rank = ? OR rank = ? )',
 100     efcc_result => { artistid => 1, charfield => UNRESOLVABLE_CONDITION },
 101   },
 102   {
 103     where => { -and => [ artistid => 1, artistid => 2 ], name => [ -and => { '!=', 1 }, 2 ], charfield => [ -or => { '=', 2 } ], rank => [-and => undef, { '=', undef }, { '!=', 2 } ] },
 104     cc_result => { artistid => [ -and => 1, 2 ], name => [ -and => { '!=', 1 }, 2 ], charfield => 2, rank => [ -and => undef, undef, { '!=', 2 } ] },
 105     sql => 'WHERE artistid = ? AND artistid = ? AND charfield = ? AND name != ? AND name = ? AND rank IS NULL AND rank IS NULL AND rank != ?',
 106     efcc_result => {
 107       artistid => UNRESOLVABLE_CONDITION,
 108       name => 2,
 109       charfield => 2,
 110     },
 111     efcc_n_result => {
 112       artistid => UNRESOLVABLE_CONDITION,
 113       name => 2,
 114       charfield => 2,
 115       rank => undef,
 116     },
 117   },
 118   {
 119     where => { -and => [
 120       [ '_macro.to' => { -like => '%correct%' }, '_wc_macros.to' => { -like => '%correct%' } ],
 121       { -and => [ { 'group.is_active' => 1 }, { 'me.is_active' => 1 } ] }
 122     ] },
 123     cc_result => {
 124       'group.is_active' => 1,
 125       'me.is_active' => 1,
 126       -or => [
 127         '_macro.to' => { -like => '%correct%' },
 128         '_wc_macros.to' => { -like => '%correct%' },
 129       ],
 130     },
 131     sql => 'WHERE ( _macro.to LIKE ? OR _wc_macros.to LIKE ? ) AND group.is_active = ? AND me.is_active = ?',
 132     efcc_result => { 'group.is_active' => 1, 'me.is_active' => 1 },
 133   },
 134   {
 135     where => { artistid => [] },
 136     cc_result => { artistid => [] },
 137     efcc_result => {},
 138   },
 139   (map {
 140     {
 141       where => { -and => $_ },
 142       cc_result => undef,
 143       efcc_result => {},
 144       sql => '',
 145     },
 146     {
 147       where => { -or => $_ },
 148       cc_result => undef,
 149       efcc_result => {},
 150       sql => '',
 151     },
 152   } (
 153     # bare
 154     [], {},
 155     # singles
 156     [ {} ], [ [] ],
 157     # doubles
 158     [ [], [] ], [ {}, {} ], [ [], {} ], [ {}, [] ],
 159     # tripples
 160     [ {}, [], {} ], [ [], {}, [] ]
 161   )),
 162
 163   # FIXME legacy compat crap, possibly worth undef/dieing in SQLMaker
 164   { where => { artistid => {} }, sql => '', cc_result => undef, efcc_result => {}, efcc_n_result => {} },
 165
 166   # batshit insanity, just to be thorough
 167   {
 168     where => { -and => [ [ 'artistid' ], [ -and => [ artistid => { '!=', 69 }, artistid => undef, artistid => { '=' => 200 } ]], artistid => [], { -or => [] }, { -and => [] }, [ 'charfield' ], { name => [] }, 'rank' ] },
 169     cc_result => { artistid => [ -and => undef, { '!=', 69 }, undef, 200, [] ], charfield => undef, name => [], rank => undef },
 170     sql => 'WHERE artistid IS NULL AND artistid != ? AND artistid IS NULL AND artistid = ? AND 0=1 AND charfield IS NULL AND 0=1 AND rank IS NULL',
 171     efcc_result => { artistid => UNRESOLVABLE_CONDITION },
 172     efcc_n_result => { artistid => UNRESOLVABLE_CONDITION, charfield => undef, rank => undef },
 173   },
 174
 175   # original test from RT#93244
 176   {
 177     where => {
 178       -and => [
 179         \[
 180           "LOWER(me.title) LIKE ?",
 181           '%spoon%',
 182         ],
 183         [ { 'me.title' => 'Spoonful of bees' } ],
 184     ]},
 185     cc_result => {
 186       '' => \[
 187         "LOWER(me.title) LIKE ?",
 188         '%spoon%',
 189       ],
 190       'me.title' => 'Spoonful of bees',
 191     },
 192     sql => 'WHERE LOWER(me.title) LIKE ? AND me.title = ?',
 193     efcc_result => { 'me.title' => 'Spoonful of bees' },
 194   }
 195 ) {
 196
 197   for my $w (
 198     $t->{where},
 199     [ -and => $t->{where} ],
 200     ( keys %{$t->{where}} <= 1 ? [ %{$t->{where}} ] : () ),
 201     ( (keys %{$t->{where}} == 1 and $t->{where}{-or})
 202       ? ( ref $t->{where}{-or} eq 'HASH'
 203         ? [ map { $_ => $t->{where}{-or}{$_} } sort keys %{$t->{where}{-or}} ]
 204         : $t->{where}{-or}
 205       )
 206       : ()
 207     ),
 208   ) {
 209     my $name = do { local ($Data::Dumper::Indent, $Data::Dumper::Terse, $Data::Dumper::Sortkeys) = (0, 1, 1); Dumper $w };
 210
 211     my @orig_sql_bind = $sm->where($w);
 212
 213     is_same_sql ( $orig_sql_bind[0], $t->{sql}, "Expected SQL from $name" )
 214       if exists $t->{sql};
 215
 216     my $collapsed_cond = $schema->storage->_collapse_cond($w);
 217
 218     is_same_sql_bind(
 219       \[ $sm->where($collapsed_cond) ],
 220       \\@orig_sql_bind,
 221       "Collapse did not alter final SQL based on $name",
 222     );
 223
 224     is_deeply(
 225       $collapsed_cond,
 226       $t->{cc_result},
 227       "Expected collapsed condition produced on $name",
 228     );
 229
 230     is_deeply(
 231       $schema->storage->_extract_fixed_condition_columns($w),
 232       $t->{efcc_result},
 233       "Expected fixed_condition produced on $name",
 234     );
 235
 236     is_deeply(
 237       $schema->storage->_extract_fixed_condition_columns($w, 'consider_nulls'),
 238       $t->{efcc_n_result},
 239       "Expected fixed_condition including NULLs produced on $name",
 240     ) if $t->{efcc_n_result};
 241   }
 242 }
 243
 244 done_testing;