t/relationship/update_or_create_multi.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIC::SqlMakerTest;
  10
  11 my $schema = DBICTest->init_schema();
  12 my $sdebug = $schema->storage->debug;
  13
  14 my $artist = $schema->resultset ('Artist')->first;
  15
  16 my $genre = $schema->resultset ('Genre')
  17             ->create ({ name => 'par excellence' });
  18 my $genre_cds = $genre->cds;
  19
  20 is ($genre_cds->count, 0, 'No cds yet');
  21
  22 # expect a create
  23 $genre->update_or_create_related ('cds', {
  24   artist => $artist,
  25   year => 2009,
  26   title => 'the best thing since sliced bread',
  27 });
  28
  29 # verify cd was inserted ok
  30 is ($genre_cds->count, 1, 'One cd');
  31 my $cd = $genre_cds->first;
  32 is_deeply (
  33   { map { $_, $cd->get_column ($_) } qw/artist year title/ },
  34   {
  35     artist => $artist->id,
  36     year => 2009,
  37     title => 'the best thing since sliced bread',
  38   },
  39   'CD created correctly',
  40 );
  41
  42 # expect a year update on the only related row
  43 # (non-qunique column + unique column set as disambiguator)
  44 $genre->update_or_create_related ('cds', {
  45   year => 2010,
  46   title => 'the best thing since sliced bread',
  47   artist => 1,
  48 });
  49
  50 # re-fetch the cd, verify update
  51 is ($genre->search_related( 'cds' )->count, 1, 'Still one cd');
  52 $cd = $genre_cds->first;
  53 is_deeply (
  54   { map { $_, $cd->get_column ($_) } qw/artist year title/ },
  55   {
  56     artist => $artist->id,
  57     year => 2010,
  58     title => 'the best thing since sliced bread',
  59   },
  60   'CD year column updated correctly',
  61 );
  62
  63 # expect a failing create:
  64 # the unique constraint is not complete, and there is nothing
  65 # in the database with such a year yet - insertion will fail due
  66 # to missing artist fk
  67 throws_ok {
  68   $genre->update_or_create_related ('cds', {
  69     year => 2020,
  70     title => 'the best thing since sliced bread',
  71   })
  72 } qr/\Qcd.artist may not be NULL/, 'ambiguous find + create failed';
  73
  74 # expect a create, after a failed search using *only* the
  75 # *current* relationship and the unique column constraints
  76 # (so no year)
  77 my @sql;
  78 $schema->storage->debugcb(sub { push @sql, $_[1] });
  79 $schema->storage->debug (1);
  80
  81 $genre->update_or_create_related ('cds', {
  82   title => 'the best thing since vertical toasters',
  83   artist => $artist,
  84   year => 2012,
  85 });
  86
  87 $schema->storage->debugcb(undef);
  88 $schema->storage->debug ($sdebug);
  89
  90 my ($search_sql) = $sql[0] =~ /^(SELECT .+?)\:/;
  91 is_same_sql (
  92   $search_sql,
  93   'SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track
  94     FROM cd me
  95     WHERE ( me.artist = ? AND me.title = ? AND me.genreid = ? )
  96   ',
  97   'expected select issued',
  98 );
  99
 100 # a has_many search without a unique constraint makes no sense
 101 # but I am not sure what to test for - leaving open
 102
 103 done_testing;