t/prefetch/correlated.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9
  10 my $schema = DBICTest->init_schema();
  11 my $orig_debug = $schema->storage->debug;
  12
  13 my $cdrs = $schema->resultset('CD')->search({ 'me.artist' => { '!=', 2 }});
  14
  15 my $cd_data = { map {
  16   $_->cdid => {
  17     siblings => $cdrs->search ({ artist => $_->get_column('artist') })->count - 1,
  18     track_titles => [ map { $_->title } ($_->tracks->all) ],
  19   },
  20 } ( $cdrs->all ) };
  21
  22 my $c_rs = $cdrs->search ({}, {
  23   prefetch => 'tracks',
  24   '+columns' => { sibling_count => $cdrs->search(
  25       {
  26         'siblings.artist' => { -ident => 'me.artist' },
  27         'siblings.cdid' => { '!=' => ['-and', { -ident => 'me.cdid' }, 23414] },
  28       }, { alias => 'siblings' },
  29     )->count_rs->as_query,
  30   },
  31 });
  32
  33 is_same_sql_bind(
  34   $c_rs->as_query,
  35   '(
  36     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
  37            (SELECT COUNT( * )
  38               FROM cd siblings
  39             WHERE siblings.artist = me.artist
  40               AND siblings.cdid != me.cdid
  41               AND siblings.cdid != ?
  42               AND me.artist != ?
  43            ),
  44            tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
  45       FROM cd me
  46       LEFT JOIN track tracks
  47         ON tracks.cd = me.cdid
  48     WHERE me.artist != ?
  49     ORDER BY tracks.cd
  50   )',
  51   [
  52
  53     # subselect
  54     [ { sqlt_datatype => 'integer', dbic_colname => 'siblings.cdid' }
  55       => 23414 ],
  56
  57     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
  58       => 2 ],
  59
  60     # outher WHERE
  61     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
  62       => 2 ],
  63   ],
  64   'Expected SQL on correlated realiased subquery'
  65 );
  66
  67 my $queries = 0;
  68 $schema->storage->debugcb(sub { $queries++; });
  69 $schema->storage->debug(1);
  70
  71 is_deeply (
  72   { map
  73     { $_->cdid => {
  74       track_titles => [ map { $_->title } ($_->tracks->all) ],
  75       siblings => $_->get_column ('sibling_count'),
  76     } }
  77     $c_rs->all
  78   },
  79   $cd_data,
  80   'Proper information retrieved from correlated subquery'
  81 );
  82
  83 is ($queries, 1, 'Only 1 query fired to retrieve everything');
  84
  85 $schema->storage->debug($orig_debug);
  86 $schema->storage->debugcb(undef);
  87
  88 # now add an unbalanced select/as pair
  89 $c_rs = $c_rs->search ({}, {
  90   '+select' => $cdrs->search(
  91     { 'siblings.artist' => { -ident => 'me.artist' } },
  92     { alias => 'siblings', columns => [
  93       { first_year => { min => 'year' }},
  94       { last_year => { max => 'year' }},
  95     ]},
  96   )->as_query,
  97   '+as' => [qw/active_from active_to/],
  98 });
  99
 100 is_same_sql_bind(
 101   $c_rs->as_query,
 102   '(
 103     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
 104            (SELECT COUNT( * )
 105               FROM cd siblings
 106             WHERE siblings.artist = me.artist
 107               AND siblings.cdid != me.cdid
 108               AND siblings.cdid != ?
 109               AND me.artist != ?
 110            ),
 111            (SELECT MIN( year ), MAX( year )
 112               FROM cd siblings
 113             WHERE siblings.artist = me.artist
 114               AND me.artist != ?
 115            ),
 116            tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
 117       FROM cd me
 118       LEFT JOIN track tracks
 119         ON tracks.cd = me.cdid
 120     WHERE me.artist != ?
 121     ORDER BY tracks.cd
 122   )',
 123   [
 124
 125     # first subselect
 126     [ { sqlt_datatype => 'integer', dbic_colname => 'siblings.cdid' }
 127       => 23414 ],
 128
 129     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
 130       => 2 ],
 131
 132     # second subselect
 133     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
 134       => 2 ],
 135
 136     # outher WHERE
 137     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
 138       => 2 ],
 139   ],
 140   'Expected SQL on correlated realiased subquery'
 141 );
 142
 143 done_testing;