t/prefetch/grouped.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4
   5 use lib qw(t/lib);
   6 use DBICTest;
   7 use DBIC::SqlMakerTest;
   8
   9 #plan tests => 6;
  10 plan 'no_plan';
  11
  12 my $schema = DBICTest->init_schema();
  13
  14 my $cd_rs = $schema->resultset('CD')->search (
  15   { 'tracks.cd' => { '!=', undef } },
  16   { prefetch => 'tracks' },
  17 );
  18
  19 # Database sanity check
  20 is($cd_rs->count, 5, 'CDs with tracks count');
  21 for ($cd_rs->all) {
  22   is ($_->tracks->count, 3, '3 tracks for CD' . $_->id );
  23 }
  24
  25 # Test a belongs_to prefetch of a has_many
  26 {
  27   my $track_rs = $schema->resultset ('Track')->search (
  28     { 'me.cd' => { -in => [ $cd_rs->get_column ('cdid')->all ] } },
  29     {
  30       # the select/as is deliberately silly to test both funcs and refs below
  31       select => [
  32         'me.cd',
  33         \ 'COUNT (me.trackid) AS track_count',
  34         { count => 'me.trackid' },
  35       ],
  36       as => [qw/
  37         cd
  38         track_count
  39         track_count_2
  40       /],
  41       group_by => [qw/me.cd/],
  42       prefetch => 'cd',
  43     },
  44   );
  45
  46   is($track_rs->count, 5, 'Prefetched count with groupby');
  47   is($track_rs->all, 5, 'Prefetched objects with groupby');
  48
  49   {
  50     my $query_cnt = 0;
  51     $schema->storage->debugcb ( sub { $query_cnt++ } );
  52
  53     $track_rs->reset;
  54     while (my $collapsed_track = $track_rs->next) {
  55
  56       my $cdid = $collapsed_track->get_column('cd');
  57       is($collapsed_track->get_column('track_count'), 3, "Correct count of tracks for CD $cdid" );
  58       ok($collapsed_track->cd->title, "Prefetched title for CD $cdid" );
  59     }
  60
  61     is ($query_cnt, 0, 'No queries on prefetched titles');
  62     $schema->storage->debugcb (undef);
  63   }
  64
  65   # Test sql by hand, as the sqlite db will simply paper over
  66   # improper group/select combinations
  67   #
  68   # the exploded IN needs fixing below, coming in another branch
  69   #
  70   is_same_sql_bind (
  71     $track_rs->count_rs->as_query,
  72     '(
  73       SELECT COUNT( * )
  74         FROM (
  75           SELECT me.cd
  76             FROM track me
  77             JOIN cd cd ON cd.cdid = me.cd
  78           WHERE ( me.cd IN ( ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ? ) )
  79           GROUP BY me.cd
  80         )
  81       count_subq
  82     )',
  83     [ map { [ 'me.cd' => $_] } ($cd_rs->get_column ('cdid')->all) ],
  84     'count() query generated expected SQL',
  85   );
  86
  87   # the double-count is deliberate
  88   is_same_sql_bind (
  89     $track_rs->as_query,
  90     '(
  91       SELECT me.cd, me.track_count, me.track_count_2, cd.cdid, cd.artist, cd.title, cd.year, cd.genreid, cd.single_track
  92         FROM (
  93           SELECT me.cd, COUNT (me.trackid) AS track_count, COUNT (me.trackid) AS track_count_2
  94             FROM track me
  95           WHERE ( cd IN ( ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ? ) )
  96           GROUP BY me.cd
  97           ) as me
  98         JOIN cd cd ON cd.cdid = me.cd
  99       WHERE ( me.cd IN ( ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ? ) )
 100     )',
 101     [ map { [ 'me.cd' => $_] } ($cd_rs->get_column ('cdid')->all) ],
 102     'next() query generated expected SQL',
 103   );
 104
 105
 106   # add an extra track to one of the cds, and then make sure we can get it on top
 107   # (check if limit works)
 108   my $top_cd = $cd_rs->slice (1,1)->next;
 109   $top_cd->create_related ('tracks', {
 110     title => 'over the top',
 111   });
 112
 113   my $top_cd_collapsed_track = $track_rs->search ({}, {
 114     rows => 2,
 115     order_by => [
 116       { -desc => 'track_count' },
 117     ],
 118   });
 119
 120   is ($top_cd_collapsed_track->count, 2);
 121
 122   is (
 123     $top_cd->title,
 124     $top_cd_collapsed_track->first->cd->title,
 125     'Correct collapsed track with prefetched CD returned on top'
 126   );
 127 }
 128
 129 # test a has_many/might_have prefetch at the same level
 130 # double-count for now, until we figure out how to do this cleanly
 131 # with a function
 132 # Note that one of the CDs now has 4 tracks instead of 3
 133 {
 134   my $most_tracks_rs = $cd_rs->search ({}, {
 135     prefetch => 'liner_notes',  # tracks are alredy prefetched
 136     select => ['me.cdid', { count => 'tracks.trackid' } ],
 137     as => [qw/cdid track_count/],
 138     group_by => 'me.cdid',
 139     order_by => { -desc => \ 'COUNT (tracks.trackid)' },
 140     rows => 2,
 141   });
 142
 143   is_same_sql_bind (
 144     $most_tracks_rs->count_rs->as_query,
 145     '(
 146       SELECT COUNT( * )
 147         FROM (
 148           SELECT me.cdid
 149             FROM cd me
 150             LEFT JOIN track tracks ON tracks.cd = me.cdid
 151             LEFT JOIN liner_notes liner_notes ON liner_notes.liner_id = me.cdid
 152           WHERE ( tracks.cd IS NOT NULL )
 153           GROUP BY me.cdid
 154           LIMIT 2
 155         ) count_subq
 156     )',
 157     [],
 158     'count() query generated expected SQL',
 159   );
 160
 161   is_same_sql_bind (
 162     $most_tracks_rs->as_query,
 163     '(
 164       SELECT me.cdid, COUNT( tracks.trackid ), tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at, liner_notes.liner_id, liner_notes.notes
 165         FROM (
 166           SELECT me.cdid, COUNT( tracks.trackid )
 167             FROM cd me
 168             LEFT JOIN track tracks ON tracks.cd = me.cdid
 169           WHERE ( tracks.cd IS NOT NULL )
 170           GROUP BY me.cdid
 171           ORDER BY COUNT (tracks.trackid) DESC,
 172           LIMIT 2
 173         ) me
 174         LEFT JOIN track tracks ON tracks.cd = me.cdid
 175         LEFT JOIN liner_notes liner_notes ON liner_notes.liner_id = me.cdid
 176       WHERE ( tracks.cd IS NOT NULL )
 177       ORDER BY COUNT (tracks.trackid) DESC, tracks.cd
 178     )',
 179     [],
 180     'next() query generated expected SQL',
 181   );
 182
 183   is ($most_tracks_rs->count, 2, 'Limit works');
 184   my $top_cd = $most_tracks_rs->first;
 185   is ($top_cd->id, 2, 'Correct cd fetched on top'); # 2 because of the slice(1,1) above
 186
 187   my $query_cnt = 0;
 188   $schema->storage->debugcb ( sub { $query_cnt++ } );
 189
 190   is ($top_cd->get_column ('track_count'), 4, 'Track count fetched correctly');
 191   is ($top_cd->tracks->count, 4, 'Count of prefetched tracks rs still correct');
 192   is ($top_cd->tracks->all, 4, 'Number of prefetched track objects still correct');
 193   is (
 194     $top_cd->liner_notes->notes,
 195     'Buy Whiskey!',
 196     'Correct liner pre-fetched with top cd',
 197   );
 198
 199   is ($query_cnt, 0, 'No queries executed during prefetched data access');
 200   $schema->storage->debugcb (undef);
 201 }