t/lib/DBICTest/Schema/Track.pm

   1 package # hide from PAUSE
   2     DBICTest::Schema::Track;
   3
   4 use warnings;
   5 use strict;
   6
   7 use base 'DBICTest::BaseResult';
   8 use DBICTest::Util 'check_customcond_args';
   9
  10 __PACKAGE__->load_components(qw{
  11     +DBICTest::DeployComponent
  12     InflateColumn::DateTime
  13     Ordered
  14 });
  15
  16 __PACKAGE__->table('track');
  17 __PACKAGE__->add_columns(
  18   'trackid' => {
  19     data_type => 'integer',
  20     is_auto_increment => 1,
  21   },
  22   'cd' => {
  23     data_type => 'integer',
  24   },
  25   'position' => {
  26     data_type => 'int',
  27     accessor => 'pos',
  28   },
  29   'title' => {
  30     data_type => 'varchar',
  31     size      => 100,
  32   },
  33   last_updated_on => {
  34     data_type => 'datetime',
  35     accessor => 'updated_date',
  36     is_nullable => 1
  37   },
  38   last_updated_at => {
  39     data_type => 'datetime',
  40     is_nullable => 1
  41   },
  42 );
  43 __PACKAGE__->set_primary_key('trackid');
  44
  45 __PACKAGE__->add_unique_constraint([ qw/cd position/ ]);
  46 __PACKAGE__->add_unique_constraint([ qw/cd title/ ]);
  47
  48 __PACKAGE__->position_column ('position');
  49 __PACKAGE__->grouping_column ('cd');
  50
  51 # the undef condition in this rel is *deliberate*
  52 # tests oddball legacy syntax
  53 __PACKAGE__->belongs_to( cd => 'DBICTest::Schema::CD', undef, {
  54     proxy => { cd_title => 'title' },
  55 });
  56 # custom condition coderef
  57 __PACKAGE__->belongs_to( cd_cref_cond => 'DBICTest::Schema::CD',
  58 sub {
  59   # This is for test purposes only. A regular user does not
  60   # need to sanity check the passed-in arguments, this is what
  61   # the tests are for :)
  62   my $args = &check_customcond_args;
  63
  64   return (
  65     {
  66       "$args->{foreign_alias}.cdid" => { -ident => "$args->{self_alias}.cd" },
  67     },
  68
  69     ! $args->{self_result_object} ? () : {
  70      "$args->{foreign_alias}.cdid" => $args->{self_result_object}->get_column('cd')
  71     },
  72
  73     ! $args->{foreign_values} ? () : {
  74      "$args->{self_alias}.cd" => $args->{foreign_values}{cdid}
  75     },
  76   );
  77 }
  78 );
  79 __PACKAGE__->belongs_to( disc => 'DBICTest::Schema::CD' => 'cd', {
  80     proxy => 'year'
  81 });
  82
  83 __PACKAGE__->might_have( cd_single => 'DBICTest::Schema::CD', 'single_track' );
  84 __PACKAGE__->might_have( lyrics => 'DBICTest::Schema::Lyrics', 'track_id' );
  85
  86 __PACKAGE__->belongs_to(
  87     "year1999cd",
  88     "DBICTest::Schema::Year1999CDs",
  89     'cd',
  90     { join_type => 'left' },  # the relationship is of course optional
  91 );
  92 __PACKAGE__->belongs_to(
  93     "year2000cd",
  94     "DBICTest::Schema::Year2000CDs",
  95     'cd',
  96     { join_type => 'left' },
  97 );
  98
  99 __PACKAGE__->has_many (
 100   next_tracks => __PACKAGE__,
 101   sub {
 102     # This is for test purposes only. A regular user does not
 103     # need to sanity check the passed-in arguments, this is what
 104     # the tests are for :)
 105     my $args = &check_customcond_args;
 106
 107     return (
 108       { "$args->{foreign_alias}.cd"       => { -ident => "$args->{self_alias}.cd" },
 109         "$args->{foreign_alias}.position" => { '>' => { -ident => "$args->{self_alias}.position" } },
 110       },
 111       $args->{self_result_object} && {
 112         "$args->{foreign_alias}.cd"       => $args->{self_result_object}->get_column('cd'),
 113         "$args->{foreign_alias}.position" => { '>' => $args->{self_result_object}->pos },
 114       }
 115     )
 116   }
 117 );
 118
 119 __PACKAGE__->has_many (
 120   deliberately_broken_all_cd_tracks => __PACKAGE__,
 121   sub {
 122     # This is for test purposes only. A regular user does not
 123     # need to sanity check the passed-in arguments, this is what
 124     # the tests are for :)
 125     my $args = &check_customcond_args;
 126
 127     return {
 128       "$args->{foreign_alias}.cd" => "$args->{self_alias}.cd"
 129     };
 130   }
 131 );
 132
 133 our $hook_cb;
 134
 135 sub sqlt_deploy_hook {
 136   my $class = shift;
 137
 138   $hook_cb->($class, @_) if $hook_cb;
 139   $class->next::method(@_) if $class->next::can;
 140 }
 141
 142 1;