t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6
   7 # this noop trick initializes the STDOUT, so that the TAP::Harness
   8 # issued IO::Select->can_read calls (which are blocking wtf wtf wtf)
   9 # keep spinning and scheduling jobs
  10 # This results in an overall much smoother job-queue drainage, since
  11 # the Harness blocks less
  12 # (ideally this needs to be addressed in T::H, but a quick patchjob
  13 # broke everything so tabling it for now)
  14 BEGIN {
  15   if ($INC{'Test/Builder.pm'}) {
  16     local $| = 1;
  17     print "#\n";
  18   }
  19 }
  20
  21 use Module::Runtime 'module_notional_filename';
  22 BEGIN {
  23   for my $mod (qw( DBIC::SqlMakerTest SQL::Abstract )) {
  24     if ( $INC{ module_notional_filename($mod) } ) {
  25       # FIXME this does not seem to work in BEGIN - why?!
  26       #require Carp;
  27       #$Carp::Internal{ (__PACKAGE__) }++;
  28       #Carp::croak( __PACKAGE__ . " must be loaded before $mod" );
  29
  30       my ($fr, @frame) = 1;
  31       while (@frame = caller($fr++)) {
  32         last if $frame[1] !~ m|^t/lib/DBICTest|;
  33       }
  34
  35       die __PACKAGE__ . " must be loaded before $mod (or modules using $mod) at $frame[1] line $frame[2]\n";
  36     }
  37   }
  38 }
  39
  40 use DBICTest::RunMode;
  41 use DBICTest::Schema;
  42 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
  43 use DBICTest::Util 'local_umask';
  44 use Carp;
  45 use Path::Class::File ();
  46 use File::Spec;
  47 use Fcntl qw/:DEFAULT :flock/;
  48
  49 =head1 NAME
  50
  51 DBICTest - Library to be used by DBIx::Class test scripts.
  52
  53 =head1 SYNOPSIS
  54
  55   use lib qw(t/lib);
  56   use DBICTest;
  57   use Test::More;
  58
  59   my $schema = DBICTest->init_schema();
  60
  61 =head1 DESCRIPTION
  62
  63 This module provides the basic utilities to write tests against
  64 DBIx::Class.
  65
  66 =head1 METHODS
  67
  68 =head2 init_schema
  69
  70   my $schema = DBICTest->init_schema(
  71     no_deploy=>1,
  72     no_populate=>1,
  73     storage_type=>'::DBI::Replicated',
  74     storage_type_args=>{
  75       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  76     },
  77   );
  78
  79 This method removes the test SQLite database in t/var/DBIxClass.db
  80 and then creates a new, empty database.
  81
  82 This method will call deploy_schema() by default, unless the
  83 no_deploy flag is set.
  84
  85 Also, by default, this method will call populate_schema() by
  86 default, unless the no_deploy or no_populate flags are set.
  87
  88 =cut
  89
  90 # some tests are very time sensitive and need to run on their own, without
  91 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  92 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  93 # will ask for an exclusive one and block until they can get it
  94 our ($global_lock_fh, $global_exclusive_lock);
  95 sub import {
  96     my $self = shift;
  97
  98     my $tmpdir = DBICTest::RunMode->tmpdir;
  99     my $lockpath = $tmpdir->file('.dbictest_global.lock');
 100
 101     {
 102       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
 103       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT) or do {
 104         my $err = $!;
 105
 106         my @x_tests = map { (defined $_) ? ( $_ ? 1 : 0 ) : 'U' } map {(-e, -d, -f, -r, -w, -x, -o)} ($tmpdir, $lockpath);
 107
 108         die sprintf <<"EOE", $lockpath, $err, scalar $>, scalar $), (stat($tmpdir))[4,5,2], @x_tests;
 109 Unable to open %s: %s
 110 Process EUID/EGID: %s / %s
 111 TmpDir UID/GID:    %s / %s
 112 TmpDir StatMode:   %o
 113 TmpDir X-tests:    -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
 114 TmpFile X-tests:   -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
 115 EOE
 116       };
 117     }
 118
 119     for (@_) {
 120         if ($_ eq ':GlobalLock') {
 121             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
 122             $global_exclusive_lock = 1;
 123         }
 124         else {
 125             croak "Unknown export $_ requested from $self";
 126         }
 127     }
 128
 129     unless ($global_exclusive_lock) {
 130         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
 131     }
 132 }
 133
 134 END {
 135     if ($global_lock_fh) {
 136         # delay destruction even more
 137     }
 138 }
 139
 140 {
 141     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 142     $dir->mkpath unless -d "$dir";
 143     $dir = "$dir";
 144
 145     sub _sqlite_dbfilename {
 146         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 147         $holder = $$ if $holder == -1;
 148
 149         # useful for missing cleanup debugging
 150         #if ( $holder == $$) {
 151         #  my $x = $0;
 152         #  $x =~ s/\//#/g;
 153         #  $holder .= "-$x";
 154         #}
 155
 156         return "$dir/DBIxClass-$holder.db";
 157     }
 158
 159     END {
 160         _cleanup_dbfile();
 161     }
 162 }
 163
 164 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 165
 166 sub _cleanup_dbfile {
 167     # cleanup if this is us
 168     if (
 169       ! $ENV{DBICTEST_LOCK_HOLDER}
 170         or
 171       $ENV{DBICTEST_LOCK_HOLDER} == -1
 172         or
 173       $ENV{DBICTEST_LOCK_HOLDER} == $$
 174     ) {
 175         my $db_file = _sqlite_dbfilename();
 176         unlink $_ for ($db_file, "${db_file}-journal");
 177     }
 178 }
 179
 180 sub has_custom_dsn {
 181     return $ENV{"DBICTEST_DSN"} ? 1:0;
 182 }
 183
 184 sub _sqlite_dbname {
 185     my $self = shift;
 186     my %args = @_;
 187     return $self->_sqlite_dbfilename if (
 188       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 189     );
 190     return ":memory:";
 191 }
 192
 193 sub _database {
 194     my $self = shift;
 195     my %args = @_;
 196
 197     if ($ENV{DBICTEST_DSN}) {
 198       return (
 199         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 200         { AutoCommit => 1, %args },
 201       );
 202     }
 203     my $db_file = $self->_sqlite_dbname(%args);
 204
 205     for ($db_file, "${db_file}-journal") {
 206       next unless -e $_;
 207       unlink ($_) or carp (
 208         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 209       );
 210     }
 211
 212     # MASSIVE FIXME - this seems necessary, but I do not yet know why
 213     # without an external variable on the pad the on_connect_do cref
 214     # (starting just below) is being considered a const of some sorts
 215     # and persists indefinitely... wtf --ribasushi
 216     my $such_var = 'very closure... much wtf... wow!!!';
 217
 218     return ("dbi:SQLite:${db_file}", '', '', {
 219       AutoCommit => 1,
 220
 221       # this is executed on every connect, and thus installs a disconnect/DESTROY
 222       # guard for every new $dbh
 223       on_connect_do => sub {
 224         # MASSIVE FIXME - this seems necessary, but I do not yet know why
 225         # without an external variable on the pad the on_connect_do cref
 226         # (starting just above) is being considered a const of some sorts
 227         # and persists indefinitely... wtf --ribasushi
 228         $such_var if 0;
 229
 230         my $storage = shift;
 231         my $dbh = $storage->_get_dbh;
 232
 233         # no fsync on commit
 234         $dbh->do ('PRAGMA synchronous = OFF');
 235
 236         if ($ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER}) {
 237
 238           $storage->throw_exception(
 239             'PRAGMA reverse_unordered_selects does not work correctly before libsqlite 3.7.9'
 240           ) if $storage->_server_info->{normalized_dbms_version} < 3.007009;
 241
 242           $dbh->do ('PRAGMA reverse_unordered_selects = ON');
 243         }
 244
 245         # set a *DBI* disconnect callback, to make sure the physical SQLite
 246         # file is still there (i.e. the test does not attempt to delete
 247         # an open database, which fails on Win32)
 248         if (my $guard_cb = __mk_disconnect_guard($dbh->sqlite_db_filename)) {
 249           $dbh->{Callbacks} = {
 250             connect => sub { $guard_cb->('connect') },
 251             disconnect => sub { $guard_cb->('disconnect') },
 252             DESTROY => sub { $guard_cb->('DESTROY') },
 253           };
 254         }
 255       },
 256       %args,
 257     });
 258 }
 259
 260 sub __mk_disconnect_guard {
 261   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 262
 263   my $db_file = shift;
 264   return unless -f $db_file;
 265
 266   my $orig_inode = (stat($db_file))[1]
 267     or return;
 268
 269   my $clan_connect_caller = '*UNKNOWN*';
 270   my $i;
 271   while ( my ($pack, $file, $line) = caller(++$i) ) {
 272     next if $file eq __FILE__;
 273     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 274     $clan_connect_caller = "$file line $line";
 275   }
 276
 277   my $failed_once = 0;
 278   my $connected = 1;
 279
 280   return sub {
 281     return if $failed_once;
 282
 283     my $event = shift;
 284     if ($event eq 'connect') {
 285       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 286       $connected = 1;
 287       return;
 288     }
 289     elsif ($event eq 'disconnect') {
 290       $connected = 0;
 291     }
 292     elsif ($event eq 'DESTROY' and ! $connected ) {
 293       return;
 294     }
 295
 296     my $fail_reason;
 297     if (! -e $db_file) {
 298       $fail_reason = 'is missing';
 299     }
 300     else {
 301       my $cur_inode = (stat($db_file))[1];
 302
 303       if ($orig_inode != $cur_inode) {
 304         # pack/unpack to match the unsigned longs returned by `stat`
 305         $fail_reason = sprintf 'was recreated (initially inode %s, now %s)', (
 306           map { unpack ('L', pack ('l', $_) ) } ($orig_inode, $cur_inode )
 307         );
 308       }
 309     }
 310
 311     if ($fail_reason) {
 312       $failed_once++;
 313
 314       require Test::Builder;
 315       my $t = Test::Builder->new;
 316       local $Test::Builder::Level = $Test::Builder::Level + 3;
 317       $t->ok (0,
 318         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 319       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 320       . 'still being open. This action would fail massively if running under Win32, hence '
 321       . 'we make sure it fails on any OS :)'
 322       );
 323     }
 324
 325     return; # this empty return is a DBI requirement
 326   };
 327 }
 328
 329 my $weak_registry = {};
 330
 331 sub init_schema {
 332     my $self = shift;
 333     my %args = @_;
 334
 335     my $schema;
 336
 337     if ($args{compose_connection}) {
 338       $schema = DBICTest::Schema->compose_connection(
 339                   'DBICTest', $self->_database(%args)
 340                 );
 341     } else {
 342       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 343     }
 344
 345     if( $args{storage_type}) {
 346       $schema->storage_type($args{storage_type});
 347     }
 348
 349     if ( !$args{no_connect} ) {
 350       $schema = $schema->connect($self->_database(%args));
 351     }
 352
 353     if ( !$args{no_deploy} ) {
 354         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 355         __PACKAGE__->populate_schema( $schema )
 356          if( !$args{no_populate} );
 357     }
 358
 359     populate_weakregistry ( $weak_registry, $schema->storage )
 360       if $INC{'Test/Builder.pm'} and $schema->storage;
 361
 362     return $schema;
 363 }
 364
 365 END {
 366     assert_empty_weakregistry($weak_registry, 'quiet');
 367 }
 368
 369 =head2 deploy_schema
 370
 371   DBICTest->deploy_schema( $schema );
 372
 373 This method does one of two things to the schema.  It can either call
 374 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 375 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 376 file and execute the SQL within. Either way you end up with a fresh set
 377 of tables for testing.
 378
 379 =cut
 380
 381 sub deploy_schema {
 382     my $self = shift;
 383     my $schema = shift;
 384     my $args = shift || {};
 385
 386     local $schema->storage->{debug}
 387       if ($ENV{TRAVIS}||'') eq 'true';
 388
 389     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 390         $schema->deploy($args);
 391     } else {
 392         my $filename = Path::Class::File->new(__FILE__)->dir
 393           ->file('sqlite.sql')->stringify;
 394         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 395         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 396           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 397             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 398           }
 399         }
 400     }
 401     return;
 402 }
 403
 404 =head2 populate_schema
 405
 406   DBICTest->populate_schema( $schema );
 407
 408 After you deploy your schema you can use this method to populate
 409 the tables with test data.
 410
 411 =cut
 412
 413 sub populate_schema {
 414     my $self = shift;
 415     my $schema = shift;
 416
 417     local $schema->storage->{debug}
 418       if ($ENV{TRAVIS}||'') eq 'true';
 419
 420     $schema->populate('Genre', [
 421       [qw/genreid name/],
 422       [qw/1       emo  /],
 423     ]);
 424
 425     $schema->populate('Artist', [
 426         [ qw/artistid name/ ],
 427         [ 1, 'Caterwauler McCrae' ],
 428         [ 2, 'Random Boy Band' ],
 429         [ 3, 'We Are Goth' ],
 430     ]);
 431
 432     $schema->populate('CD', [
 433         [ qw/cdid artist title year genreid/ ],
 434         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 435         [ 2, 1, "Forkful of bees", 2001 ],
 436         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 437         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 438         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 439     ]);
 440
 441     $schema->populate('LinerNotes', [
 442         [ qw/liner_id notes/ ],
 443         [ 2, "Buy Whiskey!" ],
 444         [ 4, "Buy Merch!" ],
 445         [ 5, "Kill Yourself!" ],
 446     ]);
 447
 448     $schema->populate('Tag', [
 449         [ qw/tagid cd tag/ ],
 450         [ 1, 1, "Blue" ],
 451         [ 2, 2, "Blue" ],
 452         [ 3, 3, "Blue" ],
 453         [ 4, 5, "Blue" ],
 454         [ 5, 2, "Cheesy" ],
 455         [ 6, 4, "Cheesy" ],
 456         [ 7, 5, "Cheesy" ],
 457         [ 8, 2, "Shiny" ],
 458         [ 9, 4, "Shiny" ],
 459     ]);
 460
 461     $schema->populate('TwoKeys', [
 462         [ qw/artist cd/ ],
 463         [ 1, 1 ],
 464         [ 1, 2 ],
 465         [ 2, 2 ],
 466     ]);
 467
 468     $schema->populate('FourKeys', [
 469         [ qw/foo bar hello goodbye sensors/ ],
 470         [ 1, 2, 3, 4, 'online' ],
 471         [ 5, 4, 3, 6, 'offline' ],
 472     ]);
 473
 474     $schema->populate('OneKey', [
 475         [ qw/id artist cd/ ],
 476         [ 1, 1, 1 ],
 477         [ 2, 1, 2 ],
 478         [ 3, 2, 2 ],
 479     ]);
 480
 481     $schema->populate('SelfRef', [
 482         [ qw/id name/ ],
 483         [ 1, 'First' ],
 484         [ 2, 'Second' ],
 485     ]);
 486
 487     $schema->populate('SelfRefAlias', [
 488         [ qw/self_ref alias/ ],
 489         [ 1, 2 ]
 490     ]);
 491
 492     $schema->populate('ArtistUndirectedMap', [
 493         [ qw/id1 id2/ ],
 494         [ 1, 2 ]
 495     ]);
 496
 497     $schema->populate('Producer', [
 498         [ qw/producerid name/ ],
 499         [ 1, 'Matt S Trout' ],
 500         [ 2, 'Bob The Builder' ],
 501         [ 3, 'Fred The Phenotype' ],
 502     ]);
 503
 504     $schema->populate('CD_to_Producer', [
 505         [ qw/cd producer/ ],
 506         [ 1, 1 ],
 507         [ 1, 2 ],
 508         [ 1, 3 ],
 509     ]);
 510
 511     $schema->populate('TreeLike', [
 512         [ qw/id parent name/ ],
 513         [ 1, undef, 'root' ],
 514         [ 2, 1, 'foo'  ],
 515         [ 3, 2, 'bar'  ],
 516         [ 6, 2, 'blop' ],
 517         [ 4, 3, 'baz'  ],
 518         [ 5, 4, 'quux' ],
 519         [ 7, 3, 'fong'  ],
 520     ]);
 521
 522     $schema->populate('Track', [
 523         [ qw/trackid cd  position title/ ],
 524         [ 4, 2, 1, "Stung with Success"],
 525         [ 5, 2, 2, "Stripy"],
 526         [ 6, 2, 3, "Sticky Honey"],
 527         [ 7, 3, 1, "Yowlin"],
 528         [ 8, 3, 2, "Howlin"],
 529         [ 9, 3, 3, "Fowlin"],
 530         [ 10, 4, 1, "Boring Name"],
 531         [ 11, 4, 2, "Boring Song"],
 532         [ 12, 4, 3, "No More Ideas"],
 533         [ 13, 5, 1, "Sad"],
 534         [ 14, 5, 2, "Under The Weather"],
 535         [ 15, 5, 3, "Suicidal"],
 536         [ 16, 1, 1, "The Bees Knees"],
 537         [ 17, 1, 2, "Apiary"],
 538         [ 18, 1, 3, "Beehind You"],
 539     ]);
 540
 541     $schema->populate('Event', [
 542         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 543         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 544     ]);
 545
 546     $schema->populate('Link', [
 547         [ qw/id url title/ ],
 548         [ 1, '', 'aaa' ]
 549     ]);
 550
 551     $schema->populate('Bookmark', [
 552         [ qw/id link/ ],
 553         [ 1, 1 ]
 554     ]);
 555
 556     $schema->populate('Collection', [
 557         [ qw/collectionid name/ ],
 558         [ 1, "Tools" ],
 559         [ 2, "Body Parts" ],
 560     ]);
 561
 562     $schema->populate('TypedObject', [
 563         [ qw/objectid type value/ ],
 564         [ 1, "pointy", "Awl" ],
 565         [ 2, "round", "Bearing" ],
 566         [ 3, "pointy", "Knife" ],
 567         [ 4, "pointy", "Tooth" ],
 568         [ 5, "round", "Head" ],
 569     ]);
 570     $schema->populate('CollectionObject', [
 571         [ qw/collection object/ ],
 572         [ 1, 1 ],
 573         [ 1, 2 ],
 574         [ 1, 3 ],
 575         [ 2, 4 ],
 576         [ 2, 5 ],
 577     ]);
 578
 579     $schema->populate('Owners', [
 580         [ qw/id name/ ],
 581         [ 1, "Newton" ],
 582         [ 2, "Waltham" ],
 583     ]);
 584
 585     $schema->populate('BooksInLibrary', [
 586         [ qw/id owner title source price/ ],
 587         [ 1, 1, "Programming Perl", "Library", 23 ],
 588         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 589         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 590     ]);
 591 }
 592
 593 1;