t/lib/DBICTest/Util/LeakTracer.pm

   1 package DBICTest::Util::LeakTracer;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Carp;
   7 use Scalar::Util qw(isweak weaken blessed reftype);
   8 use DBIx::Class::_Util qw(refcount hrefaddr);
   9 use DBIx::Class::Optional::Dependencies;
  10 use Data::Dumper::Concise;
  11 use DBICTest::Util 'stacktrace';
  12 use constant {
  13   CV_TRACING => DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks_heavy'),
  14 };
  15
  16 use base 'Exporter';
  17 our @EXPORT_OK = qw(populate_weakregistry assert_empty_weakregistry visit_refs);
  18
  19 my $refs_traced = 0;
  20 my $leaks_found = 0;
  21 my %reg_of_regs;
  22
  23 # so we don't trigger stringification
  24 sub _describe_ref {
  25   sprintf '%s%s(%s)',
  26     (defined blessed $_[0]) ? blessed($_[0]) . '=' : '',
  27     reftype $_[0],
  28     hrefaddr $_[0],
  29   ;
  30 }
  31
  32 sub populate_weakregistry {
  33   my ($weak_registry, $target, $note) = @_;
  34
  35   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
  36   croak 'Target is not a reference' unless length ref $target;
  37
  38   my $refaddr = hrefaddr $target;
  39
  40   # a registry could be fed to itself or another registry via recursive sweeps
  41   return $target if $reg_of_regs{$refaddr};
  42
  43   weaken( $reg_of_regs{ hrefaddr($weak_registry) } = $weak_registry )
  44     unless( $reg_of_regs{ hrefaddr($weak_registry) } );
  45
  46   # an explicit "garbage collection" pass every time we store a ref
  47   # if we do not do this the registry will keep growing appearing
  48   # as if the traced program is continuously slowly leaking memory
  49   for my $reg (values %reg_of_regs) {
  50     (defined $reg->{$_}{weakref}) or delete $reg->{$_}
  51       for keys %$reg;
  52   }
  53
  54   if (! defined $weak_registry->{$refaddr}{weakref}) {
  55     $weak_registry->{$refaddr} = {
  56       stacktrace => stacktrace(1),
  57       weakref => $target,
  58     };
  59     weaken( $weak_registry->{$refaddr}{weakref} );
  60     $refs_traced++;
  61   }
  62
  63   my $desc = _describe_ref($target);
  64   $weak_registry->{$refaddr}{slot_names}{$desc} = 1;
  65   if ($note) {
  66     $note =~ s/\s*\Q$desc\E\s*//g;
  67     $weak_registry->{$refaddr}{slot_names}{$note} = 1;
  68   }
  69
  70   $target;
  71 }
  72
  73 # Regenerate the slots names on a thread spawn
  74 sub CLONE {
  75   my @individual_regs = grep { scalar keys %{$_||{}} } values %reg_of_regs;
  76   %reg_of_regs = ();
  77
  78   for my $reg (@individual_regs) {
  79     my @live_slots = grep { defined $_->{weakref} } values %$reg
  80       or next;
  81
  82     $reg = {};  # get a fresh hashref in the new thread ctx
  83     weaken( $reg_of_regs{hrefaddr($reg)} = $reg );
  84
  85     for my $slot_info (@live_slots) {
  86       my $new_addr = hrefaddr $slot_info->{weakref};
  87
  88       # replace all slot names
  89       $slot_info->{slot_names} = { map {
  90         my $name = $_;
  91         $name =~ s/\(0x[0-9A-F]+\)/sprintf ('(%s)', $new_addr)/ieg;
  92         ($name => 1);
  93       } keys %{$slot_info->{slot_names}} };
  94
  95       $reg->{$new_addr} = $slot_info;
  96     }
  97   }
  98 }
  99
 100 sub visit_refs {
 101   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 102
 103   $args->{seen_refs} ||= {};
 104
 105   my $visited_cnt = '0E0';
 106   for my $i (0 .. $#{$args->{refs}} ) {
 107
 108     next unless length ref $args->{refs}[$i]; # not-a-ref
 109
 110     my $addr = hrefaddr $args->{refs}[$i];
 111
 112     # no diving into weakregistries
 113     next if $reg_of_regs{$addr};
 114
 115     next if $args->{seen_refs}{$addr}++;
 116     $visited_cnt++;
 117
 118     my $r = $args->{refs}[$i];
 119
 120     $args->{action}->($r) or next;
 121
 122     # This may end up being necessarry some day, but do not slow things
 123     # down for now
 124     #if ( defined( my $t = tied($r) ) ) {
 125     #  $visited_cnt += visit_refs({ %$args, refs => [ $t ] });
 126     #}
 127
 128     my $type = reftype $r;
 129
 130     local $@;
 131     eval {
 132       if ($type eq 'HASH') {
 133         $visited_cnt += visit_refs({ %$args, refs => [ map {
 134           ( !isweak($r->{$_}) ) ? $r->{$_} : ()
 135         } keys %$r ] });
 136       }
 137       elsif ($type eq 'ARRAY') {
 138         $visited_cnt += visit_refs({ %$args, refs => [ map {
 139           ( !isweak($r->[$_]) ) ? $r->[$_] : ()
 140         } 0..$#$r ] });
 141       }
 142       elsif ($type eq 'REF' and !isweak($$r)) {
 143         $visited_cnt += visit_refs({ %$args, refs => [ $$r ] });
 144       }
 145       elsif (CV_TRACING and $type eq 'CODE') {
 146         $visited_cnt += visit_refs({ %$args, refs => [ map {
 147           ( !isweak($_) ) ? $_ : ()
 148         } values %{ scalar PadWalker::closed_over($r) } ] }); # scalar due to RT#92269
 149       }
 150       1;
 151     } or warn "Could not descend into @{[ _describe_ref($r) ]}: $@\n";
 152   }
 153   $visited_cnt;
 154 }
 155
 156 sub visit_namespaces {
 157   my $args = { (ref $_[0]) ? %{$_[0]} : @_ };
 158
 159   my $visited = 1;
 160
 161   $args->{package} ||= '::';
 162   $args->{package} = '::' if $args->{package} eq 'main';
 163
 164   if ( $args->{action}->($args->{package}) ) {
 165
 166     my $base = $args->{package};
 167     $base = '' if $base eq '::';
 168
 169
 170     $visited += visit_namespaces({ %$args, package => $_ }) for map
 171       { $_ =~ /(.+?)::$/ && "${base}::$1" }
 172       grep
 173         { $_ =~ /(?<!^main)::$/ }
 174         do {  no strict 'refs'; keys %{ $base . '::'} }
 175   }
 176
 177   return $visited;
 178 }
 179
 180 # compiles a list of addresses stored as globals (possibly even catching
 181 # class data in the form of method closures), so we can skip them further on
 182 sub symtable_referenced_addresses {
 183
 184   my $refs_per_pkg;
 185
 186   my $seen_refs = {};
 187   visit_namespaces(
 188     action => sub {
 189
 190       no strict 'refs';
 191
 192       my $pkg = shift;
 193       $pkg = '' if $pkg eq '::';
 194       $pkg .= '::';
 195
 196       # the unless regex at the end skips some dangerous namespaces outright
 197       # (but does not prevent descent)
 198       $refs_per_pkg->{$pkg} += visit_refs (
 199         seen_refs => $seen_refs,
 200
 201         action => sub { 1 },
 202
 203         refs => [ map { my $sym = $_;
 204           # *{"$pkg$sym"}{CODE} won't simply work - MRO-cached CVs are invisible there
 205           ( CV_TRACING ? Class::MethodCache::get_cv("${pkg}$sym") : () ),
 206
 207           ( defined *{"$pkg$sym"}{SCALAR} and length ref ${"$pkg$sym"} and ! isweak( ${"$pkg$sym"} ) )
 208             ? ${"$pkg$sym"} : ()
 209           ,
 210
 211           ( map {
 212             ( defined *{"$pkg$sym"}{$_} and ! isweak(defined *{"$pkg$sym"}{$_}) )
 213               ? *{"$pkg$sym"}{$_}
 214               : ()
 215           } qw(HASH ARRAY IO GLOB) ),
 216
 217         } keys %$pkg ],
 218       ) unless $pkg =~ /^ :: (?:
 219         DB | next | B | .+? ::::ISA (?: ::CACHE ) | Class::C3
 220       ) :: $/x;
 221     }
 222   );
 223
 224 #  use Devel::Dwarn;
 225 #  Ddie [ map
 226 #    { { $_ => $refs_per_pkg->{$_} } }
 227 #    sort
 228 #      {$refs_per_pkg->{$a} <=> $refs_per_pkg->{$b} }
 229 #      keys %$refs_per_pkg
 230 #  ];
 231
 232   $seen_refs;
 233 }
 234
 235 sub assert_empty_weakregistry {
 236   my ($weak_registry, $quiet) = @_;
 237
 238   # in case we hooked bless any extra object creation will wreak
 239   # havoc during the assert phase
 240   local *CORE::GLOBAL::bless;
 241   *CORE::GLOBAL::bless = sub { CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() ) };
 242
 243   croak 'Expecting a registry hashref' unless ref $weak_registry eq 'HASH';
 244
 245   defined $weak_registry->{$_}{weakref} or delete $weak_registry->{$_}
 246     for keys %$weak_registry;
 247
 248   return unless keys %$weak_registry;
 249
 250   my $tb = eval { Test::Builder->new }
 251     or croak "Calling assert_empty_weakregistry in $0 without a loaded Test::Builder makes no sense";
 252
 253   for my $addr (keys %$weak_registry) {
 254     $weak_registry->{$addr}{display_name} = join ' | ', (
 255       sort
 256         { length $a <=> length $b or $a cmp $b }
 257         keys %{$weak_registry->{$addr}{slot_names}}
 258     );
 259
 260     $tb->BAILOUT("!!!! WEAK REGISTRY SLOT $weak_registry->{$addr}{display_name} IS NOT A WEAKREF !!!!")
 261       if defined $weak_registry->{$addr}{weakref} and ! isweak( $weak_registry->{$addr}{weakref} );
 262   }
 263
 264   # the walk is very expensive - if we are $quiet (running in an END block)
 265   # we do not really need to be too thorough
 266   unless ($quiet) {
 267     delete $weak_registry->{$_} for keys %{ symtable_referenced_addresses() };
 268   }
 269
 270
 271   for my $addr (sort { $weak_registry->{$a}{display_name} cmp $weak_registry->{$b}{display_name} } keys %$weak_registry) {
 272
 273     next if ! defined $weak_registry->{$addr}{weakref};
 274
 275     $leaks_found++ unless $tb->in_todo;
 276     $tb->ok (0, "Leaked $weak_registry->{$addr}{display_name}");
 277
 278     my $diag = do {
 279       local $Data::Dumper::Maxdepth = 1;
 280       sprintf "\n%s (refcnt %d) => %s\n",
 281         $weak_registry->{$addr}{display_name},
 282         refcount($weak_registry->{$addr}{weakref}),
 283         (
 284           ref($weak_registry->{$addr}{weakref}) eq 'CODE'
 285             and
 286           B::svref_2object($weak_registry->{$addr}{weakref})->XSUB
 287         ) ? '__XSUB__' : Dumper( $weak_registry->{$addr}{weakref} )
 288       ;
 289     };
 290
 291     # FIXME - need to add a circular reference seeker based on the visitor
 292     # (will need a bunch of modifications, punting with just a stub for now)
 293
 294     $diag .= Devel::FindRef::track ($weak_registry->{$addr}{weakref}, 50) . "\n"
 295       if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
 296
 297     $diag =~ s/^/    /mg;
 298
 299     if (my $stack = $weak_registry->{$addr}{stacktrace}) {
 300       $diag .= "    Reference first seen$stack";
 301     }
 302
 303     $tb->diag($diag);
 304
 305 #    if ($leaks_found == 1) {
 306 #      # using the fh dumper due to intermittent buffering issues
 307 #      # in case we decide to exit soon after (possibly via _exit)
 308 #      require Devel::MAT::Dumper;
 309 #      local $Devel::MAT::Dumper::MAX_STRING = -1;
 310 #      open( my $fh, '>:raw', "leaked_${addr}_pid$$.pmat" ) or die $!;
 311 #      Devel::MAT::Dumper::dumpfh( $fh );
 312 #      close ($fh) or die $!;
 313 #
 314 #      use POSIX;
 315 #      POSIX::_exit(1);
 316 #    }
 317   }
 318
 319   if (! $quiet and !$leaks_found and ! $tb->in_todo) {
 320     $tb->ok(1, sprintf "No leaks found at %s line %d", (caller())[1,2] );
 321   }
 322 }
 323
 324 END {
 325   if ($INC{'Test/Builder.pm'}) {
 326     my $tb = Test::Builder->new;
 327
 328     # we check for test passage - a leak may be a part of a TODO
 329     if ($leaks_found and !$tb->is_passing) {
 330
 331       $tb->diag(sprintf
 332         "\n\n%s\n%s\n\nInstall Devel::FindRef and re-run the test with set "
 333       . '$ENV{TEST_VERBOSE} (prove -v) to see a more detailed leak-report'
 334       . "\n\n%s\n%s\n\n", ('#' x 16) x 4
 335       ) if ( !$ENV{TEST_VERBOSE} or !$INC{'Devel/FindRef.pm'} );
 336
 337     }
 338     else {
 339       $tb->note("Auto checked $refs_traced references for leaks - none detected");
 340     }
 341   }
 342 }
 343
 344 1;