t/relationship/core.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9
  10 my $schema = DBICTest->init_schema();
  11 my $sdebug = $schema->storage->debug;
  12
  13 # has_a test
  14 my $cd = $schema->resultset("CD")->find(4);
  15 my ($artist) = ($INC{'DBICTest/HelperRels'}
  16                   ? $cd->artist
  17                   : $cd->search_related('artist'));
  18 is($artist->name, 'Random Boy Band', 'has_a search_related ok');
  19
  20 # has_many test with an order_by clause defined
  21 $artist = $schema->resultset("Artist")->find(1);
  22 my @cds = ($INC{'DBICTest/HelperRels'}
  23              ? $artist->cds
  24              : $artist->search_related('cds'));
  25 is( $cds[1]->title, 'Spoonful of bees', 'has_many search_related with order_by ok' );
  26
  27 # search_related with additional abstract query
  28 @cds = ($INC{'DBICTest/HelperRels'}
  29           ? $artist->cds({ title => { like => '%of%' } })
  30           : $artist->search_related('cds', { title => { like => '%of%' } } )
  31        );
  32 is( $cds[1]->title, 'Forkful of bees', 'search_related with abstract query ok' );
  33
  34 # creating a related object
  35 if ($INC{'DBICTest/HelperRels.pm'}) {
  36   $artist->add_to_cds({ title => 'Big Flop', year => 2005 });
  37 } else {
  38   my $big_flop = $artist->create_related( 'cds', {
  39       title => 'Big Flop',
  40       year => 2005,
  41   } );
  42 }
  43
  44 my $big_flop_cd = ($artist->search_related('cds'))[3];
  45 is( $big_flop_cd->title, 'Big Flop', 'create_related ok' );
  46
  47 { # make sure we are not making pointless select queries when a FK IS NULL
  48   my $queries = 0;
  49   $schema->storage->debugcb(sub { $queries++; });
  50   $schema->storage->debug(1);
  51   $big_flop_cd->genre; #should not trigger a select query
  52   is($queries, 0, 'No SELECT made for belongs_to if key IS NULL');
  53   $big_flop_cd->genre_inefficient; #should trigger a select query
  54   is($queries, 1, 'SELECT made for belongs_to if key IS NULL when undef_on_null_fk disabled');
  55   $schema->storage->debug($sdebug);
  56   $schema->storage->debugcb(undef);
  57 }
  58
  59 my( $rs_from_list ) = $artist->search_related_rs('cds');
  60 isa_ok( $rs_from_list, 'DBIx::Class::ResultSet', 'search_related_rs in list context returns rs' );
  61
  62 ( $rs_from_list ) = $artist->cds_rs();
  63 isa_ok( $rs_from_list, 'DBIx::Class::ResultSet', 'relation_rs in list context returns rs' );
  64
  65 # count_related
  66 is( $artist->count_related('cds'), 4, 'count_related ok' );
  67
  68 # set_from_related
  69 my $track = $schema->resultset("Track")->create( {
  70   trackid => 1,
  71   cd => 3,
  72   position => 98,
  73   title => 'Hidden Track'
  74 } );
  75 $track->set_from_related( cd => $cd );
  76
  77 # has_relationship
  78 ok(! $track->has_relationship( 'foo' ), 'Track has no relationship "foo"');
  79 ok($track->has_relationship( 'disc' ), 'Track has relationship "disk"' );
  80
  81 is($track->disc->cdid, 4, 'set_from_related ok, including alternative accessor' );
  82
  83 $track->set_from_related( cd => undef );
  84
  85 ok( !defined($track->cd), 'set_from_related with undef ok');
  86
  87 $track = $schema->resultset("Track")->new( {} );
  88 $track->cd;
  89 $track->set_from_related( cd => $cd );
  90 ok ($track->cd, 'set_from_related ok after using the accessor' );
  91
  92 # update_from_related, the same as set_from_related, but it calls update afterwards
  93 $track = $schema->resultset("Track")->create( {
  94   trackid => 2,
  95   cd => 3,
  96   title => 'Hidden Track 2'
  97 } );
  98 $track->update_from_related( cd => $cd );
  99
 100 my $t_cd = ($schema->resultset("Track")->search({ cd => 4, title => 'Hidden Track 2' }))[0]->cd;
 101
 102 is( $t_cd->cdid, 4, 'update_from_related ok' );
 103
 104 # find_or_create_related with an existing record
 105 $cd = $artist->find_or_create_related( 'cds', { title => 'Big Flop' } );
 106 is( $cd->year, 2005, 'find_or_create_related on existing record ok' );
 107
 108 # find_or_create_related creating a new record
 109 $cd = $artist->find_or_create_related( 'cds', {
 110   title => 'Greatest Hits',
 111   year => 2006,
 112 } );
 113 is( $cd->title, 'Greatest Hits', 'find_or_create_related new record ok' );
 114
 115 @cds = $artist->search_related('cds');
 116 is( ($artist->search_related('cds'))[4]->title, 'Greatest Hits', 'find_or_create_related new record search ok' );
 117
 118 $artist->delete_related( cds => { title => 'Greatest Hits' });
 119 cmp_ok( $schema->resultset("CD")->search({ title => 'Greatest Hits' }), '==', 0, 'delete_related ok' );
 120
 121 # find_or_new_related with an existing record
 122 $cd = $artist->find_or_new_related( 'cds', { title => 'Big Flop' } );
 123 is( $cd->year, 2005, 'find_or_new_related on existing record ok' );
 124 ok( $cd->in_storage, 'find_or_new_related on existing record: is in_storage' );
 125
 126 # find_or_new_related instantiating a new record
 127 $cd = $artist->find_or_new_related( 'cds', {
 128   title => 'Greatest Hits 2: Louder Than Ever',
 129   year => 2007,
 130 } );
 131 is( $cd->title, 'Greatest Hits 2: Louder Than Ever', 'find_or_new_related new record ok' );
 132 is( $cd->in_storage, 0, 'find_or_new_related on a new record: not in_storage' );
 133
 134 $cd->artist(undef);
 135 my $newartist = $cd->find_or_new_related( 'artist', {
 136   name => 'Random Boy Band Two',
 137   artistid => 200,
 138 } );
 139 is($newartist->name, 'Random Boy Band Two', 'find_or_new_related new artist record with id');
 140 is($newartist->id, 200, 'find_or_new_related new artist id set');
 141
 142 lives_ok(
 143     sub {
 144         my $new_bookmark = $schema->resultset("Bookmark")->new_result( {} );
 145         my $new_related_link = $new_bookmark->new_related( 'link', {} );
 146     },
 147     'No back rel'
 148 );
 149
 150
 151 {
 152   local $TODO = "relationship checking needs fixing";
 153   # try to add a bogus relationship using the wrong cols
 154   throws_ok {
 155       DBICTest::Schema::Artist->add_relationship(
 156           tracks => 'DBICTest::Schema::Track',
 157           { 'foreign.cd' => 'self.cdid' }
 158       );
 159   } qr/Unknown column/, 'failed when creating a rel with invalid key, ok';
 160 }
 161
 162 # another bogus relationship using no join condition
 163 throws_ok {
 164     DBICTest::Schema::Artist->add_relationship( tracks => 'DBICTest::Track' );
 165 } qr/join condition/, 'failed when creating a rel without join condition, ok';
 166
 167 # many_to_many helper tests
 168 $cd = $schema->resultset("CD")->find(1);
 169 my @producers = $cd->producers();
 170 is( $producers[0]->name, 'Matt S Trout', 'many_to_many ok' );
 171 is( $cd->producers_sorted->next->name, 'Bob The Builder',
 172     'sorted many_to_many ok' );
 173 is( $cd->producers_sorted({producerid => 3})->next->name, 'Fred The Phenotype',
 174     'sorted many_to_many with search condition ok' );
 175
 176 $cd = $schema->resultset('CD')->find(2);
 177 my $prod_rs = $cd->producers();
 178 my $prod_before_count = $schema->resultset('Producer')->count;
 179 is( $prod_rs->count, 0, "CD doesn't yet have any producers" );
 180 my $prod = $schema->resultset('Producer')->find(1);
 181 $cd->add_to_producers($prod);
 182 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($obj) count ok' );
 183 is( $prod_rs->first->name, 'Matt S Trout',
 184     'many_to_many add_to_$rel($obj) ok' );
 185 $cd->remove_from_producers($prod);
 186 $cd->add_to_producers($prod, {attribute => 1});
 187 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($obj, $link_vals) count ok' );
 188 is( $cd->cd_to_producer->first->attribute, 1, 'many_to_many $link_vals ok');
 189 $cd->remove_from_producers($prod);
 190 $cd->set_producers([$prod], {attribute => 2});
 191 is( $prod_rs->count(), 1, 'many_to_many set_$rel($obj, $link_vals) count ok' );
 192 is( $cd->cd_to_producer->first->attribute, 2, 'many_to_many $link_vals ok');
 193 $cd->remove_from_producers($prod);
 194 is( $schema->resultset('Producer')->find(1)->name, 'Matt S Trout',
 195     "producer object exists after remove of link" );
 196 is( $prod_rs->count, 0, 'many_to_many remove_from_$rel($obj) ok' );
 197 $cd->add_to_producers({ name => 'Testy McProducer' });
 198 is( $schema->resultset('Producer')->count, $prod_before_count+1,
 199     'add_to_$rel($hash) inserted a new producer' );
 200 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($hash) count ok' );
 201 is( $prod_rs->first->name, 'Testy McProducer',
 202     'many_to_many add_to_$rel($hash) ok' );
 203 $cd->add_to_producers({ name => 'Jack Black' });
 204 is( $prod_rs->count(), 2, 'many_to_many add_to_$rel($hash) count ok' );
 205 $cd->set_producers($schema->resultset('Producer')->all);
 206 is( $cd->producers->count(), $prod_before_count+2,
 207     'many_to_many set_$rel(@objs) count ok' );
 208 $cd->set_producers($schema->resultset('Producer')->find(1));
 209 is( $cd->producers->count(), 1, 'many_to_many set_$rel($obj) count ok' );
 210 $cd->set_producers([$schema->resultset('Producer')->all]);
 211 is( $cd->producers->count(), $prod_before_count+2,
 212     'many_to_many set_$rel(\@objs) count ok' );
 213 $cd->set_producers([$schema->resultset('Producer')->find(1)]);
 214 is( $cd->producers->count(), 1, 'many_to_many set_$rel([$obj]) count ok' );
 215
 216 throws_ok {
 217   $cd->remove_from_producers({ fake => 'hash' })
 218 } qr/needs an object/, 'remove_from_$rel($hash) dies correctly';
 219
 220 throws_ok {
 221   $cd->add_to_producers()
 222 } qr/needs an object or hashref/, 'add_to_$rel(undef) dies correctly';
 223
 224 # many_to_many stresstest
 225 my $twokey = $schema->resultset('TwoKeys')->find(1,1);
 226 my $fourkey = $schema->resultset('FourKeys')->find(1,2,3,4);
 227
 228 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 229 $twokey->add_to_fourkeys($fourkey, { autopilot => 'engaged' });
 230 my $got_fourkey = $twokey->fourkeys({ sensors => 'online' })->first;
 231 is( $twokey->fourkeys->count, 1, 'twokey has one fourkey' );
 232 is( $got_fourkey->$_, $fourkey->$_,
 233     'fourkeys row has the correct value for column '.$_ )
 234   for (qw(foo bar hello goodbye sensors));
 235 $twokey->remove_from_fourkeys($fourkey);
 236 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 237 is( $twokey->fourkeys_to_twokeys->count, 0,
 238     'twokey has no links to fourkey' );
 239
 240
 241 my $undef_artist_cd = $schema->resultset("CD")->new_result({ 'title' => 'badgers', 'year' => 2007 });
 242 is($undef_artist_cd->has_column_loaded('artist'), '', 'FK not loaded');
 243 is($undef_artist_cd->search_related('artist')->count, 0, '0=1 search when FK does not exist and object not yet in db');
 244 lives_ok {
 245      $undef_artist_cd->related_resultset('artist')->new({name => 'foo'});
 246 } 'Object created on a resultset related to not yet inserted object';
 247 lives_ok{
 248   $schema->resultset('Artwork')->new_result({})->cd;
 249 } 'undef_on_null_fk does not choke on empty conds';
 250
 251 my $def_artist_cd = $schema->resultset("CD")->new_result({ 'title' => 'badgers', 'year' => 2007, artist => undef });
 252 is($def_artist_cd->has_column_loaded('artist'), 1, 'FK loaded');
 253 is($def_artist_cd->search_related('artist')->count, 0, 'closed search on null FK');
 254
 255 # test undirected many-to-many relationship (e.g. "related artists")
 256 my $undir_maps = $schema->resultset("Artist")
 257                           ->search ({artistid => 1})
 258                             ->search_related ('artist_undirected_maps');
 259 is($undir_maps->count, 1, 'found 1 undirected map for artist 1');
 260 is_same_sql_bind (
 261   $undir_maps->as_query,
 262   '(
 263     SELECT artist_undirected_maps.id1, artist_undirected_maps.id2
 264       FROM artist me
 265       JOIN artist_undirected_map artist_undirected_maps
 266         ON artist_undirected_maps.id1 = me.artistid OR artist_undirected_maps.id2 = me.artistid
 267     WHERE ( artistid = ? )
 268   )',
 269   [[ { sqlt_datatype => 'integer', dbic_colname => 'artistid' }
 270       => 1 ]],
 271   'expected join sql produced',
 272 );
 273
 274 $undir_maps = $schema->resultset("Artist")->find(2)->artist_undirected_maps;
 275 is($undir_maps->count, 1, 'found 1 undirected map for artist 2');
 276
 277 my $mapped_rs = $undir_maps->search_related('mapped_artists');
 278
 279 my @art = $mapped_rs->all;
 280
 281 cmp_ok(@art, '==', 2, "Both artist returned from map");
 282
 283 my $searched = $mapped_rs->search({'mapped_artists.artistid' => {'!=', undef}});
 284
 285 cmp_ok($searched->count, '==', 2, "Both artist returned from map after adding another condition");
 286
 287 # check join through cascaded has_many relationships (also empty has_many rels)
 288 $artist = $schema->resultset("Artist")->find(1);
 289 my $trackset = $artist->cds->search_related('tracks');
 290 is($trackset->count, 10, "Correct number of tracks for artist");
 291 is($trackset->all, 10, "Correct number of track objects for artist");
 292
 293 # now see about updating eveything that belongs to artist 2 to artist 3
 294 $artist = $schema->resultset("Artist")->find(2);
 295 my $nartist = $schema->resultset("Artist")->find(3);
 296 cmp_ok($artist->cds->count, '==', 1, "Correct orig #cds for artist");
 297 cmp_ok($nartist->cds->count, '==', 1, "Correct orig #cds for artist");
 298 $artist->cds->update({artist => $nartist->id});
 299 cmp_ok($artist->cds->count, '==', 0, "Correct new #cds for artist");
 300 cmp_ok($nartist->cds->count, '==', 2, "Correct new #cds for artist");
 301
 302 # check if is_foreign_key_constraint attr is set
 303 my $rs_normal = $schema->source('Track');
 304 my $relinfo = $rs_normal->relationship_info ('cd');
 305 cmp_ok($relinfo->{attrs}{is_foreign_key_constraint}, '==', 1, "is_foreign_key_constraint defined for belongs_to relationships.");
 306
 307 my $rs_overridden = $schema->source('ForceForeign');
 308 my $relinfo_with_attr = $rs_overridden->relationship_info ('cd_3');
 309 cmp_ok($relinfo_with_attr->{attrs}{is_foreign_key_constraint}, '==', 0, "is_foreign_key_constraint defined for belongs_to relationships with attr.");
 310
 311 # check that relationships below left join relationships are forced to left joins
 312 # when traversing multiple belongs_to
 313 my $cds = $schema->resultset("CD")->search({ 'me.cdid' => 5 }, { join => { single_track => 'cd' } });
 314 is($cds->count, 1, "subjoins under left joins force_left (string)");
 315
 316 $cds = $schema->resultset("CD")->search({ 'me.cdid' => 5 }, { join => { single_track => ['cd'] } });
 317 is($cds->count, 1, "subjoins under left joins force_left (arrayref)");
 318
 319 $cds = $schema->resultset("CD")->search({ 'me.cdid' => 5 }, { join => { single_track => { cd => {} } } });
 320 is($cds->count, 1, "subjoins under left joins force_left (hashref)");
 321
 322 done_testing;