t/lib/DBICTest/RunMode.pm

   1 package # hide from PAUSE
   2     DBICTest::RunMode;
   3
   4 use strict;
   5 use warnings;
   6
   7 BEGIN {
   8   if ($INC{'DBIx/Class.pm'}) {
   9     my ($fr, @frame) = 1;
  10     while (@frame = caller($fr++)) {
  11       last if $frame[1] !~ m|^t/lib/DBICTest|;
  12     }
  13
  14     die __PACKAGE__ . " must be loaded before DBIx::Class (or modules using DBIx::Class) at $frame[1] line $frame[2]\n";
  15   }
  16 }
  17
  18 use Path::Class qw/file dir/;
  19 use File::Spec;
  20
  21 _check_author_makefile() unless $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION};
  22
  23 # PathTools has a bug where on MSWin32 it will often return / as a tmpdir.
  24 # This is *really* stupid and the result of having our lockfiles all over
  25 # the place is also rather obnoxious. So we use our own heuristics instead
  26 # https://rt.cpan.org/Ticket/Display.html?id=76663
  27 my $tmpdir;
  28 sub tmpdir {
  29   dir ($tmpdir ||= do {
  30
  31     my $dir = dir(File::Spec->tmpdir);
  32
  33     my @parts = File::Spec->splitdir($dir);
  34     if (@parts == 2 and $parts[1] eq '') {
  35       # This means we were give the root dir (C:\ or something equally unacceptable)
  36       # Replace with our local project tmpdir. This will make multiple runs
  37       # from different runs conflict with each other, but is much better than
  38       # polluting the root dir with random crap
  39       $dir = _find_co_root()->subdir('t')->subdir('var');
  40       $dir->mkpath;
  41     }
  42
  43     $dir->stringify;
  44   });
  45 }
  46
  47
  48 # Die if the author did not update his makefile
  49 #
  50 # This is pretty heavy handed, so the check is pretty solid:
  51 #
  52 # 1) Assume that this particular module is loaded from -I <$root>/t/lib
  53 # 2) Make sure <$root>/Makefile.PL exists
  54 # 3) Make sure we can stat() <$root>/Makefile.PL
  55 #
  56 # If all of the above is satisfied
  57 #
  58 # *) die if <$root>/inc does not exist
  59 # *) die if no stat() results for <$root>/Makefile (covers no Makefile)
  60 # *) die if Makefile.PL mtime > Makefile mtime
  61 #
  62 sub _check_author_makefile {
  63
  64   my $root = _find_co_root()
  65     or return;
  66
  67   my $optdeps = file('lib/DBIx/Class/Optional/Dependencies.pm');
  68
  69   # not using file->stat as it invokes File::stat which in turn breaks stat(_)
  70   my ($mf_pl_mtime, $mf_mtime, $optdeps_mtime) = ( map
  71     { (stat ($root->file ($_)) )[9] || undef }  # stat returns () on nonexistent files
  72     (qw|Makefile.PL  Makefile|, $optdeps)
  73   );
  74
  75   return unless $mf_pl_mtime;   # something went wrong during co_root detection ?
  76
  77   my @fail_reasons;
  78
  79   if(not -d $root->subdir ('inc')) {
  80     push @fail_reasons, "Missing ./inc directory";
  81   }
  82
  83   if(not $mf_mtime) {
  84     push @fail_reasons, "Missing ./Makefile";
  85   }
  86   else {
  87     if($mf_mtime < $mf_pl_mtime) {
  88       push @fail_reasons, "./Makefile.PL is newer than ./Makefile";
  89     }
  90     if($mf_mtime < $optdeps_mtime) {
  91       push @fail_reasons, "./$optdeps is newer than ./Makefile";
  92     }
  93   }
  94
  95   if (@fail_reasons) {
  96     print STDOUT "\nBail out!\n";
  97     print STDERR <<'EOE';
  98
  99
 100 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 101 ======================== FATAL ERROR ===========================
 102 !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 103
 104 We have a number of reasons to believe that this is a development
 105 checkout and that you, the user, did not run `perl Makefile.PL`
 106 before using this code. You absolutely _must_ perform this step,
 107 to ensure you have all required dependencies present. Not doing
 108 so often results in a lot of wasted time for other contributors
 109 trying to assit you with spurious "its broken!" problems.
 110
 111 By default DBICs Makefile.PL turns all optional dependenciess into
 112 *HARD REQUIREMENTS*, in order to make sure that the entire test
 113 suite is executed, and no tests are skipped due to missing modules.
 114 If you for some reason need to disable this behavior - supply the
 115 --skip_author_deps option when running perl Makefile.PL
 116
 117 If you are seeing this message unexpectedly (i.e. you are in fact
 118 attempting a regular installation be it through CPAN or manually),
 119 please report the situation to either the mailing list or to the
 120 irc channel as described in
 121
 122 http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT
 123
 124 The DBIC team
 125
 126
 127 Reasons you received this message:
 128
 129 EOE
 130
 131     foreach my $r (@fail_reasons) {
 132       print STDERR "  * $r\n";
 133     }
 134     print STDERR "\n\n\n";
 135
 136     exit 1;
 137   }
 138 }
 139
 140 # Mimic $Module::Install::AUTHOR
 141 sub is_author {
 142
 143   my $root = _find_co_root()
 144     or return undef;
 145
 146   return (
 147     ( not -d $root->subdir ('inc') )
 148       or
 149     ( -e $root->subdir ('inc')->subdir ($^O eq 'VMS' ? '_author' : '.author') )
 150   );
 151 }
 152
 153 sub is_smoker {
 154   return
 155     ( ($ENV{TRAVIS}||'') eq 'true' )
 156       ||
 157     ( $ENV{AUTOMATED_TESTING} && ! $ENV{PERL5_CPANM_IS_RUNNING} && ! $ENV{RELEASE_TESTING} )
 158   ;
 159 }
 160
 161 sub is_plain {
 162   return (! __PACKAGE__->is_smoker && ! __PACKAGE__->is_author && ! $ENV{RELEASE_TESTING} )
 163 }
 164
 165 # Try to determine the root of a checkout/untar if possible
 166 # or return undef
 167 sub _find_co_root {
 168
 169     my @mod_parts = split /::/, (__PACKAGE__ . '.pm');
 170     my $rel_path = join ('/', @mod_parts);  # %INC stores paths with / regardless of OS
 171
 172     return undef unless ($INC{$rel_path});
 173
 174     # a bit convoluted, but what we do here essentially is:
 175     #  - get the file name of this particular module
 176     #  - do 'cd ..' as many times as necessary to get to t/lib/../..
 177
 178     my $root = dir ($INC{$rel_path});
 179     for (1 .. @mod_parts + 2) {
 180         $root = $root->parent;
 181     }
 182
 183     return (-f $root->file ('Makefile.PL') )
 184       ? $root
 185       : undef
 186     ;
 187 }
 188
 189 1;