t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6
   7 # this noop trick initializes the STDOUT, so that the TAP::Harness
   8 # issued IO::Select->can_read calls (which are blocking wtf wtf wtf)
   9 # keep spinning and scheduling jobs
  10 # This results in an overall much smoother job-queue drainage, since
  11 # the Harness blocks less
  12 # (ideally this needs to be addressed in T::H, but a quick patchjob
  13 # broke everything so tabling it for now)
  14 BEGIN {
  15   if ($INC{'Test/Builder.pm'}) {
  16     local $| = 1;
  17     print "#\n";
  18   }
  19 }
  20
  21 use Module::Runtime 'module_notional_filename';
  22 BEGIN {
  23   for my $mod (qw( DBIC::SqlMakerTest SQL::Abstract )) {
  24     if ( $INC{ module_notional_filename($mod) } ) {
  25       # FIXME this does not seem to work in BEGIN - why?!
  26       #require Carp;
  27       #$Carp::Internal{ (__PACKAGE__) }++;
  28       #Carp::croak( __PACKAGE__ . " must be loaded before $mod" );
  29
  30       my ($fr, @frame) = 1;
  31       while (@frame = caller($fr++)) {
  32         last if $frame[1] !~ m|^t/lib/DBICTest|;
  33       }
  34
  35       die __PACKAGE__ . " must be loaded before $mod (or modules using $mod) at $frame[1] line $frame[2]\n";
  36     }
  37   }
  38 }
  39
  40 use DBICTest::RunMode;
  41 use DBICTest::Schema;
  42 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
  43 use DBICTest::Util 'local_umask';
  44 use Carp;
  45 use Path::Class::File ();
  46 use File::Spec;
  47 use Fcntl qw/:DEFAULT :flock/;
  48 use Config;
  49
  50 =head1 NAME
  51
  52 DBICTest - Library to be used by DBIx::Class test scripts.
  53
  54 =head1 SYNOPSIS
  55
  56   use lib qw(t/lib);
  57   use DBICTest;
  58   use Test::More;
  59
  60   my $schema = DBICTest->init_schema();
  61
  62 =head1 DESCRIPTION
  63
  64 This module provides the basic utilities to write tests against
  65 DBIx::Class.
  66
  67 =head1 METHODS
  68
  69 =head2 init_schema
  70
  71   my $schema = DBICTest->init_schema(
  72     no_deploy=>1,
  73     no_populate=>1,
  74     storage_type=>'::DBI::Replicated',
  75     storage_type_args=>{
  76       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  77     },
  78   );
  79
  80 This method removes the test SQLite database in t/var/DBIxClass.db
  81 and then creates a new, empty database.
  82
  83 This method will call deploy_schema() by default, unless the
  84 no_deploy flag is set.
  85
  86 Also, by default, this method will call populate_schema() by
  87 default, unless the no_deploy or no_populate flags are set.
  88
  89 =cut
  90
  91 # some tests are very time sensitive and need to run on their own, without
  92 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  93 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  94 # will ask for an exclusive one and block until they can get it
  95 our ($global_lock_fh, $global_exclusive_lock);
  96 sub import {
  97     my $self = shift;
  98
  99     my $tmpdir = DBICTest::RunMode->tmpdir;
 100     my $lockpath = $tmpdir->file('.dbictest_global.lock');
 101
 102     {
 103       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
 104       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT)
 105         or die "Unable to open $lockpath: $!";
 106     }
 107
 108     for (@_) {
 109         if ($_ eq ':GlobalLock') {
 110             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
 111             $global_exclusive_lock = 1;
 112         }
 113         else {
 114             croak "Unknown export $_ requested from $self";
 115         }
 116     }
 117
 118     unless ($global_exclusive_lock) {
 119         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
 120     }
 121 }
 122
 123 END {
 124     if ($global_lock_fh) {
 125         # delay destruction even more
 126     }
 127 }
 128
 129 {
 130     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 131     $dir->mkpath unless -d "$dir";
 132     $dir = "$dir";
 133
 134     sub _sqlite_dbfilename {
 135         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 136         $holder = $$ if $holder == -1;
 137
 138         # useful for missing cleanup debugging
 139         #if ( $holder == $$) {
 140         #  my $x = $0;
 141         #  $x =~ s/\//#/g;
 142         #  $holder .= "-$x";
 143         #}
 144
 145         return "$dir/DBIxClass-$holder.db";
 146     }
 147
 148     END {
 149         _cleanup_dbfile();
 150     }
 151 }
 152
 153 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 154
 155 sub _cleanup_dbfile {
 156     # cleanup if this is us
 157     if (
 158       ! $ENV{DBICTEST_LOCK_HOLDER}
 159         or
 160       $ENV{DBICTEST_LOCK_HOLDER} == -1
 161         or
 162       $ENV{DBICTEST_LOCK_HOLDER} == $$
 163     ) {
 164         my $db_file = _sqlite_dbfilename();
 165         unlink $_ for ($db_file, "${db_file}-journal");
 166     }
 167 }
 168
 169 sub has_custom_dsn {
 170     return $ENV{"DBICTEST_DSN"} ? 1:0;
 171 }
 172
 173 sub _sqlite_dbname {
 174     my $self = shift;
 175     my %args = @_;
 176     return $self->_sqlite_dbfilename if (
 177       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 178     );
 179     return ":memory:";
 180 }
 181
 182 sub _database {
 183     my $self = shift;
 184     my %args = @_;
 185
 186     if ($ENV{DBICTEST_DSN}) {
 187       return (
 188         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 189         { AutoCommit => 1, %args },
 190       );
 191     }
 192     my $db_file = $self->_sqlite_dbname(%args);
 193
 194     for ($db_file, "${db_file}-journal") {
 195       next unless -e $_;
 196       unlink ($_) or carp (
 197         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 198       );
 199     }
 200
 201     return ("dbi:SQLite:${db_file}", '', '', {
 202       AutoCommit => 1,
 203
 204       # this is executed on every connect, and thus installs a disconnect/DESTROY
 205       # guard for every new $dbh
 206       on_connect_do => sub {
 207
 208         my $storage = shift;
 209         my $dbh = $storage->_get_dbh;
 210
 211         # no fsync on commit
 212         $dbh->do ('PRAGMA synchronous = OFF');
 213
 214         if ($ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER}) {
 215
 216           $storage->throw_exception(
 217             'PRAGMA reverse_unordered_selects does not work correctly before libsqlite 3.7.9'
 218           ) if $storage->_server_info->{normalized_dbms_version} < 3.007009;
 219
 220           $dbh->do ('PRAGMA reverse_unordered_selects = ON');
 221         }
 222
 223         # set a *DBI* disconnect callback, to make sure the physical SQLite
 224         # file is still there (i.e. the test does not attempt to delete
 225         # an open database, which fails on Win32)
 226         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 227           $dbh->{Callbacks} = {
 228             connect => sub { $guard_cb->('connect') },
 229             disconnect => sub { $guard_cb->('disconnect') },
 230             DESTROY => sub { $guard_cb->('DESTROY') },
 231           };
 232         }
 233       },
 234       %args,
 235     });
 236 }
 237
 238 sub __mk_disconnect_guard {
 239   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 240
 241   my $db_file = shift;
 242   return unless -f $db_file;
 243
 244   my $orig_inode = (stat($db_file))[1]
 245     or return;
 246
 247   my $clan_connect_caller = '*UNKNOWN*';
 248   my $i;
 249   while ( my ($pack, $file, $line) = caller(++$i) ) {
 250     next if $file eq __FILE__;
 251     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 252     $clan_connect_caller = "$file line $line";
 253   }
 254
 255   my $failed_once = 0;
 256   my $connected = 1;
 257
 258   return sub {
 259     return if $failed_once;
 260
 261     my $event = shift;
 262     if ($event eq 'connect') {
 263       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 264       $connected = 1;
 265       return;
 266     }
 267     elsif ($event eq 'disconnect') {
 268       $connected = 0;
 269     }
 270     elsif ($event eq 'DESTROY' and ! $connected ) {
 271       return;
 272     }
 273
 274     my $fail_reason;
 275     if (! -e $db_file) {
 276       $fail_reason = 'is missing';
 277     }
 278     else {
 279       my $cur_inode = (stat($db_file))[1];
 280
 281       if ($orig_inode != $cur_inode) {
 282         my @inodes = ($orig_inode, $cur_inode);
 283         # unless this is a fixed perl (P5RT#84590) pack/unpack before display
 284         # to match the unsigned longs returned by `stat`
 285         @inodes = map { unpack ('L', pack ('l', $_) ) } @inodes
 286           unless $Config{st_ino_size};
 287
 288         $fail_reason = sprintf
 289           'was recreated (initially inode %s, now %s)',
 290           @inodes
 291         ;
 292       }
 293     }
 294
 295     if ($fail_reason) {
 296       $failed_once++;
 297
 298       require Test::Builder;
 299       my $t = Test::Builder->new;
 300       local $Test::Builder::Level = $Test::Builder::Level + 3;
 301       $t->ok (0,
 302         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 303       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 304       . 'still being open. This action would fail massively if running under Win32, hence '
 305       . 'we make sure it fails on any OS :)'
 306       );
 307     }
 308
 309     return; # this empty return is a DBI requirement
 310   };
 311 }
 312
 313 my $weak_registry = {};
 314
 315 sub init_schema {
 316     my $self = shift;
 317     my %args = @_;
 318
 319     my $schema;
 320
 321     if ($args{compose_connection}) {
 322       $schema = DBICTest::Schema->compose_connection(
 323                   'DBICTest', $self->_database(%args)
 324                 );
 325     } else {
 326       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 327     }
 328
 329     if( $args{storage_type}) {
 330       $schema->storage_type($args{storage_type});
 331     }
 332
 333     if ( !$args{no_connect} ) {
 334       $schema = $schema->connect($self->_database(%args));
 335     }
 336
 337     if ( !$args{no_deploy} ) {
 338         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 339         __PACKAGE__->populate_schema( $schema )
 340          if( !$args{no_populate} );
 341     }
 342
 343     populate_weakregistry ( $weak_registry, $schema->storage )
 344       if $INC{'Test/Builder.pm'} and $schema->storage;
 345
 346     return $schema;
 347 }
 348
 349 END {
 350     assert_empty_weakregistry($weak_registry, 'quiet');
 351 }
 352
 353 =head2 deploy_schema
 354
 355   DBICTest->deploy_schema( $schema );
 356
 357 This method does one of two things to the schema.  It can either call
 358 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 359 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 360 file and execute the SQL within. Either way you end up with a fresh set
 361 of tables for testing.
 362
 363 =cut
 364
 365 sub deploy_schema {
 366     my $self = shift;
 367     my $schema = shift;
 368     my $args = shift || {};
 369
 370     local $schema->storage->{debug}
 371       if ($ENV{TRAVIS}||'') eq 'true';
 372
 373     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 374         $schema->deploy($args);
 375     } else {
 376         my $filename = Path::Class::File->new(__FILE__)->dir
 377           ->file('sqlite.sql')->stringify;
 378         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 379         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 380           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 381             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 382           }
 383         }
 384     }
 385     return;
 386 }
 387
 388 =head2 populate_schema
 389
 390   DBICTest->populate_schema( $schema );
 391
 392 After you deploy your schema you can use this method to populate
 393 the tables with test data.
 394
 395 =cut
 396
 397 sub populate_schema {
 398     my $self = shift;
 399     my $schema = shift;
 400
 401     local $schema->storage->{debug}
 402       if ($ENV{TRAVIS}||'') eq 'true';
 403
 404     $schema->populate('Genre', [
 405       [qw/genreid name/],
 406       [qw/1       emo  /],
 407     ]);
 408
 409     $schema->populate('Artist', [
 410         [ qw/artistid name/ ],
 411         [ 1, 'Caterwauler McCrae' ],
 412         [ 2, 'Random Boy Band' ],
 413         [ 3, 'We Are Goth' ],
 414     ]);
 415
 416     $schema->populate('CD', [
 417         [ qw/cdid artist title year genreid/ ],
 418         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 419         [ 2, 1, "Forkful of bees", 2001 ],
 420         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 421         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 422         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 423     ]);
 424
 425     $schema->populate('LinerNotes', [
 426         [ qw/liner_id notes/ ],
 427         [ 2, "Buy Whiskey!" ],
 428         [ 4, "Buy Merch!" ],
 429         [ 5, "Kill Yourself!" ],
 430     ]);
 431
 432     $schema->populate('Tag', [
 433         [ qw/tagid cd tag/ ],
 434         [ 1, 1, "Blue" ],
 435         [ 2, 2, "Blue" ],
 436         [ 3, 3, "Blue" ],
 437         [ 4, 5, "Blue" ],
 438         [ 5, 2, "Cheesy" ],
 439         [ 6, 4, "Cheesy" ],
 440         [ 7, 5, "Cheesy" ],
 441         [ 8, 2, "Shiny" ],
 442         [ 9, 4, "Shiny" ],
 443     ]);
 444
 445     $schema->populate('TwoKeys', [
 446         [ qw/artist cd/ ],
 447         [ 1, 1 ],
 448         [ 1, 2 ],
 449         [ 2, 2 ],
 450     ]);
 451
 452     $schema->populate('FourKeys', [
 453         [ qw/foo bar hello goodbye sensors/ ],
 454         [ 1, 2, 3, 4, 'online' ],
 455         [ 5, 4, 3, 6, 'offline' ],
 456     ]);
 457
 458     $schema->populate('OneKey', [
 459         [ qw/id artist cd/ ],
 460         [ 1, 1, 1 ],
 461         [ 2, 1, 2 ],
 462         [ 3, 2, 2 ],
 463     ]);
 464
 465     $schema->populate('SelfRef', [
 466         [ qw/id name/ ],
 467         [ 1, 'First' ],
 468         [ 2, 'Second' ],
 469     ]);
 470
 471     $schema->populate('SelfRefAlias', [
 472         [ qw/self_ref alias/ ],
 473         [ 1, 2 ]
 474     ]);
 475
 476     $schema->populate('ArtistUndirectedMap', [
 477         [ qw/id1 id2/ ],
 478         [ 1, 2 ]
 479     ]);
 480
 481     $schema->populate('Producer', [
 482         [ qw/producerid name/ ],
 483         [ 1, 'Matt S Trout' ],
 484         [ 2, 'Bob The Builder' ],
 485         [ 3, 'Fred The Phenotype' ],
 486     ]);
 487
 488     $schema->populate('CD_to_Producer', [
 489         [ qw/cd producer/ ],
 490         [ 1, 1 ],
 491         [ 1, 2 ],
 492         [ 1, 3 ],
 493     ]);
 494
 495     $schema->populate('TreeLike', [
 496         [ qw/id parent name/ ],
 497         [ 1, undef, 'root' ],
 498         [ 2, 1, 'foo'  ],
 499         [ 3, 2, 'bar'  ],
 500         [ 6, 2, 'blop' ],
 501         [ 4, 3, 'baz'  ],
 502         [ 5, 4, 'quux' ],
 503         [ 7, 3, 'fong'  ],
 504     ]);
 505
 506     $schema->populate('Track', [
 507         [ qw/trackid cd  position title/ ],
 508         [ 4, 2, 1, "Stung with Success"],
 509         [ 5, 2, 2, "Stripy"],
 510         [ 6, 2, 3, "Sticky Honey"],
 511         [ 7, 3, 1, "Yowlin"],
 512         [ 8, 3, 2, "Howlin"],
 513         [ 9, 3, 3, "Fowlin"],
 514         [ 10, 4, 1, "Boring Name"],
 515         [ 11, 4, 2, "Boring Song"],
 516         [ 12, 4, 3, "No More Ideas"],
 517         [ 13, 5, 1, "Sad"],
 518         [ 14, 5, 2, "Under The Weather"],
 519         [ 15, 5, 3, "Suicidal"],
 520         [ 16, 1, 1, "The Bees Knees"],
 521         [ 17, 1, 2, "Apiary"],
 522         [ 18, 1, 3, "Beehind You"],
 523     ]);
 524
 525     $schema->populate('Event', [
 526         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 527         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 528     ]);
 529
 530     $schema->populate('Link', [
 531         [ qw/id url title/ ],
 532         [ 1, '', 'aaa' ]
 533     ]);
 534
 535     $schema->populate('Bookmark', [
 536         [ qw/id link/ ],
 537         [ 1, 1 ]
 538     ]);
 539
 540     $schema->populate('Collection', [
 541         [ qw/collectionid name/ ],
 542         [ 1, "Tools" ],
 543         [ 2, "Body Parts" ],
 544     ]);
 545
 546     $schema->populate('TypedObject', [
 547         [ qw/objectid type value/ ],
 548         [ 1, "pointy", "Awl" ],
 549         [ 2, "round", "Bearing" ],
 550         [ 3, "pointy", "Knife" ],
 551         [ 4, "pointy", "Tooth" ],
 552         [ 5, "round", "Head" ],
 553     ]);
 554     $schema->populate('CollectionObject', [
 555         [ qw/collection object/ ],
 556         [ 1, 1 ],
 557         [ 1, 2 ],
 558         [ 1, 3 ],
 559         [ 2, 4 ],
 560         [ 2, 5 ],
 561     ]);
 562
 563     $schema->populate('Owners', [
 564         [ qw/id name/ ],
 565         [ 1, "Newton" ],
 566         [ 2, "Waltham" ],
 567     ]);
 568
 569     $schema->populate('BooksInLibrary', [
 570         [ qw/id owner title source price/ ],
 571         [ 1, 1, "Programming Perl", "Library", 23 ],
 572         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 573         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 574     ]);
 575 }
 576
 577 1;