t/lib/DBICTest/Util/LeakTracer.pm

   1 package DBICTest::Util::LeakTracer;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Carp;
   7 use Scalar::Util qw(isweak weaken blessed reftype);
   8 use DBIx::Class::_Util qw(refcount hrefaddr refdesc);
   9 use DBIx::Class::Optional::Dependencies;
  10 use Data::Dumper::Concise;
  11 use DBICTest::Util qw( stacktrace visit_namespaces );
  12 use constant {
  13   CV_TRACING => !DBICTest::RunMode->is_plain && DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy'),
  14 };
  15
  16 use base 'Exporter';
  17 our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  18
  19 my $refs_traced = 0;
  20 my $leaks_found = 0;
  21 my %reg_of_regs;
  22
  23 sub populate_weakregistry {
  24   my ($weak_registry, $target, $note) = @_;
  25
  26   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
  27   croak 'Target is not a reference' unless length ref $target;
  28
  29   my $refaddr = hrefaddr $target;
  30
  31   # a registry could be fed to itself or another registry via recursive sweeps
  32   return $target if $reg_of_regs{$refaddr};
  33
  34   weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
  35     unless( $reg_of_regs{ hrefaddr($weak_registry) } );
  36
  37   # an explicit "garbage collection" pass every time we store a ref
  38   # if we do not do this the registry will keep growing appearing
  39   # as if the traced program is continuously slowly leaking memory
  40   for my $reg (values %reg_of_regs) {
  41     (defined $reg->{$_}{weakref}) or delete $reg->{$_}
  42       for keys %$reg;
  43   }
  44
  45   if (! defined $weak_registry->{$refaddr}{weakref}) {
  46     $weak_registry->{$refaddr} = {
  47       stacktrace => stacktrace(1),
  48       weakref => $target,
  49     };
  50     weaken( $weak_registry->{$refaddr}{weakref} );
  51     $refs_traced++;
  52   }
  53
  54   my $desc = refdesc $target;
  55   $weak_registry->{$refaddr}{slot_names}{$desc} = 1;
  56   if ($note) {
  57     $note =~ s/\s*\Q$desc\E\s*//g;
  58     $weak_registry->{$refaddr}{slot_names}{$note} = 1;
  59   }
  60
  61   $target;
  62 }
  63
  64 # Regenerate the slots names on a thread spawn
  65 sub CLONE {
  66   my @individual_regs = grep { scalar keys %{$_||{}} } values %reg_of_regs;
  67   %reg_of_regs = ();
  68
  69   for my $reg (@individual_regs) {
  70     my @live_slots = grep { defined $_->{weakref} } values %$reg
  71       or next;
  72
  73     $reg = {};  # get a fresh hashref in the new thread ctx
  74     weaken( $reg_of_regs{hrefaddr($reg)} = $reg );
  75
  76     for my $slot_info (@live_slots) {
  77       my $new_addr = hrefaddr $slot_info->{weakref};
  78
  79       # replace all slot names
  80       $slot_info->{slot_names} = { map {
  81         my $name = $_;
  82         $name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
  83         ($name => 1);
  84       } keys %{$slot_info->{slot_names}} };
  85
  86       $reg->{$new_addr} = $slot_info;
  87     }
  88   }
  89 }
  90
  91 sub visit_refs {
  92   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
  93
  94   $args->{seen_refs} ||= {};
  95
  96   my $visited_cnt = '0E0';
  97   for my $i (0 .. $#{$args->{refs}} ) {
  98
  99     next unless length ref $args->{refs}[$i]; # not-a-ref
 100
 101     my $addr = hrefaddr $args->{refs}[$i];
 102
 103     # no diving into weakregistries
 104     next if $reg_of_regs{$addr};
 105
 106     next if $args->{seen_refs}{$addr}++;
 107     $visited_cnt++;
 108
 109     my $r = $args->{refs}[$i];
 110
 111     $args->{action}->($r) or next;
 112
 113     # This may end up being necessarry some day, but do not slow things
 114     # down for now
 115     #if ( defined( my $t = tied($r) ) ) {
 116     #  $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
 117     #}
 118
 119     my $type = reftype $r;
 120
 121     local $@;
 122     eval {
 123       if ($type eq 'HASH') {
 124         $visited_cnt += visit_refs({ %$args, refs => [ map {
 125           ( !isweak($r->{$_}) ) ? $r->{$_} : ()
 126         } keys %$r ] });
 127       }
 128       elsif ($type eq 'ARRAY') {
 129         $visited_cnt += visit_refs({ %$args, refs => [ map {
 130           ( !isweak($r->[$_]) ) ? $r->[$_] : ()
 131         } 0..$#$r ] });
 132       }
 133       elsif ($type eq 'REF' and !isweak($$r)) {
 134         $visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
 135       }
 136       elsif (CV_TRACING and $type eq 'CODE') {
 137         $visited_cnt += visit_refs({ %$args, refs => [ map {
 138           ( !isweak($_) ) ? $_ : ()
 139         } values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
 140       }
 141       1;
 142     } or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
 143   }
 144   $visited_cnt;
 145 }
 146
 147 # compiles a list of addresses stored as globals (possibly even catching
 148 # class data in the form of method closures), so we can skip them further on
 149 sub symtable_referenced_addresses {
 150
 151   my $refs_per_pkg;
 152
 153   my $seen_refs = {};
 154   visit_namespaces(
 155     action => sub {
 156
 157       no strict 'refs';
 158
 159       my $pkg = shift;
 160
 161       # the unless regex at the end skips some dangerous namespaces outright
 162       # (but does not prevent descent)
 163       $refs_per_pkg->{$pkg} += visit_refs (
 164         seen_refs => $seen_refs,
 165
 166         action => sub { 1 },
 167
 168         refs => [ map { my $sym = $_;
 169           # *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
 170           ( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),
 171
 172           ( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
 173             ? ${"${pkg}::$sym"} : ()
 174           ,
 175
 176           ( map {
 177             ( defined *{"${pkg}::$sym"}{$_} and ! isweak(defined *{"${pkg}::$sym"}{$_}) )
 178               ? *{"${pkg}::$sym"}{$_}
 179               : ()
 180           } qw(HASH ARRAY IO GLOB) ),
 181
 182         } keys %{"${pkg}::"} ],
 183       ) unless $pkg =~ /^ (?:
 184         DB | next | B | .+? ::::ISA (?: ::CACHE ) | Class::C3
 185       ) $/x;
 186     }
 187   );
 188
 189 #  use Devel::Dwarn;
 190 #  Ddie [ map
 191 #    { { $_ => $refs_per_pkg->{$_} } }
 192 #    sort
 193 #      {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
 194 #      keys %$refs_per_pkg
 195 #  ];
 196
 197   $seen_refs;
 198 }
 199
 200 sub assert_empty_weakregistry {
 201   my ($weak_registry, $quiet) = @_;
 202
 203   # in case we hooked bless any extra object creation will wreak
 204   # havoc during the assert phase
 205   local *CORE::GLOBAL::bless;
 206   *CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() ) };
 207
 208   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
 209
 210   defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
 211     for keys %$weak_registry;
 212
 213   return unless keys %$weak_registry;
 214
 215   my $tb = eval { Test::Builder->new }
 216     or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";
 217
 218   for my $addr (keys %$weak_registry) {
 219     $weak_registry->{$addr}{display_name} = join ' | ', (
 220       sort
 221         { length $a <=> length $b or $a cmp $b }
 222         keys %{$weak_registry->{$addr}{slot_names}}
 223     );
 224
 225     $tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
 226       if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
 227   }
 228
 229   # the symtable walk is very expensive
 230   # if we are $quiet (running in an END block) we do not really need to be
 231   # that thorough - can get by with only %Sub::Quote::QUOTED
 232   delete $weak_registry->{$_} for $quiet
 233     ? do {
 234       my $refs = {};
 235       visit_refs (
 236         # only look at the closed over stuffs
 237         refs => [ grep { length ref $_ } map { values %{$_->[2]} } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ],
 238         seen_refs => $refs,
 239         action => sub { 1 },
 240       );
 241       keys %$refs;
 242     }
 243     : (
 244       # full sumtable walk, starting from ::
 245       keys %{ symtable_referenced_addresses() }
 246     )
 247   ;
 248
 249   for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {
 250
 251     next if ! defined $weak_registry->{$addr}{weakref};
 252
 253     $leaks_found++ unless $tb->in_todo;
 254     $tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");
 255
 256     my $diag = do {
 257       local $Data::Dumper::Maxdepth = 1;
 258       sprintf "\n%s (refcnt %d) => %s\n",
 259         $weak_registry->{$addr}{display_name},
 260         refcount($weak_registry->{$addr}{weakref}),
 261         (
 262           ref($weak_registry->{$addr}{weakref}) eq 'CODE'
 263             and
 264           B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
 265         ) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
 266       ;
 267     };
 268
 269     # FIXME - need to add a circular reference seeker based on the visitor
 270     # (will need a bunch of modifications, punting with just a stub for now)
 271
 272     $diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
 273       if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
 274
 275     $diag =~ s/^/    /mg;
 276
 277     if (my $stack = $weak_registry->{$addr}{stacktrace}) {
 278       $diag .= "    Reference first seen$stack";
 279     }
 280
 281     $tb->diag($diag);
 282
 283 #    if ($leaks_found == 1) {
 284 #      # using the fh dumper due to intermittent buffering issues
 285 #      # in case we decide to exit soon after (possibly via _exit)
 286 #      require Devel::MAT::Dumper;
 287 #      local $Devel::MAT::Dumper::MAX_STRING = -1;
 288 #      open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
 289 #      Devel::MAT::Dumper::dumpfh( $fh );
 290 #      close ($fh) or die $!;
 291 #
 292 #      use POSIX;
 293 #      POSIX::_exit(1);
 294 #    }
 295   }
 296
 297   if (! $quiet and !$leaks_found and ! $tb->in_todo) {
 298     $tb->ok(1, sprintf "No leaks found at %s line %d", (caller())[1,2] );
 299   }
 300 }
 301
 302 END {
 303   if (
 304     $INC{'Test/Builder.pm'}
 305       and
 306     my $tb = do {
 307       local $@;
 308       my $t = eval { Test::Builder->new }
 309         or warn "Test::Builder->new failed:\n$@\n";
 310       $t;
 311     }
 312   ) {
 313     # we check for test passage - a leak may be a part of a TODO
 314     if ($leaks_found and !$tb->is_passing) {
 315
 316       $tb->diag(sprintf
 317         "\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
 318       . '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
 319       . "\n\n%s\n%s\n\n", ('#' x 16) x 4
 320       ) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );
 321
 322     }
 323     else {
 324       $tb->note("Auto checked $refs_traced references for leaks - none detected");
 325     }
 326
 327     # also while we are here and not in plain runmode: make sure we never
 328     # loaded any of the strictures XS bullshit (it's a leak in a sense)
 329     unless (
 330       $ENV{MOO_FATAL_WARNINGS}
 331         or
 332       # FIXME - SQLT loads strictures explicitly, /facedesk
 333       # remove this INC check when 0fb58589 and 45287c815 are rectified
 334       $INC{'SQL/Translator.pm'}
 335         or
 336       DBICTest::RunMode->is_plain
 337     ) {
 338       for (qw(indirect multidimensional bareword::filehandles)) {
 339         exists $INC{ Module::Runtime::module_notional_filename($_) }
 340           and
 341         $tb->ok(0, "$_ load should not have been attempted!!!" )
 342       }
 343     }
 344   }
 345 }
 346
 347 1;