t/lib/DBICTest/BaseSchema.pm

   1 package #hide from pause
   2   DBICTest::BaseSchema;
   3
   4 use strict;
   5 use warnings;
   6 use base qw(DBICTest::Base DBIx::Class::Schema);
   7
   8 use Fcntl qw(:DEFAULT :seek :flock);
   9 use Time::HiRes 'sleep';
  10 use DBIx::Class::_Util 'scope_guard';
  11 use DBICTest::Util::LeakTracer qw(populate_weakregistry assert_empty_weakregistry);
  12 use DBICTest::Util qw( local_umask await_flock dbg DEBUG_TEST_CONCURRENCY_LOCKS );
  13 use namespace::clean;
  14
  15 sub capture_executed_sql_bind {
  16   my ($self, $cref) = @_;
  17
  18   $self->throw_exception("Expecting a coderef to run") unless ref $cref eq 'CODE';
  19
  20   require DBICTest::SQLTracerObj;
  21
  22   # hack around stupid, stupid API
  23   no warnings 'redefine';
  24   local *DBIx::Class::Storage::DBI::_format_for_trace = sub { $_[1] };
  25   Class::C3->reinitialize if DBIx::Class::_ENV_::OLD_MRO;
  26
  27   # can not use local() due to an unknown number of storages
  28   # (think replicated)
  29   my $orig_states = { map
  30     { $_ => $self->storage->$_ }
  31     qw(debugcb debugobj debug)
  32   };
  33
  34   my $sg = scope_guard {
  35     $self->storage->$_ ( $orig_states->{$_} ) for keys %$orig_states;
  36   };
  37
  38   $self->storage->debugcb(undef);
  39   $self->storage->debugobj( my $tracer_obj = DBICTest::SQLTracerObj->new );
  40   $self->storage->debug(1);
  41
  42   local $Test::Builder::Level = $Test::Builder::Level + 2;
  43   $cref->();
  44
  45   return $tracer_obj->{sqlbinds} || [];
  46 }
  47
  48 sub is_executed_querycount {
  49   my ($self, $cref, $exp_counts, $msg) = @_;
  50
  51   local $Test::Builder::Level = $Test::Builder::Level + 1;
  52
  53   $self->throw_exception("Expecting an hashref of counts or an integer representing total query count")
  54     unless ref $exp_counts eq 'HASH' or (defined $exp_counts and ! ref $exp_counts);
  55
  56   my @got = map { $_->[0] } @{ $self->capture_executed_sql_bind($cref) };
  57
  58   return Test::More::is( @got, $exp_counts, $msg )
  59     unless ref $exp_counts;
  60
  61   my $got_counts = { map { $_ => 0 } keys %$exp_counts };
  62   $got_counts->{$_}++ for @got;
  63
  64   return Test::More::is_deeply(
  65     $got_counts,
  66     $exp_counts,
  67     $msg,
  68   );
  69 }
  70
  71 sub is_executed_sql_bind {
  72   my ($self, $cref, $sqlbinds, $msg) = @_;
  73
  74   local $Test::Builder::Level = $Test::Builder::Level + 1;
  75
  76   $self->throw_exception("Expecting an arrayref of SQL/Bind pairs") unless ref $sqlbinds eq 'ARRAY';
  77
  78   my @expected = @$sqlbinds;
  79
  80   my @got = map { $_->[1] } @{ $self->capture_executed_sql_bind($cref) };
  81
  82
  83   return Test::Builder->new->ok(1, $msg || "No queries executed while running $cref")
  84     if !@got and !@expected;
  85
  86   require SQL::Abstract::Test;
  87   my $ret = 1;
  88   while (@expected or @got) {
  89     my $left = shift @got;
  90     my $right = shift @expected;
  91
  92     # allow the right side to "simplify" the entire shebang
  93     if ($left and $right) {
  94       $left = [ @$left ];
  95       for my $i (1..$#$right) {
  96         if (
  97           ! ref $right->[$i]
  98             and
  99           ref $left->[$i] eq 'ARRAY'
 100             and
 101           @{$left->[$i]} == 2
 102         ) {
 103           $left->[$i] = $left->[$i][1]
 104         }
 105       }
 106     }
 107
 108     $ret &= SQL::Abstract::Test::is_same_sql_bind(
 109       \( $left || [] ),
 110       \( $right || [] ),
 111       $msg,
 112     );
 113   }
 114
 115   return $ret;
 116 }
 117
 118 our $locker;
 119 END {
 120   # we need the $locker to be referenced here for delayed destruction
 121   if ($locker->{lock_name} and ($ENV{DBICTEST_LOCK_HOLDER}||0) == $$) {
 122     DEBUG_TEST_CONCURRENCY_LOCKS
 123       and dbg "$locker->{type} LOCK RELEASED (END): $locker->{lock_name}";
 124   }
 125 }
 126
 127 my $weak_registry = {};
 128
 129 sub connection {
 130   my $self = shift->next::method(@_);
 131
 132 # MASSIVE FIXME
 133 # we can't really lock based on DSN, as we do not yet have a way to tell that e.g.
 134 # DBICTEST_MSSQL_DSN=dbi:Sybase:server=192.168.0.11:1433;database=dbtst
 135 #  and
 136 # DBICTEST_MSSQL_ODBC_DSN=dbi:ODBC:server=192.168.0.11;port=1433;database=dbtst;driver=FreeTDS;tds_version=8.0
 137 # are the same server
 138 # hence we lock everything based on sqlt_type or just globally if not available
 139 # just pretend we are python you know? :)
 140
 141
 142   # when we get a proper DSN resolution sanitize to produce a portable lockfile name
 143   # this may look weird and unnecessary, but consider running tests from
 144   # windows over a samba share >.>
 145   #utf8::encode($dsn);
 146   #$dsn =~ s/([^A-Za-z0-9_\-\.\=])/ sprintf '~%02X', ord($1) /ge;
 147   #$dsn =~ s/^dbi/dbi/i;
 148
 149   # provide locking for physical (non-memory) DSNs, so that tests can
 150   # safely run in parallel. While the harness (make -jN test) does set
 151   # an envvar, we can not detect when a user invokes prove -jN. Hence
 152   # perform the locking at all times, it shouldn't hurt.
 153   # the lock fh *should* inherit across forks/subprocesses
 154   if (
 155     ! $DBICTest::global_exclusive_lock
 156       and
 157     ( ! $ENV{DBICTEST_LOCK_HOLDER} or $ENV{DBICTEST_LOCK_HOLDER} == $$ )
 158       and
 159     ref($_[0]) ne 'CODE'
 160       and
 161     ($_[0]||'') !~ /^ (?i:dbi) \: SQLite \: (?: dbname\= )? (?: \:memory\: | t [\/\\] var [\/\\] DBIxClass\-) /x
 162   ) {
 163
 164     my $locktype;
 165
 166     {
 167       # guard against infinite recursion
 168       local $ENV{DBICTEST_LOCK_HOLDER} = -1;
 169
 170       # we need to work with a forced fresh clone so that we do not upset any state
 171       # of the main $schema (some tests examine it quite closely)
 172       local $SIG{__WARN__} = sub {};
 173       local $@;
 174
 175       # this will either give us an undef $locktype or will determine things
 176       # properly with a default ( possibly connecting in the process )
 177       eval {
 178         my $s = ref($self)->connect(@{$self->storage->connect_info})->storage;
 179
 180         $locktype = $s->sqlt_type || 'generic';
 181
 182         # in case sqlt_type did connect, doesn't matter if it fails or something
 183         $s->disconnect;
 184       };
 185     }
 186
 187     # Never hold more than one lock. This solves the "lock in order" issues
 188     # unrelated tests may have
 189     # Also if there is no connection - there is no lock to be had
 190     if ($locktype and (!$locker or $locker->{type} ne $locktype)) {
 191
 192       # this will release whatever lock we may currently be holding
 193       # which is fine since the type does not match as checked above
 194       DEBUG_TEST_CONCURRENCY_LOCKS
 195         and $locker
 196         and dbg "$locker->{type} LOCK RELEASED (UNDEF): $locker->{lock_name}";
 197
 198       undef $locker;
 199
 200       my $lockpath = DBICTest::RunMode->tmpdir->file("_dbictest_$locktype.lock");
 201
 202       DEBUG_TEST_CONCURRENCY_LOCKS
 203         and dbg "Waiting for $locktype LOCK: $lockpath...";
 204
 205       my $lock_fh;
 206       {
 207         my $u = local_umask(0); # so that the file opens as 666, and any user can lock
 208         sysopen ($lock_fh, $lockpath, O_RDWR|O_CREAT) or die "Unable to open $lockpath: $!";
 209       }
 210
 211       await_flock ($lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
 212
 213       DEBUG_TEST_CONCURRENCY_LOCKS
 214         and dbg "Got $locktype LOCK: $lockpath";
 215
 216       # see if anyone was holding a lock before us, and wait up to 5 seconds for them to terminate
 217       # if we do not do this we may end up trampling over some long-running END or somesuch
 218       seek ($lock_fh, 0, SEEK_SET) or die "seek failed $!";
 219       my $old_pid;
 220       if (
 221         read ($lock_fh, $old_pid, 100)
 222           and
 223         ($old_pid) = $old_pid =~ /^(\d+)$/
 224       ) {
 225         DEBUG_TEST_CONCURRENCY_LOCKS
 226           and dbg "Post-grab WAIT for $old_pid START: $lockpath";
 227
 228         for (1..50) {
 229           kill (0, $old_pid) or last;
 230           sleep 0.1;
 231         }
 232
 233         DEBUG_TEST_CONCURRENCY_LOCKS
 234           and dbg "Post-grab WAIT for $old_pid FINISHED: $lockpath";
 235       }
 236
 237       truncate $lock_fh, 0;
 238       seek ($lock_fh, 0, SEEK_SET) or die "seek failed $!";
 239       $lock_fh->autoflush(1);
 240       print $lock_fh $$;
 241
 242       $ENV{DBICTEST_LOCK_HOLDER} ||= $$;
 243
 244       $locker = {
 245         type => $locktype,
 246         fh => $lock_fh,
 247         lock_name => "$lockpath",
 248       };
 249     }
 250   }
 251
 252   if ($INC{'Test/Builder.pm'}) {
 253     populate_weakregistry ( $weak_registry, $self->storage );
 254
 255     my $cur_connect_call = $self->storage->on_connect_call;
 256
 257     $self->storage->on_connect_call([
 258       (ref $cur_connect_call eq 'ARRAY'
 259         ? @$cur_connect_call
 260         : ($cur_connect_call || ())
 261       ),
 262       [sub {
 263         populate_weakregistry( $weak_registry, shift->_dbh )
 264       }],
 265     ]);
 266   }
 267
 268   return $self;
 269 }
 270
 271 sub clone {
 272   my $self = shift->next::method(@_);
 273   populate_weakregistry ( $weak_registry, $self )
 274     if $INC{'Test/Builder.pm'};
 275   $self;
 276 }
 277
 278 END {
 279   # Make sure we run after any cleanup in other END blocks
 280   push @{ B::end_av()->object_2svref }, sub {
 281     assert_empty_weakregistry($weak_registry, 'quiet');
 282   };
 283 }
 284
 285 1;