t/lib/DBICTest/Util/LeakTracer.pm

   1 package DBICTest::Util::LeakTracer;
   2
   3 use warnings;
   4 use strict;
   5
   6 use ANFANG;
   7 use Carp;
   8 use Scalar::Util qw(isweak weaken blessed reftype);
   9 use DBIx::Class::_Util qw(refcount hrefaddr refdesc dump_value);
  10 use DBICTest::RunMode;
  11 use DBICTest::Util qw( stacktrace visit_namespaces );
  12 use constant {
  13   CV_TRACING => !!(
  14     !DBICTest::RunMode->is_plain
  15       &&
  16     require DBIx::Class::Optional::Dependencies
  17       &&
  18     DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy')
  19   ),
  20 };
  21
  22 use base 'Exporter';
  23 our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  24
  25 my $refs_traced = 0;
  26 my $leaks_found = 0;
  27 my %reg_of_regs;
  28
  29 sub populate_weakregistry {
  30   my ($weak_registry, $target, $note) = @_;
  31
  32   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
  33   croak 'Target is not a reference' unless length ref $target;
  34
  35   my $refaddr = hrefaddr $target;
  36
  37   # a registry could be fed to itself or another registry via recursive sweeps
  38   return $target if $reg_of_regs{$refaddr};
  39
  40   weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
  41     unless( $reg_of_regs{ hrefaddr($weak_registry) } );
  42
  43   # an explicit "garbage collection" pass every time we store a ref
  44   # if we do not do this the registry will keep growing appearing
  45   # as if the traced program is continuously slowly leaking memory
  46   for my $reg (values %reg_of_regs) {
  47     (defined $reg->{$_}{weakref}) or delete $reg->{$_}
  48       for keys %$reg;
  49   }
  50
  51   if (! defined $weak_registry->{$refaddr}{weakref}) {
  52     $weak_registry->{$refaddr} = {
  53       stacktrace => stacktrace(1),
  54       weakref => $target,
  55     };
  56
  57     # on perl < 5.8.3 sometimes a weaken can throw (can't find RT)
  58     # so guard against that unlikely event
  59     local $SIG{__DIE__} if $SIG{__DIE__};
  60     local $@;
  61     eval { weaken( $weak_registry->{$refaddr}{weakref} ); $refs_traced++ }
  62       or delete $weak_registry->{$refaddr};
  63   }
  64
  65   my $desc = refdesc $target;
  66   $weak_registry->{$refaddr}{slot_names}{$desc} = 1;
  67   if ($note) {
  68     $note =~ s/\s*\Q$desc\E\s*//g;
  69     $weak_registry->{$refaddr}{slot_names}{$note} = 1;
  70   }
  71
  72   $target;
  73 }
  74
  75 # Regenerate the slots names on a thread spawn
  76 sub CLONE {
  77   my @individual_regs = grep { scalar keys %{$_||{}} } values %reg_of_regs;
  78   %reg_of_regs = ();
  79
  80   for my $reg (@individual_regs) {
  81     my @live_slots = grep { defined $_->{weakref} } values %$reg
  82       or next;
  83
  84     $reg = {};  # get a fresh hashref in the new thread ctx
  85     weaken( $reg_of_regs{hrefaddr($reg)} = $reg );
  86
  87     for my $slot_info (@live_slots) {
  88       my $new_addr = hrefaddr $slot_info->{weakref};
  89
  90       # replace all slot names
  91       $slot_info->{slot_names} = { map {
  92         my $name = $_;
  93         $name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
  94         ($name => 1);
  95       } keys %{$slot_info->{slot_names}} };
  96
  97       $reg->{$new_addr} = $slot_info;
  98     }
  99   }
 100
 101   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 102   # collected before leaving this scope. Depending on the code above, this
 103   # may very well be just a preventive measure guarding future modifications
 104   undef;
 105 }
 106
 107 sub visit_refs {
 108   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 109
 110   $args->{seen_refs} ||= {};
 111
 112   my $visited_cnt = '0E0';
 113   for my $i (0 .. $#{$args->{refs}} ) {
 114
 115     next unless length ref $args->{refs}[$i]; # not-a-ref
 116
 117     my $addr = hrefaddr $args->{refs}[$i];
 118
 119     # no diving into weakregistries
 120     next if $reg_of_regs{$addr};
 121
 122     next if $args->{seen_refs}{$addr}++;
 123     $visited_cnt++;
 124
 125     my $r = $args->{refs}[$i];
 126
 127     $args->{action}->($r) or next;
 128
 129     # This may end up being necessarry some day, but do not slow things
 130     # down for now
 131     #if ( defined( my $t = tied($r) ) ) {
 132     #  $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
 133     #}
 134
 135     my $type = reftype $r;
 136
 137     local $SIG{__DIE__} if $SIG{__DIE__};
 138     local $@;
 139     eval {
 140       if ($type eq 'HASH') {
 141         $visited_cnt += visit_refs({ %$args, refs => [ map {
 142           ( !isweak($r->{$_}) ) ? $r->{$_} : ()
 143         } keys %$r ] });
 144       }
 145       elsif ($type eq 'ARRAY') {
 146         $visited_cnt += visit_refs({ %$args, refs => [ map {
 147           ( !isweak($r->[$_]) ) ? $r->[$_] : ()
 148         } 0..$#$r ] });
 149       }
 150       elsif ($type eq 'REF' and !isweak($$r)) {
 151         $visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
 152       }
 153       elsif (CV_TRACING and $type eq 'CODE') {
 154         $visited_cnt += visit_refs({ %$args, refs => [ map {
 155           ( !isweak($_) ) ? $_ : ()
 156         } values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
 157       }
 158       1;
 159     } or warn "Could not descend into @{[ refdesc $r ]}: $@\n";
 160   }
 161   $visited_cnt;
 162 }
 163
 164 # compiles a list of addresses stored as globals (possibly even catching
 165 # class data in the form of method closures), so we can skip them further on
 166 sub symtable_referenced_addresses {
 167
 168   my $refs_per_pkg;
 169
 170   my $seen_refs = {};
 171   visit_namespaces(
 172     action => sub {
 173
 174       no strict 'refs';
 175
 176       my $pkg = shift;
 177
 178       # the unless regex at the end skips some dangerous namespaces outright
 179       # (but does not prevent descent)
 180       $refs_per_pkg->{$pkg} += visit_refs (
 181         seen_refs => $seen_refs,
 182
 183         action => sub { 1 },
 184
 185         refs => [ map { my $sym = $_;
 186           # *{"${pkg}::$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
 187           ( CV_TRACING ? Class::MethodCache::get_cv("${pkg}::$sym") : () ),
 188
 189           ( defined *{"${pkg}::$sym"}{SCALAR} and length ref ${"${pkg}::$sym"} and ! isweak( ${"${pkg}::$sym"} ) )
 190             ? ${"${pkg}::$sym"} : ()
 191           ,
 192
 193           ( map {
 194             ( defined *{"${pkg}::$sym"}{$_} and ! isweak(defined *{"${pkg}::$sym"}{$_}) )
 195               ? *{"${pkg}::$sym"}{$_}
 196               : ()
 197           } qw(HASH ARRAY IO GLOB) ),
 198
 199         } keys %{"${pkg}::"} ],
 200       ) unless $pkg =~ /^ (?:
 201         DB | next | B | .+? ::::ISA (?: ::CACHE ) | Class::C3
 202       ) $/x;
 203     }
 204   );
 205
 206 #  use Devel::Dwarn;
 207 #  Ddie [ map
 208 #    { { $_ => $refs_per_pkg->{$_} } }
 209 #    sort
 210 #      {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
 211 #      keys %$refs_per_pkg
 212 #  ];
 213
 214   $seen_refs;
 215 }
 216
 217 sub assert_empty_weakregistry {
 218   my ($weak_registry, $quiet) = @_;
 219
 220   # in case we hooked bless any extra object creation will wreak
 221   # havoc during the assert phase
 222   local *CORE::GLOBAL::bless;
 223   *CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : CORE::caller() ) };
 224
 225   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
 226
 227   defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
 228     for keys %$weak_registry;
 229
 230   return unless keys %$weak_registry;
 231
 232   my $tb = eval { Test::Builder->new }
 233     or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";
 234
 235   for my $addr (keys %$weak_registry) {
 236     $weak_registry->{$addr}{display_name} = join ' | ', (
 237       sort
 238         { length $a <=> length $b or $a cmp $b }
 239         keys %{$weak_registry->{$addr}{slot_names}}
 240     );
 241
 242     $tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
 243       if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
 244   }
 245
 246   # the symtable walk is very expensive
 247   # if we are $quiet (running in an END block) we do not really need to be
 248   # that thorough - can get by with only %Sub::Quote::QUOTED
 249   delete $weak_registry->{$_} for $quiet
 250     ? do {
 251       my $refs = {};
 252       visit_refs (
 253         # only look at the closed over stuffs
 254         refs => [ grep { length ref $_ } map { values %{$_->[2]} } grep { ref $_ eq 'ARRAY' } values %Sub::Quote::QUOTED ],
 255         seen_refs => $refs,
 256         action => sub { 1 },
 257       );
 258       keys %$refs;
 259     }
 260     : (
 261       # full sumtable walk, starting from ::
 262       keys %{ symtable_referenced_addresses() }
 263     )
 264   ;
 265
 266   for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {
 267
 268     next if ! defined $weak_registry->{$addr}{weakref};
 269
 270     $leaks_found++ unless $tb->in_todo;
 271     $tb->ok (0, "Expected garbage collection of $weak_registry->{$addr}{display_name}");
 272
 273     my $diag = do {
 274       local $Data::Dumper::Maxdepth = 1;
 275       sprintf "\n%s (refcnt %d) => %s\n",
 276         $weak_registry->{$addr}{display_name},
 277         refcount($weak_registry->{$addr}{weakref}),
 278         (
 279           ref($weak_registry->{$addr}{weakref}) eq 'CODE'
 280             and
 281           B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
 282         ) ? '__XSUB__' : dump_value $weak_registry->{$addr}{weakref}
 283       ;
 284     };
 285
 286     # FIXME - need to add a circular reference seeker based on the visitor
 287     # (will need a bunch of modifications, punting with just a stub for now)
 288
 289     $diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
 290       if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
 291
 292     $diag =~ s/^/    /mg;
 293
 294     if (my $stack = $weak_registry->{$addr}{stacktrace}) {
 295       $diag .= "    Reference first seen$stack";
 296     }
 297
 298     $tb->diag($diag);
 299
 300 #    if ($leaks_found == 1) {
 301 #      # using the fh dumper due to intermittent buffering issues
 302 #      # in case we decide to exit soon after (possibly via _exit)
 303 #      require Devel::MAT::Dumper;
 304 #      local $Devel::MAT::Dumper::MAX_STRING = -1;
 305 #      open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
 306 #      Devel::MAT::Dumper::dumpfh( $fh );
 307 #      close ($fh) or die $!;
 308 #
 309 #      require POSIX;
 310 #      POSIX::_exit(1);
 311 #    }
 312   }
 313
 314   if (! $quiet and !$leaks_found and ! $tb->in_todo) {
 315     $tb->ok(1, sprintf "No leaks found at %s line %d", (CORE::caller())[1,2] );
 316   }
 317 }
 318
 319 END {
 320   if (
 321     $INC{'Test/Builder.pm'}
 322       and
 323     my $tb = do {
 324       local $@;
 325       my $t = eval { Test::Builder->new }
 326         or warn "Test::Builder->new failed:\n$@\n";
 327       $t;
 328     }
 329   ) {
 330     # we check for test passage - a leak may be a part of a TODO
 331     if ($leaks_found and !$tb->is_passing) {
 332
 333       $tb->diag(sprintf
 334         "\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
 335       . '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
 336       . "\n\n%s\n%s\n\n", ('#' x 16) x 4
 337       ) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );
 338
 339     }
 340     else {
 341       $tb->note("Auto checked $refs_traced references for leaks - none detected");
 342     }
 343
 344     # also while we are here and not in plain runmode: make sure we never
 345     # loaded any of the strictures XS bullshit (it's a leak in a sense)
 346     unless (
 347       $ENV{MOO_FATAL_WARNINGS}
 348         or
 349       # FIXME - SQLT loads strictures explicitly, /facedesk
 350       # remove this INC check when 0fb58589 and 45287c815 are rectified
 351       $INC{'SQL/Translator.pm'}
 352         or
 353       DBICTest::RunMode->is_plain
 354     ) {
 355       for (qw(indirect multidimensional bareword::filehandles)) {
 356         exists $INC{ Module::Runtime::module_notional_filename($_) }
 357           and
 358         $tb->ok(0, "$_ load should not have been attempted!!!" )
 359       }
 360     }
 361   }
 362 }
 363
 364 1;