t/lib/DBICTest/Schema/CD.pm

   1 package # hide from PAUSE
   2     DBICTest::Schema::CD;
   3
   4 use warnings;
   5 use strict;
   6
   7 use base qw/DBICTest::BaseResult/;
   8
   9 # this tests table name as scalar ref
  10 # DO NOT REMOVE THE \
  11 __PACKAGE__->table(\'cd');
  12
  13 __PACKAGE__->add_columns(
  14   'cdid' => {
  15     data_type => 'integer',
  16     is_auto_increment => 1,
  17   },
  18   'artist' => {
  19     data_type => 'integer',
  20   },
  21   'title' => {
  22     data_type => 'varchar',
  23     size      => 100,
  24   },
  25   'year' => {
  26     data_type => 'varchar',
  27     size      => 100,
  28   },
  29   'genreid' => {
  30     data_type => 'integer',
  31     is_nullable => 1,
  32     accessor => undef,
  33   },
  34   'single_track' => {
  35     data_type => 'integer',
  36     is_nullable => 1,
  37     is_foreign_key => 1,
  38   }
  39 );
  40 __PACKAGE__->set_primary_key('cdid');
  41 __PACKAGE__->add_unique_constraint([ qw/artist title/ ]);
  42
  43 __PACKAGE__->belongs_to( artist => 'DBICTest::Schema::Artist', undef, {
  44     is_deferrable => 1,
  45     proxy => { artist_name => 'name' },
  46 });
  47 __PACKAGE__->belongs_to( very_long_artist_relationship => 'DBICTest::Schema::Artist', 'artist', {
  48     is_deferrable => 1,
  49 });
  50
  51 # in case this is a single-cd it promotes a track from another cd
  52 __PACKAGE__->belongs_to( single_track => 'DBICTest::Schema::Track', 'single_track',
  53     { join_type => 'left'}
  54 );
  55
  56 __PACKAGE__->has_many( tracks => 'DBICTest::Schema::Track' );
  57 __PACKAGE__->has_many(
  58     tags => 'DBICTest::Schema::Tag', undef,
  59     { order_by => 'tag' },
  60 );
  61 __PACKAGE__->has_many(
  62     cd_to_producer => 'DBICTest::Schema::CD_to_Producer' => 'cd'
  63 );
  64
  65 __PACKAGE__->might_have(
  66     liner_notes => 'DBICTest::Schema::LinerNotes', undef,
  67     { proxy => [ qw/notes/ ] },
  68 );
  69 __PACKAGE__->might_have(artwork => 'DBICTest::Schema::Artwork', 'cd_id');
  70 __PACKAGE__->has_one(mandatory_artwork => 'DBICTest::Schema::Artwork', 'cd_id');
  71
  72 __PACKAGE__->many_to_many( producers => cd_to_producer => 'producer' );
  73 __PACKAGE__->many_to_many(
  74     producers_sorted => cd_to_producer => 'producer',
  75     { order_by => 'producer.name' },
  76 );
  77
  78 __PACKAGE__->belongs_to('genre', 'DBICTest::Schema::Genre',
  79     { 'foreign.genreid' => 'self.genreid' },
  80     {
  81         join_type => 'left',
  82         on_delete => 'SET NULL',
  83         on_update => 'CASCADE',
  84     },
  85 );
  86
  87 #This second relationship was added to test the short-circuiting of pointless
  88 #queries provided by undef_on_null_fk. the relevant test in 66relationship.t
  89 __PACKAGE__->belongs_to('genre_inefficient', 'DBICTest::Schema::Genre',
  90     { 'foreign.genreid' => 'self.genreid' },
  91     {
  92         join_type => 'left',
  93         on_delete => 'SET NULL',
  94         on_update => 'CASCADE',
  95         undef_on_null_fk => 0,
  96     },
  97 );
  98
  99
 100 # This is insane. Don't ever do anything like that
 101 # This is for testing purposes only!
 102
 103 # mst: mo: DBIC is an "object relational mapper"
 104 # mst: mo: not an "object relational hider-because-mo-doesn't-understand-databases
 105 # ribasushi: mo: try it with a subselect nevertheless, I'd love to be proven wrong
 106 # ribasushi: mo: does sqlite actually take this?
 107 # ribasushi: an order in a correlated subquery is insane - how long does it take you on real data?
 108
 109 __PACKAGE__->might_have(
 110     'last_track',
 111     'DBICTest::Schema::Track',
 112     sub {
 113         my $args = shift;
 114         return (
 115             {
 116                 "$args->{foreign_alias}.trackid" => { '=' =>
 117                     $args->{self_resultsource}->schema->resultset('Track')->search(
 118                        { 'correlated_tracks.cd' => { -ident => "$args->{self_alias}.cdid" } },
 119                        {
 120                           order_by => { -desc => 'position' },
 121                           rows     => 1,
 122                           alias    => 'correlated_tracks',
 123                           columns  => ['trackid']
 124                        },
 125                     )->as_query
 126                 }
 127             }
 128         );
 129     },
 130 );
 131
 132 1;