t/relationship/custom.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest ':DiffSQL';
   8
   9 my $schema = DBICTest->init_schema();
  10
  11 $schema->resultset('Artist')->delete;
  12 $schema->resultset('CD')->delete;
  13
  14 my $artist  = $schema->resultset("Artist")->create({ artistid => 21, name => 'Michael Jackson', rank => 20 });
  15 my $artist2 = $schema->resultset("Artist")->create({ artistid => 22, name => 'Chico Buarque', rank => 1 }) ;
  16 my $artist3 = $schema->resultset("Artist")->create({ artistid => 23, name => 'Ziraldo', rank => 1 });
  17 my $artist4 = $schema->resultset("Artist")->create({ artistid => 24, name => 'Paulo Caruso', rank => 20 });
  18
  19 my @artworks;
  20
  21 foreach my $year (1975..1985) {
  22   my $cd = $artist->create_related('cds', { year => $year, title => 'Compilation from ' . $year });
  23   push @artworks, $cd->create_related('artwork', {});
  24 }
  25
  26 foreach my $year (1975..1995) {
  27   my $cd = $artist2->create_related('cds', { year => $year, title => 'Compilation from ' . $year });
  28   push @artworks, $cd->create_related('artwork', {});
  29 }
  30
  31 foreach my $artwork (@artworks) {
  32   $artwork->create_related('artwork_to_artist', { artist => $_ }) for ($artist3, $artist4);
  33 }
  34
  35
  36 my $cds_80s_rs = $artist->cds_80s;
  37 is_same_sql_bind(
  38   $cds_80s_rs->as_query,
  39   '(
  40     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track
  41       FROM cd me
  42     WHERE ( ( me.artist = ? AND ( me.year < ? AND me.year > ? ) ) )
  43   )',
  44   [
  45     [
  46       { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
  47         => 21
  48     ],
  49     [
  50       { sqlt_datatype => 'varchar', sqlt_size => 100, dbic_colname => 'me.year' }
  51         => 1990
  52     ],
  53     [
  54       { sqlt_datatype => 'varchar', sqlt_size => 100, dbic_colname => 'me.year' }
  55         => 1979
  56     ],
  57   ],
  58 );
  59 my @cds_80s = $cds_80s_rs->all;
  60 is(@cds_80s, 6, '6 80s cds found (1980 - 1985)');
  61 map { ok($_->year < 1990 && $_->year > 1979) } @cds_80s;
  62
  63
  64 my $cds_90s_rs = $artist2->cds_90s;
  65 is_same_sql_bind(
  66   $cds_90s_rs->as_query,
  67   '(
  68     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track
  69       FROM artist artist__row
  70       JOIN cd me
  71         ON ( me.artist = artist__row.artistid AND ( me.year < ? AND me.year > ? ) )
  72       WHERE ( artist__row.artistid = ? )
  73   )',
  74   [
  75     [
  76       { sqlt_datatype => 'varchar', sqlt_size => 100, dbic_colname => 'me.year' }
  77         => 2000
  78     ],
  79     [
  80       { sqlt_datatype => 'varchar', sqlt_size => 100, dbic_colname => 'me.year' }
  81         => 1989
  82     ],
  83     [ { sqlt_datatype => 'integer', dbic_colname => 'artist__row.artistid' }
  84         => 22
  85     ],
  86   ]
  87 );
  88
  89 # re-test with ::-containing moniker name
  90 # (we don't have any currently, so fudge it with lots of local() )
  91 {
  92   local $schema->source('Artist')->{source_name} = 'Ar::Tist';
  93   local $artist2->{related_resultsets};
  94
  95   is_same_sql_bind(
  96     $artist2->cds_90s->as_query,
  97     '(
  98       SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track
  99         FROM artist ar_tist__row
 100         JOIN cd me
 101           ON ( me.artist = ar_tist__row.artistid AND ( me.year < ? AND me.year > ? ) )
 102         WHERE ( ar_tist__row.artistid = ? )
 103     )',
 104     [
 105       [
 106         { sqlt_datatype => 'varchar', sqlt_size => 100, dbic_colname => 'me.year' }
 107           => 2000
 108       ],
 109       [
 110       { sqlt_datatype => 'varchar', sqlt_size => 100, dbic_colname => 'me.year' }
 111           => 1989
 112       ],
 113       [ { sqlt_datatype => 'integer', dbic_colname => 'ar_tist__row.artistid' }
 114           => 22
 115       ],
 116     ]
 117   );
 118 }
 119
 120
 121 my @cds_90s = $cds_90s_rs->all;
 122 is(@cds_90s, 6, '6 90s cds found (1990 - 1995) even with non-optimized search');
 123 map { ok($_->year < 2000 && $_->year > 1989) } @cds_90s;
 124
 125 lives_ok {
 126   my @cds_90s_95 = $artist2->cds_90s->search({ 'me.year' => 1995 });
 127   is(@cds_90s_95, 1, '1 90s (95) cds found even with non-optimized search');
 128   map { ok($_->year == 1995) } @cds_90s_95;
 129 } 'should preserve chain-head "me" alias (API-consistency)';
 130
 131 # search for all artists prefetching published cds in the 80s...
 132 my @all_artists_with_80_cds = $schema->resultset("Artist")->search
 133   ({ 'cds_80s.cdid' => { '!=' => undef } }, { join => 'cds_80s', distinct => 1 });
 134
 135 is_deeply(
 136   [ sort ( map { $_->year } map { $_->cds_80s->all } @all_artists_with_80_cds ) ],
 137   [ sort (1980..1989, 1980..1985) ],
 138   '16 correct cds found'
 139 );
 140
 141 lives_ok {
 142
 143 my @all_artists_with_80_cds_pref = $schema->resultset("Artist")->search
 144   ({ 'cds_80s.cdid' => { '!=' => undef } }, { prefetch => 'cds_80s' });
 145
 146 is_deeply(
 147   [ sort ( map { $_->year } map { $_->cds_80s->all } @all_artists_with_80_cds_pref ) ],
 148   [ sort (1980..1989, 1980..1985) ],
 149   '16 correct cds found'
 150 );
 151
 152 } 'prefetchy-fetchy-fetch';
 153
 154
 155 # try to create_related a 80s cd
 156 throws_ok {
 157   $artist->create_related('cds_80s', { title => 'related creation 1' });
 158 } qr/\QCustom relationship 'cds_80s' not definitive - returns conditions instead of values for column(s): 'year'/,
 159 'Create failed - complex cond';
 160
 161 # now supply an explicit arg overwriting the ambiguous cond
 162 my $id_2020 = $artist->create_related('cds_80s', { title => 'related creation 2', year => '2020' })->id;
 163 is(
 164   $schema->resultset('CD')->find($id_2020)->title,
 165   'related creation 2',
 166   '2020 CD created correctly'
 167 );
 168
 169 # try a default year from a specific rel
 170 my $id_1984 = $artist->create_related('cds_84', { title => 'related creation 3' })->id;
 171 is(
 172   $schema->resultset('CD')->find($id_1984)->title,
 173   'related creation 3',
 174   '1984 CD created correctly'
 175 );
 176
 177 # try a specific everything via a non-simplified rel
 178 throws_ok {
 179   $artist->create_related('cds_90s', { title => 'related_creation 4', year => '2038' });
 180 } qr/\QCustom relationship 'cds_90s' does not resolve to a join-free condition fragment/,
 181 'Create failed - non-simplified rel';
 182
 183 # Do a self-join last-entry search
 184 my @last_tracks;
 185 for my $cd ($schema->resultset('CD')->search ({}, { order_by => 'cdid'})->all) {
 186   push @last_tracks, $cd->tracks
 187                          ->search ({}, { order_by => { -desc => 'position'} })
 188                           ->next || ();
 189 }
 190
 191 my $last_tracks_rs = $schema->resultset('Track')->search (
 192   {'next_tracks.trackid' => undef},
 193   { join => 'next_tracks', order_by => 'me.cd' },
 194 );
 195
 196 is_deeply (
 197   [$last_tracks_rs->get_column ('trackid')->all],
 198   [ map { $_->trackid } @last_tracks ],
 199   'last group-entry via self-join works',
 200 );
 201
 202 is_deeply (
 203   [map { $_->last_track->id } grep { $_->last_track } $schema->resultset('CD')->search ({}, { order_by => 'cdid', prefetch => 'last_track'})->all],
 204   [ map { $_->trackid } @last_tracks ],
 205   'last_track via insane subquery condition works',
 206 );
 207
 208 is_deeply (
 209   [map { $_->last_track->id } grep { $_->last_track } $schema->resultset('CD')->search ({}, { order_by => 'cdid'})->all],
 210   [ map { $_->trackid } @last_tracks ],
 211   'last_track via insane subquery condition works, even without prefetch',
 212 );
 213
 214 my $artwork = $schema->resultset('Artwork')->search({},{ order_by => 'cd_id' })->first;
 215 my @artists = $artwork->artists->all;
 216 is(scalar @artists, 2, 'the two artists are associated');
 217
 218 my @artwork_artists = $artwork->artwork_to_artist->all;
 219 foreach (@artwork_artists) {
 220   lives_ok {
 221     my $artista = $_->artist;
 222     my $artistb = $_->artist_test_m2m;
 223     ok($artista->rank < 10 ? $artistb : 1, 'belongs_to with custom rel works.');
 224     my $artistc = $_->artist_test_m2m_noopt;
 225     ok($artista->rank < 10 ? $artistc : 1, 'belongs_to with custom rel works even in non-simplified.');
 226   } 'belongs_to works with custom rels';
 227 }
 228
 229 @artists = ();
 230 lives_ok {
 231   @artists = $artwork->artists_test_m2m2->all;
 232 } 'manytomany with extended rels in the has many works';
 233 is(scalar @artists, 2, 'two artists');
 234
 235 @artists = ();
 236 lives_ok {
 237   @artists = $artwork->artists_test_m2m->all;
 238 } 'can fetch many to many with optimized version';
 239 is(scalar @artists, 1, 'only one artist is associated');
 240
 241 @artists = ();
 242 lives_ok {
 243   @artists = $artwork->artists_test_m2m_noopt->all;
 244 } 'can fetch many to many with non-optimized version';
 245 is(scalar @artists, 1, 'only one artist is associated');
 246
 247
 248 # Make a single for each last_track
 249 my @singles = map {
 250   $_->create_related('cd_single', {
 251     title => $_->title . ' (the single)',
 252     artist => $artist,
 253     year => 1999,
 254   }) } @last_tracks
 255 ;
 256
 257 # See if chaining works
 258 is_deeply (
 259   [ map { $_->title } $last_tracks_rs->search_related('cd_single')->all ],
 260   [ map { $_->title } @singles ],
 261   'Retrieved singles in proper order'
 262 );
 263
 264 # See if prefetch works
 265 is_deeply (
 266   [ map { $_->cd_single->title } $last_tracks_rs->search({}, { prefetch => 'cd_single' })->all ],
 267   [ map { $_->title } @singles ],
 268   'Prefetched singles in proper order'
 269 );
 270
 271 done_testing;