t/lib/DBICTest/Schema/Track.pm

   1 package # hide from PAUSE
   2     DBICTest::Schema::Track;
   3
   4 use warnings;
   5 use strict;
   6
   7 use base qw/DBICTest::BaseResult/;
   8 use Carp qw/confess/;
   9
  10 __PACKAGE__->load_components(qw{
  11     +DBICTest::DeployComponent
  12     InflateColumn::DateTime
  13     Ordered
  14 });
  15
  16 __PACKAGE__->table('track');
  17 __PACKAGE__->add_columns(
  18   'trackid' => {
  19     data_type => 'integer',
  20     is_auto_increment => 1,
  21   },
  22   'cd' => {
  23     data_type => 'integer',
  24   },
  25   'position' => {
  26     data_type => 'int',
  27     accessor => 'pos',
  28   },
  29   'title' => {
  30     data_type => 'varchar',
  31     size      => 100,
  32   },
  33   last_updated_on => {
  34     data_type => 'datetime',
  35     accessor => 'updated_date',
  36     is_nullable => 1
  37   },
  38   last_updated_at => {
  39     data_type => 'datetime',
  40     is_nullable => 1
  41   },
  42 );
  43 __PACKAGE__->set_primary_key('trackid');
  44
  45 __PACKAGE__->add_unique_constraint([ qw/cd position/ ]);
  46 __PACKAGE__->add_unique_constraint([ qw/cd title/ ]);
  47
  48 __PACKAGE__->position_column ('position');
  49 __PACKAGE__->grouping_column ('cd');
  50
  51 # the undef condition in this rel is *deliberate*
  52 # tests oddball legacy syntax
  53 __PACKAGE__->belongs_to( cd => 'DBICTest::Schema::CD', undef, {
  54     proxy => { cd_title => 'title' },
  55 });
  56 __PACKAGE__->belongs_to( disc => 'DBICTest::Schema::CD' => 'cd', {
  57     proxy => 'year'
  58 });
  59
  60 __PACKAGE__->might_have( cd_single => 'DBICTest::Schema::CD', 'single_track' );
  61 __PACKAGE__->might_have( lyrics => 'DBICTest::Schema::Lyrics', 'track_id' );
  62
  63 __PACKAGE__->belongs_to(
  64     "year1999cd",
  65     "DBICTest::Schema::Year1999CDs",
  66     'cd',
  67     { join_type => 'left' },  # the relationship is of course optional
  68 );
  69 __PACKAGE__->belongs_to(
  70     "year2000cd",
  71     "DBICTest::Schema::Year2000CDs",
  72     'cd',
  73     { join_type => 'left' },
  74 );
  75
  76 __PACKAGE__->has_many (
  77   next_tracks => __PACKAGE__,
  78   sub {
  79     my $args = shift;
  80
  81     # This is for test purposes only. A regular user does not
  82     # need to sanity check the passed-in arguments, this is what
  83     # the tests are for :)
  84     my @missing_args = grep { ! defined $args->{$_} }
  85       qw/self_alias foreign_alias self_resultsource foreign_relname/;
  86     confess "Required arguments not supplied to custom rel coderef: @missing_args\n"
  87       if @missing_args;
  88
  89     return (
  90       { "$args->{foreign_alias}.cd"       => { -ident => "$args->{self_alias}.cd" },
  91         "$args->{foreign_alias}.position" => { '>' => { -ident => "$args->{self_alias}.position" } },
  92       },
  93       $args->{self_rowobj} && {
  94         "$args->{foreign_alias}.cd"       => $args->{self_rowobj}->get_column('cd'),
  95         "$args->{foreign_alias}.position" => { '>' => $args->{self_rowobj}->pos },
  96       }
  97     )
  98   }
  99 );
 100
 101 our $hook_cb;
 102
 103 sub sqlt_deploy_hook {
 104   my $class = shift;
 105
 106   $hook_cb->($class, @_) if $hook_cb;
 107   $class->next::method(@_) if $class->next::can;
 108 }
 109
 110 1;