t/prefetch/correlated.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7 use DBIC::SqlMakerTest;
   8
   9 my $schema = DBICTest->init_schema();
  10 my $orig_debug = $schema->storage->debug;
  11
  12 my $cdrs = $schema->resultset('CD')->search({ 'me.artist' => { '!=', 2 }});
  13
  14 my $cd_data = { map {
  15   $_->cdid => {
  16     siblings => $cdrs->search ({ artist => $_->get_column('artist') })->count - 1,
  17     track_titles => [ map { $_->title } ($_->tracks->all) ],
  18   },
  19 } ( $cdrs->all ) };
  20
  21 my $c_rs = $cdrs->search ({}, {
  22   prefetch => 'tracks',
  23   '+columns' => { sibling_count => $cdrs->search(
  24       {
  25         'siblings.artist' => { -ident => 'me.artist' },
  26         'siblings.cdid' => { '!=' => ['-and', { -ident => 'me.cdid' }, 23414] },
  27       }, { alias => 'siblings' },
  28     )->count_rs->as_query,
  29   },
  30 });
  31
  32 is_same_sql_bind(
  33   $c_rs->as_query,
  34   '(
  35     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
  36            (SELECT COUNT( * )
  37               FROM cd siblings
  38             WHERE siblings.artist = me.artist
  39               AND siblings.cdid != me.cdid
  40               AND siblings.cdid != ?
  41               AND me.artist != ?
  42            ),
  43            tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
  44       FROM cd me
  45       LEFT JOIN track tracks
  46         ON tracks.cd = me.cdid
  47     WHERE me.artist != ?
  48   )',
  49   [
  50
  51     # subselect
  52     [ { sqlt_datatype => 'integer', dbic_colname => 'siblings.cdid' }
  53       => 23414 ],
  54
  55     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
  56       => 2 ],
  57
  58     # outher WHERE
  59     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
  60       => 2 ],
  61   ],
  62   'Expected SQL on correlated realiased subquery'
  63 );
  64
  65 my $queries = 0;
  66 $schema->storage->debugcb(sub { $queries++; });
  67 $schema->storage->debug(1);
  68
  69 is_deeply (
  70   { map
  71     { $_->cdid => {
  72       track_titles => [ map { $_->title } ($_->tracks->all) ],
  73       siblings => $_->get_column ('sibling_count'),
  74     } }
  75     $c_rs->all
  76   },
  77   $cd_data,
  78   'Proper information retrieved from correlated subquery'
  79 );
  80
  81 is ($queries, 1, 'Only 1 query fired to retrieve everything');
  82
  83 $schema->storage->debug($orig_debug);
  84 $schema->storage->debugcb(undef);
  85
  86 # now add an unbalanced select/as pair
  87 $c_rs = $c_rs->search ({}, {
  88   '+select' => $cdrs->search(
  89     { 'siblings.artist' => { -ident => 'me.artist' } },
  90     { alias => 'siblings', columns => [
  91       { first_year => { min => 'year' }},
  92       { last_year => { max => 'year' }},
  93     ]},
  94   )->as_query,
  95   '+as' => [qw/active_from active_to/],
  96 });
  97
  98 is_same_sql_bind(
  99   $c_rs->as_query,
 100   '(
 101     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
 102            (SELECT COUNT( * )
 103               FROM cd siblings
 104             WHERE siblings.artist = me.artist
 105               AND siblings.cdid != me.cdid
 106               AND siblings.cdid != ?
 107               AND me.artist != ?
 108            ),
 109            (SELECT MIN( year ), MAX( year )
 110               FROM cd siblings
 111             WHERE siblings.artist = me.artist
 112               AND me.artist != ?
 113            ),
 114            tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
 115       FROM cd me
 116       LEFT JOIN track tracks
 117         ON tracks.cd = me.cdid
 118     WHERE me.artist != ?
 119   )',
 120   [
 121
 122     # first subselect
 123     [ { sqlt_datatype => 'integer', dbic_colname => 'siblings.cdid' }
 124       => 23414 ],
 125
 126     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
 127       => 2 ],
 128
 129     # second subselect
 130     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
 131       => 2 ],
 132
 133     # outher WHERE
 134     [ { sqlt_datatype => 'integer', dbic_colname => 'me.artist' }
 135       => 2 ],
 136   ],
 137   'Expected SQL on correlated realiased subquery'
 138 );
 139
 140 done_testing;