t/lib/DBICTest/Schema/Artist.pm

   1 package # hide from PAUSE
   2     DBICTest::Schema::Artist;
   3
   4 use base qw/DBICTest::BaseResult/;
   5
   6 __PACKAGE__->table('artist');
   7 __PACKAGE__->source_info({
   8     "source_info_key_A" => "source_info_value_A",
   9     "source_info_key_B" => "source_info_value_B",
  10     "source_info_key_C" => "source_info_value_C",
  11 });
  12 __PACKAGE__->add_columns(
  13   'artistid' => {
  14     data_type => 'integer',
  15     is_auto_increment => 1,
  16   },
  17   'name' => {
  18     data_type => 'varchar',
  19     size      => 100,
  20     is_nullable => 1,
  21   },
  22   rank => {
  23     data_type => 'integer',
  24     default_value => 13,
  25   },
  26   charfield => {
  27     data_type => 'char',
  28     size => 10,
  29     is_nullable => 1,
  30   },
  31 );
  32 __PACKAGE__->set_primary_key('artistid');
  33 __PACKAGE__->add_unique_constraint(['name']);
  34 __PACKAGE__->add_unique_constraint(artist => ['artistid']); # do not remove, part of a test
  35 __PACKAGE__->add_unique_constraint(u_nullable => [qw/charfield rank/]);
  36
  37
  38 __PACKAGE__->mk_classdata('field_name_for', {
  39     artistid    => 'primary key',
  40     name        => 'artist name',
  41 });
  42
  43 __PACKAGE__->has_many(
  44     cds => 'DBICTest::Schema::CD', undef,
  45     { order_by => { -asc => 'year'} },
  46 );
  47
  48
  49 __PACKAGE__->has_many(
  50   cds_80s => 'DBICTest::Schema::CD',
  51   sub {
  52     my $args = shift;
  53
  54     return (
  55       { "$args->{foreign_alias}.artist" => { '=' => { -ident => "$args->{self_alias}.artistid"} },
  56         "$args->{foreign_alias}.year"   => { '>' => 1979, '<' => 1990 },
  57       },
  58       $args->{self_rowobj} && {
  59         "$args->{foreign_alias}.artist" => $args->{self_rowobj}->artistid,
  60         "$args->{foreign_alias}.year"   => { '>' => 1979, '<' => 1990 },
  61       }
  62     );
  63   },
  64 );
  65
  66 __PACKAGE__->has_many(
  67   cds_90s => 'DBICTest::Schema::CD',
  68   sub {
  69     my $args = shift;
  70     return (
  71       { "$args->{foreign_alias}.artist" => { -ident => "$args->{self_alias}.artistid" },
  72         "$args->{foreign_alias}.year"   => { '>' => 1989, '<' => 2000 },
  73       }
  74     );
  75   }
  76 );
  77
  78
  79 __PACKAGE__->has_many(
  80   cds_84 => 'DBICTest::Schema::CD',
  81   sub {
  82     my $args = shift;
  83     return (
  84       { "$args->{foreign_alias}.artist" => { -ident => "$args->{self_alias}.artistid" },
  85         "$args->{foreign_alias}.year"   => 1984,
  86       },
  87       $args->{self_rowobj} && {
  88         "$args->{foreign_alias}.artist" => $args->{self_rowobj}->artistid,
  89         "$args->{foreign_alias}.year"   => 1984,
  90       }
  91     );
  92   }
  93 );
  94
  95
  96 __PACKAGE__->has_many(
  97     cds_unordered => 'DBICTest::Schema::CD'
  98 );
  99 __PACKAGE__->has_many(
 100     cds_very_very_very_long_relationship_name => 'DBICTest::Schema::CD'
 101 );
 102
 103 __PACKAGE__->has_many( twokeys => 'DBICTest::Schema::TwoKeys' );
 104 __PACKAGE__->has_many( onekeys => 'DBICTest::Schema::OneKey' );
 105
 106 __PACKAGE__->has_many(
 107   artist_undirected_maps => 'DBICTest::Schema::ArtistUndirectedMap',
 108   [ {'foreign.id1' => 'self.artistid'}, {'foreign.id2' => 'self.artistid'} ],
 109   { cascade_copy => 0 } # this would *so* not make sense
 110 );
 111
 112 __PACKAGE__->has_many(
 113     artwork_to_artist => 'DBICTest::Schema::Artwork_to_Artist' => 'artist_id'
 114 );
 115 __PACKAGE__->many_to_many('artworks', 'artwork_to_artist', 'artwork');
 116
 117
 118 sub sqlt_deploy_hook {
 119   my ($self, $sqlt_table) = @_;
 120
 121   if ($sqlt_table->schema->translator->producer_type =~ /SQLite$/ ) {
 122     $sqlt_table->add_index( name => 'artist_name_hookidx', fields => ['name'] )
 123       or die $sqlt_table->error;
 124   }
 125 }
 126
 127 sub store_column {
 128   my ($self, $name, $value) = @_;
 129   $value = 'X '.$value if ($name eq 'name' && $value && $value =~ /(X )?store_column test/);
 130   $self->next::method($name, $value);
 131 }
 132
 133
 134 1;