t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6 use DBICTest::RunMode;
   7 use DBICTest::Schema;
   8 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
   9 use DBICTest::Util 'local_umask';
  10 use Carp;
  11 use Path::Class::File ();
  12 use File::Spec;
  13 use Fcntl qw/:DEFAULT :flock/;
  14
  15 =head1 NAME
  16
  17 DBICTest - Library to be used by DBIx::Class test scripts.
  18
  19 =head1 SYNOPSIS
  20
  21   use lib qw(t/lib);
  22   use DBICTest;
  23   use Test::More;
  24
  25   my $schema = DBICTest->init_schema();
  26
  27 =head1 DESCRIPTION
  28
  29 This module provides the basic utilities to write tests against
  30 DBIx::Class.
  31
  32 =head1 METHODS
  33
  34 =head2 init_schema
  35
  36   my $schema = DBICTest->init_schema(
  37     no_deploy=>1,
  38     no_populate=>1,
  39     storage_type=>'::DBI::Replicated',
  40     storage_type_args=>{
  41       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  42     },
  43   );
  44
  45 This method removes the test SQLite database in t/var/DBIxClass.db
  46 and then creates a new, empty database.
  47
  48 This method will call deploy_schema() by default, unless the
  49 no_deploy flag is set.
  50
  51 Also, by default, this method will call populate_schema() by
  52 default, unless the no_deploy or no_populate flags are set.
  53
  54 =cut
  55
  56 # some tests are very time sensitive and need to run on their own, without
  57 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  58 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  59 # will ask for an exclusive one and block until they can get it
  60 our ($global_lock_fh, $global_exclusive_lock);
  61 sub import {
  62     my $self = shift;
  63
  64     my $tmpdir = DBICTest::RunMode->tmpdir;
  65     my $lockpath = $tmpdir->file('.dbictest_global.lock');
  66
  67     {
  68       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
  69       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT) or do {
  70         my $err = $!;
  71
  72         my @x_tests = map { (defined $_) ? ( $_ ? 1 : 0 ) : 'U' } map {(-e, -d, -f, -r, -w, -x, -o)} ($tmpdir, $lockpath);
  73
  74         die sprintf <<"EOE", $lockpath, $err, scalar $>, scalar $), (stat($tmpdir))[4,5,2], @x_tests;
  75 Unable to open %s: %s
  76 Process EUID/EGID: %s / %s
  77 TmpDir UID/GID:    %s / %s
  78 TmpDir StatMode:   %o
  79 TmpDir X-tests:    -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
  80 TmpFile X-tests:   -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
  81 EOE
  82       };
  83     }
  84
  85     for (@_) {
  86         if ($_ eq ':GlobalLock') {
  87             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
  88             $global_exclusive_lock = 1;
  89         }
  90         else {
  91             croak "Unknown export $_ requested from $self";
  92         }
  93     }
  94
  95     unless ($global_exclusive_lock) {
  96         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
  97     }
  98 }
  99
 100 END {
 101     if ($global_lock_fh) {
 102         # delay destruction even more
 103     }
 104 }
 105
 106 {
 107     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 108     $dir->mkpath unless -d "$dir";
 109     $dir = "$dir";
 110
 111     sub _sqlite_dbfilename {
 112         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 113         $holder = $$ if $holder == -1;
 114
 115         # useful for missing cleanup debugging
 116         #if ( $holder == $$) {
 117         #  my $x = $0;
 118         #  $x =~ s/\//#/g;
 119         #  $holder .= "-$x";
 120         #}
 121
 122         return "$dir/DBIxClass-$holder.db";
 123     }
 124
 125     END {
 126         _cleanup_dbfile();
 127     }
 128 }
 129
 130 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 131
 132 sub _cleanup_dbfile {
 133     # cleanup if this is us
 134     if (
 135       ! $ENV{DBICTEST_LOCK_HOLDER}
 136         or
 137       $ENV{DBICTEST_LOCK_HOLDER} == -1
 138         or
 139       $ENV{DBICTEST_LOCK_HOLDER} == $$
 140     ) {
 141         my $db_file = _sqlite_dbfilename();
 142         unlink $_ for ($db_file, "${db_file}-journal");
 143     }
 144 }
 145
 146 sub has_custom_dsn {
 147     return $ENV{"DBICTEST_DSN"} ? 1:0;
 148 }
 149
 150 sub _sqlite_dbname {
 151     my $self = shift;
 152     my %args = @_;
 153     return $self->_sqlite_dbfilename if (
 154       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 155     );
 156     return ":memory:";
 157 }
 158
 159 sub _database {
 160     my $self = shift;
 161     my %args = @_;
 162
 163     if ($ENV{DBICTEST_DSN}) {
 164       return (
 165         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 166         { AutoCommit => 1, %args },
 167       );
 168     }
 169     my $db_file = $self->_sqlite_dbname(%args);
 170
 171     for ($db_file, "${db_file}-journal") {
 172       next unless -e $_;
 173       unlink ($_) or carp (
 174         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 175       );
 176     }
 177
 178     return ("dbi:SQLite:${db_file}", '', '', {
 179       AutoCommit => 1,
 180
 181       # this is executed on every connect, and thus installs a disconnect/DESTROY
 182       # guard for every new $dbh
 183       on_connect_do => sub {
 184         my $storage = shift;
 185         my $dbh = $storage->_get_dbh;
 186
 187         # no fsync on commit
 188         $dbh->do ('PRAGMA synchronous = OFF');
 189
 190         $dbh->do ('PRAGMA reverse_unordered_selects = ON')
 191           if $ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER};
 192
 193         # set a *DBI* disconnect callback, to make sure the physical SQLite
 194         # file is still there (i.e. the test does not attempt to delete
 195         # an open database, which fails on Win32)
 196         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 197           $dbh->{Callbacks} = {
 198             connect => sub { $guard_cb->('connect') },
 199             disconnect => sub { $guard_cb->('disconnect') },
 200             DESTROY => sub { $guard_cb->('DESTROY') },
 201           };
 202         }
 203       },
 204       %args,
 205     });
 206 }
 207
 208 sub __mk_disconnect_guard {
 209   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 210
 211   my $db_file = shift;
 212   return unless -f $db_file;
 213
 214   my $orig_inode = (stat($db_file))[1]
 215     or return;
 216
 217   my $clan_connect_caller = '*UNKNOWN*';
 218   my $i;
 219   while ( my ($pack, $file, $line) = caller(++$i) ) {
 220     next if $file eq __FILE__;
 221     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 222     $clan_connect_caller = "$file line $line";
 223   }
 224
 225   my $failed_once = 0;
 226   my $connected = 1;
 227
 228   return sub {
 229     return if $failed_once;
 230
 231     my $event = shift;
 232     if ($event eq 'connect') {
 233       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 234       $connected = 1;
 235       return;
 236     }
 237     elsif ($event eq 'disconnect') {
 238       $connected = 0;
 239     }
 240     elsif ($event eq 'DESTROY' and ! $connected ) {
 241       return;
 242     }
 243
 244     my $fail_reason;
 245     if (! -e $db_file) {
 246       $fail_reason = 'is missing';
 247     }
 248     else {
 249       my $cur_inode = (stat($db_file))[1];
 250
 251       if ($orig_inode != $cur_inode) {
 252         # pack/unpack to match the unsigned longs returned by `stat`
 253         $fail_reason = sprintf 'was recreated (initially inode %s, now %s)', (
 254           map { unpack ('L', pack ('l', $_) ) } ($orig_inode, $cur_inode )
 255         );
 256       }
 257     }
 258
 259     if ($fail_reason) {
 260       $failed_once++;
 261
 262       require Test::Builder;
 263       my $t = Test::Builder->new;
 264       local $Test::Builder::Level = $Test::Builder::Level + 3;
 265       $t->ok (0,
 266         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 267       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 268       . 'still being open. This action would fail massively if running under Win32, hence '
 269       . 'we make sure it fails on any OS :)'
 270       );
 271     }
 272
 273     return; # this empty return is a DBI requirement
 274   };
 275 }
 276
 277 my $weak_registry = {};
 278
 279 sub init_schema {
 280     my $self = shift;
 281     my %args = @_;
 282
 283     my $schema;
 284
 285     if ($args{compose_connection}) {
 286       $schema = DBICTest::Schema->compose_connection(
 287                   'DBICTest', $self->_database(%args)
 288                 );
 289     } else {
 290       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 291     }
 292
 293     if( $args{storage_type}) {
 294       $schema->storage_type($args{storage_type});
 295     }
 296
 297     if ( !$args{no_connect} ) {
 298       $schema = $schema->connect($self->_database(%args));
 299     }
 300
 301     if ( !$args{no_deploy} ) {
 302         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 303         __PACKAGE__->populate_schema( $schema )
 304          if( !$args{no_populate} );
 305     }
 306
 307     populate_weakregistry ( $weak_registry, $schema->storage )
 308       if $INC{'Test/Builder.pm'} and $schema->storage;
 309
 310     return $schema;
 311 }
 312
 313 END {
 314     assert_empty_weakregistry($weak_registry, 'quiet');
 315 }
 316
 317 =head2 deploy_schema
 318
 319   DBICTest->deploy_schema( $schema );
 320
 321 This method does one of two things to the schema.  It can either call
 322 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 323 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 324 file and execute the SQL within. Either way you end up with a fresh set
 325 of tables for testing.
 326
 327 =cut
 328
 329 sub deploy_schema {
 330     my $self = shift;
 331     my $schema = shift;
 332     my $args = shift || {};
 333
 334     local $schema->storage->{debug}
 335       if ($ENV{TRAVIS}||'') eq 'true';
 336
 337     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 338         $schema->deploy($args);
 339     } else {
 340         my $filename = Path::Class::File->new(__FILE__)->dir
 341           ->file('sqlite.sql')->stringify;
 342         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 343         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 344           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 345             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 346           }
 347         }
 348     }
 349     return;
 350 }
 351
 352 =head2 populate_schema
 353
 354   DBICTest->populate_schema( $schema );
 355
 356 After you deploy your schema you can use this method to populate
 357 the tables with test data.
 358
 359 =cut
 360
 361 sub populate_schema {
 362     my $self = shift;
 363     my $schema = shift;
 364
 365     local $schema->storage->{debug}
 366       if ($ENV{TRAVIS}||'') eq 'true';
 367
 368     $schema->populate('Genre', [
 369       [qw/genreid name/],
 370       [qw/1       emo  /],
 371     ]);
 372
 373     $schema->populate('Artist', [
 374         [ qw/artistid name/ ],
 375         [ 1, 'Caterwauler McCrae' ],
 376         [ 2, 'Random Boy Band' ],
 377         [ 3, 'We Are Goth' ],
 378     ]);
 379
 380     $schema->populate('CD', [
 381         [ qw/cdid artist title year genreid/ ],
 382         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 383         [ 2, 1, "Forkful of bees", 2001 ],
 384         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 385         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 386         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 387     ]);
 388
 389     $schema->populate('LinerNotes', [
 390         [ qw/liner_id notes/ ],
 391         [ 2, "Buy Whiskey!" ],
 392         [ 4, "Buy Merch!" ],
 393         [ 5, "Kill Yourself!" ],
 394     ]);
 395
 396     $schema->populate('Tag', [
 397         [ qw/tagid cd tag/ ],
 398         [ 1, 1, "Blue" ],
 399         [ 2, 2, "Blue" ],
 400         [ 3, 3, "Blue" ],
 401         [ 4, 5, "Blue" ],
 402         [ 5, 2, "Cheesy" ],
 403         [ 6, 4, "Cheesy" ],
 404         [ 7, 5, "Cheesy" ],
 405         [ 8, 2, "Shiny" ],
 406         [ 9, 4, "Shiny" ],
 407     ]);
 408
 409     $schema->populate('TwoKeys', [
 410         [ qw/artist cd/ ],
 411         [ 1, 1 ],
 412         [ 1, 2 ],
 413         [ 2, 2 ],
 414     ]);
 415
 416     $schema->populate('FourKeys', [
 417         [ qw/foo bar hello goodbye sensors/ ],
 418         [ 1, 2, 3, 4, 'online' ],
 419         [ 5, 4, 3, 6, 'offline' ],
 420     ]);
 421
 422     $schema->populate('OneKey', [
 423         [ qw/id artist cd/ ],
 424         [ 1, 1, 1 ],
 425         [ 2, 1, 2 ],
 426         [ 3, 2, 2 ],
 427     ]);
 428
 429     $schema->populate('SelfRef', [
 430         [ qw/id name/ ],
 431         [ 1, 'First' ],
 432         [ 2, 'Second' ],
 433     ]);
 434
 435     $schema->populate('SelfRefAlias', [
 436         [ qw/self_ref alias/ ],
 437         [ 1, 2 ]
 438     ]);
 439
 440     $schema->populate('ArtistUndirectedMap', [
 441         [ qw/id1 id2/ ],
 442         [ 1, 2 ]
 443     ]);
 444
 445     $schema->populate('Producer', [
 446         [ qw/producerid name/ ],
 447         [ 1, 'Matt S Trout' ],
 448         [ 2, 'Bob The Builder' ],
 449         [ 3, 'Fred The Phenotype' ],
 450     ]);
 451
 452     $schema->populate('CD_to_Producer', [
 453         [ qw/cd producer/ ],
 454         [ 1, 1 ],
 455         [ 1, 2 ],
 456         [ 1, 3 ],
 457     ]);
 458
 459     $schema->populate('TreeLike', [
 460         [ qw/id parent name/ ],
 461         [ 1, undef, 'root' ],
 462         [ 2, 1, 'foo'  ],
 463         [ 3, 2, 'bar'  ],
 464         [ 6, 2, 'blop' ],
 465         [ 4, 3, 'baz'  ],
 466         [ 5, 4, 'quux' ],
 467         [ 7, 3, 'fong'  ],
 468     ]);
 469
 470     $schema->populate('Track', [
 471         [ qw/trackid cd  position title/ ],
 472         [ 4, 2, 1, "Stung with Success"],
 473         [ 5, 2, 2, "Stripy"],
 474         [ 6, 2, 3, "Sticky Honey"],
 475         [ 7, 3, 1, "Yowlin"],
 476         [ 8, 3, 2, "Howlin"],
 477         [ 9, 3, 3, "Fowlin"],
 478         [ 10, 4, 1, "Boring Name"],
 479         [ 11, 4, 2, "Boring Song"],
 480         [ 12, 4, 3, "No More Ideas"],
 481         [ 13, 5, 1, "Sad"],
 482         [ 14, 5, 2, "Under The Weather"],
 483         [ 15, 5, 3, "Suicidal"],
 484         [ 16, 1, 1, "The Bees Knees"],
 485         [ 17, 1, 2, "Apiary"],
 486         [ 18, 1, 3, "Beehind You"],
 487     ]);
 488
 489     $schema->populate('Event', [
 490         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 491         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 492     ]);
 493
 494     $schema->populate('Link', [
 495         [ qw/id url title/ ],
 496         [ 1, '', 'aaa' ]
 497     ]);
 498
 499     $schema->populate('Bookmark', [
 500         [ qw/id link/ ],
 501         [ 1, 1 ]
 502     ]);
 503
 504     $schema->populate('Collection', [
 505         [ qw/collectionid name/ ],
 506         [ 1, "Tools" ],
 507         [ 2, "Body Parts" ],
 508     ]);
 509
 510     $schema->populate('TypedObject', [
 511         [ qw/objectid type value/ ],
 512         [ 1, "pointy", "Awl" ],
 513         [ 2, "round", "Bearing" ],
 514         [ 3, "pointy", "Knife" ],
 515         [ 4, "pointy", "Tooth" ],
 516         [ 5, "round", "Head" ],
 517     ]);
 518     $schema->populate('CollectionObject', [
 519         [ qw/collection object/ ],
 520         [ 1, 1 ],
 521         [ 1, 2 ],
 522         [ 1, 3 ],
 523         [ 2, 4 ],
 524         [ 2, 5 ],
 525     ]);
 526
 527     $schema->populate('Owners', [
 528         [ qw/id name/ ],
 529         [ 1, "Newton" ],
 530         [ 2, "Waltham" ],
 531     ]);
 532
 533     $schema->populate('BooksInLibrary', [
 534         [ qw/id owner title source price/ ],
 535         [ 1, 1, "Programming Perl", "Library", 23 ],
 536         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 537         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 538     ]);
 539 }
 540
 541 1;