t/lib/DBICTest/Util/LeakTracer.pm

   1 package DBICTest::Util::LeakTracer;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Carp;
   7 use Scalar::Util qw(isweak weaken blessed reftype);
   8 use DBIx::Class::_Util 'refcount';
   9 use DBIx::Class::Optional::Dependencies;
  10 use Data::Dumper::Concise;
  11 use DBICTest::Util 'stacktrace';
  12 use constant {
  13   CV_TRACING => DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy'),
  14   SKIP_SCALAR_REFS => ( $] > 5.017 ) ? 1 : 0,
  15 };
  16
  17 use base 'Exporter';
  18 our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry hrefaddr visit_refs);
  19
  20 my $refs_traced = 0;
  21 my $leaks_found = 0;
  22 my %reg_of_regs;
  23
  24 sub hrefaddr { sprintf '0x%x', &Scalar::Util::refaddr }
  25
  26 # so we don't trigger stringification
  27 sub _describe_ref {
  28   sprintf '%s%s(%s)',
  29     (defined blessed $_[0]) ? blessed($_[0]) . '=' : '',
  30     reftype $_[0],
  31     hrefaddr $_[0],
  32   ;
  33 }
  34
  35 sub populate_weakregistry {
  36   my ($weak_registry, $target, $note) = @_;
  37
  38   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
  39   croak 'Target is not a reference' unless length ref $target;
  40
  41   my $refaddr = hrefaddr $target;
  42
  43   # a registry could be fed to itself or another registry via recursive sweeps
  44   return $target if $reg_of_regs{$refaddr};
  45
  46   weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
  47     unless( $reg_of_regs{ hrefaddr($weak_registry) } );
  48
  49   # an explicit "garbage collection" pass every time we store a ref
  50   # if we do not do this the registry will keep growing appearing
  51   # as if the traced program is continuously slowly leaking memory
  52   for my $reg (values %reg_of_regs) {
  53     (defined $reg->{$_}{weakref}) or delete $reg->{$_}
  54       for keys %$reg;
  55   }
  56
  57   # FIXME/INVESTIGATE - something fishy is going on with refs to plain
  58   # strings, perhaps something to do with the CoW work etc...
  59   return $target if SKIP_SCALAR_REFS and reftype($target) eq 'SCALAR';
  60
  61   if (! defined $weak_registry->{$refaddr}{weakref}) {
  62     $weak_registry->{$refaddr} = {
  63       stacktrace => stacktrace(1),
  64       weakref => $target,
  65     };
  66     weaken( $weak_registry->{$refaddr}{weakref} );
  67     $refs_traced++;
  68   }
  69
  70   my $desc = _describe_ref($target);
  71   $weak_registry->{$refaddr}{slot_names}{$desc} = 1;
  72   if ($note) {
  73     $note =~ s/\s*\Q$desc\E\s*//g;
  74     $weak_registry->{$refaddr}{slot_names}{$note} = 1;
  75   }
  76
  77   $target;
  78 }
  79
  80 # Regenerate the slots names on a thread spawn
  81 sub CLONE {
  82   my @individual_regs = grep { scalar keys %{$_||{}} } values %reg_of_regs;
  83   %reg_of_regs = ();
  84
  85   for my $reg (@individual_regs) {
  86     my @live_slots = grep { defined $_->{weakref} } values %$reg
  87       or next;
  88
  89     $reg = {};  # get a fresh hashref in the new thread ctx
  90     weaken( $reg_of_regs{hrefaddr($reg)} = $reg );
  91
  92     for my $slot_info (@live_slots) {
  93       my $new_addr = hrefaddr $slot_info->{weakref};
  94
  95       # replace all slot names
  96       $slot_info->{slot_names} = { map {
  97         my $name = $_;
  98         $name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
  99         ($name => 1);
 100       } keys %{$slot_info->{slot_names}} };
 101
 102       $reg->{$new_addr} = $slot_info;
 103     }
 104   }
 105 }
 106
 107 sub visit_refs {
 108   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 109
 110   $args->{seen_refs} ||= {};
 111
 112   my $visited_cnt = '0E0';
 113   for my $i (0 .. $#{$args->{refs}} ) {
 114     next if isweak($args->{refs}[$i]);
 115
 116     my $r = $args->{refs}[$i];
 117
 118     next unless length ref $r;
 119
 120     next if $args->{seen_refs}{my $dec_addr = Scalar::Util::refaddr($r)}++;
 121
 122     $visited_cnt++;
 123     $args->{action}->($r) or next;
 124
 125     my $type = reftype $r;
 126     if ($type eq 'HASH') {
 127       $visited_cnt += visit_refs({ %$args, refs => [ map {
 128         ( !isweak($r->{$_}) ) ? $r->{$_} : ()
 129       } keys %$r ] });
 130     }
 131     elsif ($type eq 'ARRAY') {
 132       $visited_cnt += visit_refs({ %$args, refs => [ map {
 133         ( !isweak($r->[$_]) ) ? $r->[$_] : ()
 134       } 0..$#$r ] });
 135     }
 136     elsif ($type eq 'REF' and !isweak($$r)) {
 137       $visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
 138     }
 139     elsif (CV_TRACING and $type eq 'CODE') {
 140       $visited_cnt += visit_refs({ %$args, refs => [ map {
 141         ( !isweak($_) ) ? $_ : ()
 142       } scalar PadWalker::closed_over($r) ] }); # scalar due to RT#92269
 143     }
 144   }
 145   $visited_cnt;
 146 }
 147
 148 sub assert_empty_weakregistry {
 149   my ($weak_registry, $quiet) = @_;
 150
 151   # in case we hooked bless any extra object creation will wreak
 152   # havoc during the assert phase
 153   local *CORE::GLOBAL::bless;
 154   *CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() ) };
 155
 156   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
 157
 158   return unless keys %$weak_registry;
 159
 160   my $tb = eval { Test::Builder->new }
 161     or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";
 162
 163   for my $addr (keys %$weak_registry) {
 164     $weak_registry->{$addr}{display_name} = join ' | ', (
 165       sort
 166         { length $a <=> length $b or $a cmp $b }
 167         keys %{$weak_registry->{$addr}{slot_names}}
 168     );
 169
 170     $tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
 171       if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
 172   }
 173
 174   # compile a list of refs stored as globals (possibly even catching
 175   # class data in the form of method closures), so we can skip them
 176   # further on
 177   my ($seen_refs, $classdata_refs) = ({}, undef);
 178
 179   # the walk is very expensive - if we are $quiet (running in an END block)
 180   # we do not really need to be too thorough
 181   unless ($quiet) {
 182     my ($symwalker, $symcounts);
 183     $symwalker = sub {
 184       no strict 'refs';
 185       my $pkg = shift || '::';
 186
 187       # any non-weak globals are "clasdata" in all possible sense
 188       #
 189       # the unless regex at the end skips some dangerous namespaces outright
 190       # (but does not prevent descent)
 191       $symcounts->{$pkg} += visit_refs (
 192         seen_refs => $seen_refs,
 193         action => sub { ++$classdata_refs->{hrefaddr $_[0]} },
 194         refs => [ map { my $sym = $_;
 195           # *{"$pkg$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
 196           ( CV_TRACING ? Class::MethodCache::get_cv("${pkg}$sym") : () ),
 197
 198           ( defined *{"$pkg$sym"}{SCALAR} and length ref ${"$pkg$sym"} and ! isweak( ${"$pkg$sym"} ) )
 199             ? ${"$pkg$sym"} : ()
 200           ,
 201           ( map {
 202             ( defined *{"$pkg$sym"}{$_} and ! isweak(defined *{"$pkg$sym"}{$_}) )
 203               ? *{"$pkg$sym"}{$_}
 204               : ()
 205           } qw(HASH ARRAY IO GLOB) ),
 206         } keys %$pkg ],
 207       ) unless $pkg =~ /^ :: (?:
 208         DB | next | B | .+? ::::ISA (?: ::CACHE ) | Class::C3
 209       ) :: $/x;
 210
 211       $symwalker->("${pkg}$_") for grep { $_ =~ /(?<!^main)::$/ } keys %$pkg;
 212     };
 213
 214     $symwalker->();
 215
 216 #    use Devel::Dwarn;
 217 #    Ddie [ map
 218 #      { { $_ => $symcounts->{$_} } }
 219 #      sort
 220 #        {$symcounts->{$a} <=> $symcounts->{$b} }
 221 #        keys %$symcounts
 222 #    ];
 223   }
 224
 225   delete $weak_registry->{$_} for keys %$classdata_refs;
 226
 227   for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {
 228
 229     next if ! defined $weak_registry->{$addr}{weakref};
 230
 231     $leaks_found++ unless $tb->in_todo;
 232     $tb->ok (0, "Leaked $weak_registry->{$addr}{display_name}");
 233
 234     my $diag = do {
 235       local $Data::Dumper::Maxdepth = 1;
 236       sprintf "\n%s (refcnt %d) => %s\n",
 237         $weak_registry->{$addr}{display_name},
 238         refcount($weak_registry->{$addr}{weakref}),
 239         (
 240           ref($weak_registry->{$addr}{weakref}) eq 'CODE'
 241             and
 242           B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
 243         ) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
 244       ;
 245     };
 246
 247     # FIXME - need to add a circular reference seeker based on the visitor
 248     # (will need a bunch of modifications, punting with just a stub for now)
 249
 250     $diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
 251       if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
 252
 253     $diag =~ s/^/    /mg;
 254
 255     if (my $stack = $weak_registry->{$addr}{stacktrace}) {
 256       $diag .= "    Reference first seen$stack";
 257     }
 258
 259     $tb->diag($diag);
 260   }
 261
 262   if (! $quiet and !$leaks_found and ! $tb->in_todo) {
 263     $tb->ok(1, sprintf "No leaks found at %s line %d", (caller())[1,2] );
 264   }
 265 }
 266
 267 END {
 268   if ($INC{'Test/Builder.pm'}) {
 269     my $tb = Test::Builder->new;
 270
 271     # we check for test passage - a leak may be a part of a TODO
 272     if ($leaks_found and !$tb->is_passing) {
 273
 274       $tb->diag(sprintf
 275         "\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
 276       . '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
 277       . "\n\n%s\n%s\n\n", ('#' x 16) x 4
 278       ) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );
 279
 280     }
 281     else {
 282       $tb->note("Auto checked $refs_traced references for leaks - none detected");
 283     }
 284   }
 285 }
 286
 287 1;